ListBox da çoklu seçimi sayfaya aktarmak

[sdegirmenci]

Merhaba; Form üzerinde seçtiğim isme ve Listbox'da çoklu seçilen tarihlere "Çalışan" yada "İstirahat" yazmak istiyorum. Normalde Bunu Forum üzerinden faydalanarak yaptım. Ancak ListBox da çoklu seçim olduğu için yapamadım . Bu konuda yardımcı olabilirseniz çok sevinirim. Saygılarımla.

 

[Korhan Ayhan]

Deneyiniz.

Private Sub çalışmayaz_Click()
    Set çz = Sheets("Çizelge")
    Set bekçi_Bul = çz.Range("6:6").Find(bekçiler.Value, , , xlWhole)
    If Not bekçi_Bul Is Nothing Then
        For X = 0 To ListBox1.ListCount - 1
            If ListBox1.Selected(X) = True Then
                Set Tarih_Bul = çz.Range("B:B").Find(CDate(ListBox1.List(X)), , , xlWhole)
                If Not Tarih_Bul Is Nothing Then
                    çz.Cells(Tarih_Bul.Row, bekçi_Bul.Column) = "Çalışma"
                End If
            End If
        Next
    End If
    MsgBox "Bilgi girişi tamamlanmıştır."
End Sub

Private Sub İstirahatyaz_Click()
    Set çz = Sheets("Çizelge")
    Set bekçi_Bul = çz.Range("6:6").Find(bekçiler.Value, , , xlWhole)
    If Not bekçi_Bul Is Nothing Then
        For X = 0 To ListBox1.ListCount - 1
            If ListBox1.Selected(X) = True Then
                Set Tarih_Bul = çz.Range("B:B").Find(CDate(ListBox1.List(X)), , , xlWhole)
                If Not Tarih_Bul Is Nothing Then
                    çz.Cells(Tarih_Bul.Row, bekçi_Bul.Column) = "İstirahat"
                End If
            End If
        Next
    End If
    MsgBox "Bilgi girişi tamamlanmıştır."
End Sub

 

[sdegirmenci]

Korhan Hocam merhaba,
İlginize çok teşekkür ederim. Kodlar Tam istediğim gibi çalıştı. İlginiz ve emeğiniz için Tekrar teşekkür ederim, İşleriniz kolay gelsin.Saygılarımla