Soru Listboxta Klasör içindeki dosyaların görünmesi

[bulentkars]

Arkadaşlar Merhaba,

C:\Raporlar\Databese\ Klasörü altında 20 adet uzantısı xksb dosyalarım var.
burada yapmak istediğim klasörün altındaki 20 xlsb çalışma kitaplarının isimlerini yandaki listeboxta görünmesini istiyorum.
ve herhangi bir ismin üzerine tıkladığımda da dosyanın açılmasını istiyorum. Konu ile ilgili yardıumcı olabilirseniz sevinirim. Örnek Dosya ekte
Şimdiden Teşekkürler

 

[Korhan Ayhan]

Merhaba,

Dosyanıza boş bir modül ekleyin ve aşağıdaki kodu uygulayın.

Option Explicit
Public My_Path As String

Sub Set_Path()
    My_Path = "C:\Raporlar\Databese\"
End Sub

Sub Auto_Open()
    Dim My_File As String
  
    Call Set_Path

    With Sayfa1.ListBox1
        .Clear
  
        My_File = Dir(My_Path & "*.xlsb")
  
        While My_File <> ""
            .AddItem VBA.CreateObject("Scripting.FileSystemObject").GetBaseName(My_File)
            My_File = Dir
        Wend
    End With
End Sub

Sonra Sayfa1 kod bölümünü açın ve aşağıdaki kodu uygulayın.

Option Explicit

Private Sub ListBox1_DblClick(ByVal Cancel As MSForms.ReturnBoolean)
    On Error Resume Next
    Call Set_Path
    If Me.ListBox1.ListIndex > -1 Then
        If Me.ListBox1.Value <> "" Then
            Workbooks.Open My_Path & Dir(My_Path & Me.ListBox1.Value & ".xls*")
            If Err.Number = 1004 Then
                MsgBox "Dosya açılamıyor!", vbCritical
            End If
        End If
        Call Auto_Open
    End If
End Sub

Tüm bu işlemlerden sonra dosyanızı "Makro İçerebilen Excel Çalışma Kitabı" biçiminde kayıt edip kapatıp açın ve denemeler yapın.

 

[bulentkars]

Korhan Bey,

Çok Teşekkür ederim.

1- Listboxta dosya isimleri geliyor, birini tıkladığımda dosya açılıyor, dosyayı kapatıp tekrar listboxtan açmak istediğimde dosya açılmıyor, Listbox kilitleniyor vba pencersinde auto_open prosedörünü çalıştırdımda oluyor,
2- Listboxta Dosya uzantılarının görünmemesi daha iyi olur.
ilginiz için teşekkürler

 

[Korhan Ayhan]

Önerdiğim kod da talep ettiğiniz revizeleri yaptım. Dosyalar çift tıklama ile açılacaktır.

 

[bulentkars]

Korhan Bey,

Çok güzel olmuş sadece listboxta boş yeri tıkladığımızda en son dosya açılıyor, boş yer tıklandığında uyarı verse veya bir işelm yapmazssa çok güzel olur, Dosya bu şekilde de işimi görür

 

[Korhan Ayhan]

Önerdiğim kodun ListBox çift tıklama olayını revize ettim. Deneyiniz.

 

[bulentkars]

Korhan Bey,

Çok Çok Teşekkür ederim.Elinize emeğinize sağlık.