Listbox birden fazla secim

[HarEndu]

merhabalar,
ekteki dosyada listboxdan secim yaparak b14 araligindan baslayarak eklemek istiyorum. Birden fazla secim yapacagim ve "In" sekmesinde B14:C18 araligina stok kodlarini eklemek istiyorum. Stok kodlarinin tum koda yapilari degiseceginden adim adim ilerlemem gerekiyor. ayrica arama yapabilecegim kodlar da olursa harika olur. simdiden herkese tesekkur ediyorum.

 

[YUSUF44]

Userformunuzdaki tüm kodları silip aşağıdakileri kullanın:

Private Sub CommandButton1_Click()
    Sheets("In").Range("B14:D18").ClearContents
    Application.ScreenUpdating = False
        sat = 14
        For i = 0 To ListBox1.ListCount - 1
            If ListBox1.Selected(i) Then
                Sheets("In").Cells(sat, "B") = ListBox1.List(i, 0)
                Sheets("In").Cells(sat, "C") = ListBox1.List(i, 1)
                sat = sat + 1
            End If
        Next
    Application.ScreenUpdating = True
    Sheets("In").Activate
End Sub

Private Sub TextBox1_Change()
    Set con = VBA.CreateObject("adodb.Connection")
    con.Open "provider=microsoft.ace.oledb.12.0;data source=" & _
    ThisWorkbook.FullName & ";extended properties=""Excel 12.0;hdr=yes"""
    
    sorgu = "select * from [Data$A:E] where [Stok Kodu] like '%" & TextBox1.Text & "%' or [Stok Adi] like '%" & TextBox1.Text & "%'"
    Set rs = con.Execute(sorgu)
    If Not rs.EOF And Not rs.bof Then
        ListBox1.Column = rs.getrows
    Else
        ListBox1.Clear
    End If
End Sub

Private Sub UserForm_Initialize()
    ListBox1.ColumnCount = 5
    ListBox1.ColumnWidths = "120;180;60;60;60"
    ListBox1.SetFocus
      
    Set con = VBA.CreateObject("adodb.Connection")
    con.Open "provider=microsoft.ace.oledb.12.0;data source=" & _
    ThisWorkbook.FullName & ";extended properties=""Excel 12.0;hdr=yes"""
    
    sorgu = "select * from [Data$A:E] where [Stok Kodu] is not null"
    Set rs = con.Execute(sorgu)
    
    ListBox1.Column = rs.getrows
End Sub

 

[HarEndu]

Harikasiniz Yusuf bey, nasil tesekkur edecegimi bilemiyorum. Omrunuze bereket olsun ins.

 

[HarEndu]

peki bir sey daha, dosya onedirve olan bilgisyarlarda calismadi, bunun icin uzg. Onedriver olan bilgisayarda da calismasi icin kodlarda nasil bir degisiklik yapabilirim.