Koşullu RANK Formülü

[vivident]

Merhaba

RANK formülü içine koşul yazılabilinir mi ?

Ekteki dosyada A sütununda koşulsuz ve tekrarsız RANK formülü uygulaması yaptım. Fakat ben koşul kullanmak istiyorum.

Yardımlarınızı bekliyorum

 

[Erdem Akdemir]

Merhaba,

Kod 200, hat 20 dışındakiler nasıl sıralanacak, örnek bir sıralama gösterebilir misiniz.?

 

[vivident]

Sıralanmasın. Koşulu sağlamayan satırlar boş kalabilir. ("") Sadece koşulu göre sıralama yapsın

 

[vivident]

Konu günceldir

 

[Erdem Akdemir]

Dosyanız ektedir.

=EĞERHATA(KAÇINCI(F8;BÜYÜK(EĞER($E$5:$E$10=$L$2;EĞER($B$5:$B$10=$L$3;$F$5:$F$10;0);0);SATIR($F$1:$F$43));0);"")

 

[vivident]

Kodu 800 yaptım
21 ve 22 nolu satırların ikisindede "1" rakamı çıktı. Sanırım aynı süreyi gördüğünde problem yaşandı. Hata ile ilgili dosya ekte

 

[Erdem Akdemir]

Merhaba,

Dizi formülüdür.

=İNDİS(EĞER($B$5:$B$43=$L$3;EĞER($E$5:$E$43=$L$2;KAÇINCI(F5;BÜYÜK(EĞER($E$5:$E$43=$L$2;EĞER($B$5:$B$43=$L$3;$F$5:$F$43;0);0);SATIR($F$1:$F$43));0);"");"");SATIR(F5)-4)

 

[vivident]

Çok teşekkürler, elinize sağlık, süper olmuş

 

[vivident]

Yalnız bişey soracağım, öğrenmek amacı ile

SATIR($F$1:$F$43) Neden F1'den başlıyor,
Örneğin onu F4'den itibaren SATIR($F$4:$F$43) yapınca bozuluyor. Fark nedir ?

 

[Erdem Akdemir]

Formülün o kısmı Büyük fonksiyonu için yazıldı. SATIR(1:43) ile oluşan dizinin en büyük sayılarını sıralı istiyorum. Satır(4:43) yaparsanız 4.büyük sayıdan itibaren değerleri getirir.

 

[Erdem Akdemir]

=İNDİS(EĞER($B$5:$B$43=$L$3;EĞER($E$5:$E$43=$L$2;KAÇINCI(F5;BÜYÜK(EĞER($E$5:$E$43=$L$2;EĞER($B$5:$B$43=$L$3;$F$5:$F$43;0);0);SATIR($F$1:$F$43));0);"");"");SATIR(F5)-4)

Bu formülün içten dışa doğru yapısını anlatmak istiyorum.

Kod: 800 Hat:20 olduğunu düşünürsek,

Formülün en iç kısmı yani başlangıcı aşağıdaki kısım.

EĞER($E$5:$E$43=$L$2;EĞER($B$5:$B$43=$L$3;$F$5:$F$43;0);0), burada şartlarımıza uyan sayıları istiyoruz ve {0\0\0\0\0\2,83\0\0\0\0\0\0\0\0\0\0\0\27,38\0\0\5,04\0\0\0\0\0\0\0\0\0\0\0\0\0\0\0\0\0\0} excel bize böyle bir dizin veriyor.

Bu oluşan dizini BÜYÜK(EĞER($E$5:$E$43=$L$2;EĞER($B$5:$B$43=$L$3;$F$5:$F$43;0);0);SATIR($F$1:$F$43)) formülü ile büyükten küçüğe sıralıyoruz ve excel bize
{27,38\5,04\2,83\0\0\0\0\0\0\0\0\0\0\0\0\0\0\0\0\0\0\0\0\0\0\0\0\0\0\0\0\0\0\0\0\0\0\0\0\#SAYI!\#SAYI!\#SAYI!\#SAYI!} dizinini veriyor.

KAÇINCI(F5;BÜYÜK(EĞER($E$5:$E$43=$L$2;EĞER($B$5:$B$43=$L$3;$F$5:$F$43;0);0);SATIR($F$1:$F$43));0) bu formül ile yukarda oluşan dizinin süre sütunundaki sayılara göre sıra numarısını öğrenmek istiyoruz. Daha önce büyükten küçüğe sıralattığımız için kaçıncı formülü ile bulacağımız sıra aslında bize sayının büyüklük sırasını da verecektir.

en baştaki EĞER($B$5:$B$43=$L$3;EĞER($E$5:$E$43=$L$2 ile sadece şartlara uyanlar için kaçıncı formülünü çalıştırıyoruz. bunu yapmazsak aynı sürede olan bütün değerler için formül çalışır.EĞER($B$5:$B$43=$L$3;EĞER($E$5:$E$43=$L$2;KAÇINCI(F21;BÜYÜK(EĞER($E$5:$E$43=$L$2;EĞER($B$5:$B$43=$L$3;$F$5:$F$43;0);0);SATIR($F$1:$F$43));0);"");"") değer olan bir hücrede {""\""\""\""\""\3\""\""\""\""\""\""\""\""\""\""\""\3\""\""\3\""\""\""\""\""\""\""\""\""\""\""\""\""\""\""\""\""\""} şeklinde bir dizin oluşturur.

Bundan sonra indis'i kullandım olmayan hücrelerde hata değerini vermesin, formüle bir ek yapmamak için.

=İNDİS(EĞER($B$5:$B$43=$L$3;EĞER($E$5:$E$43=$L$2;KAÇINCI(F10;BÜYÜK(EĞER($E$5:$E$43=$L$2;EĞER($B$5:$B$43=$L$3;$F$5:$F$43;0);0);SATIR($F$1:$F$43));0);"");"");SATIR(F10)-4) indis formlü ile yukarıdaki oluşan dizinin 6 sıradadaki değerini istiyorum bu aynı zamanda f5:f43 aralığında f10 hücresinin sıra numarası.

 

[vivident]

Elinize sağlık. Ayrintili şekilde anlatmaniz hem bana hemde benim gibi bu işi öğrenmeye çalışan forum üyelerine çok yardimci olacak. Teşekkürler