listboxtan listboxa saat verisini tl ile çarparak aktarma

[şehiriçi]

Merhaba
Arkadaşlar yine bir saat konusunda takıldım. şöyle ki listbox2 ye dosyadan çektiğim saat verisini 100 tl ile çarpıp listbox1 e aktarmak , desteğinizi bekliyorum.
dosyam ektedir

 

[RBozkurt]

İşlemin sonucu nedir?

(00:45:25)*100 = ???

 

[şehiriçi]

dakikası 100 tl den 4500 tl 25 sn de 41,66 tl eder toplamda 4541,66 tl eder

 

[RBozkurt]

dakikası 100 tl den 4500 tl 25 sn de 41,66 tl eder toplamda 4541,66 tl eder

B1 hücresine;
=(A1*24*60)*100

Userform kodunuza;

ListBox1.AddItem
ListBox1.List(0, 0) = Format(Worksheets("saat").Range("B1"), "#,##0.00")

gibi....

 

[RBozkurt]

A ve B sütunlarındaki tüm veriyi aktarır..

Private Sub UserForm_Initialize()
    Dim lastRow As Long
    Dim i As Long
    Dim ws As Worksheet
    
    Set ws = ThisWorkbook.Worksheets("saat")
    
    'B sütunundaki verileri Listbox1'e aktar
    lastRow = ws.Cells(ws.Rows.Count, "B").End(xlUp).Row
    For i = 1 To lastRow
        ListBox1.AddItem Format(ws.Cells(i, "B").Value, "#,##0.00")
    Next i
    
    'A sütunundaki verileri Listbox2'ye aktar
    lastRow = ws.Cells(ws.Rows.Count, "A").End(xlUp).Row
    For i = 1 To lastRow
        ListBox2.AddItem Format(ws.Cells(i, "A").Value, "hh:mm:ss")
    Next i
End Sub

 

[RBozkurt]

Para işlemini hücreye yazdırmadan makro içinde çevirir, daha kullanışlı sadece saat verisini çektirirsiniz.

Private Sub UserForm_Initialize()
    Dim lastRow As Long
    Dim i As Long
    Dim timeValue As Date
    Dim calculatedValue As Double
    
    lastRow = Sheets("Saat").Cells(Rows.Count, "A").End(xlUp).Row
    
    For i = 1 To lastRow
        timeValue = Sheets("Saat").Cells(i, "A").Value
        ListBox2.AddItem Format(timeValue, "hh:mm:ss")
    Next i
    
    For i = 1 To lastRow
        calculatedValue = Sheets("Saat").Cells(i, "A").Value * 24 * 60 * 100
        ListBox1.AddItem Format(calculatedValue, "#,##0.00 TL")
    Next i
End Sub