Koşula Bağlı Son Verinin ya da Son Üç Verinin Ortalamasının Alınması

[yildirim52]

Merhabalar,

YARIMAMÜL	GERÇEKLEŞEN MALİYET
Armut	2,00
Elma	2,30
Portakal	2,75
Elma	2,45
Armut	3,20
Potakal	3,00
Elma	2,85	Portakal Güncel Fiyatı	?
Portakal	3,25
Elma	3,75

10 çeşit kadar yarımamül üretmekteyiz. Üretilen ürünlerin tarih, miktar, işçilik ve hammadde miktarları verilerini elle giriyoruz. Sonuçta "Gerçekleşen Maliyet" hesaplanmış oluyor. İkinci bir Çalışma Sayfasında ise aynı şekilde Mamüllerimiz var. Burada da tarih, miktar, işçilik, kullanılan yarımamül miktarı, ambalaj malzemesi miktarı verilerini elle giriyoruz. Yarımamül fiyatını otomatik olarak gerçekleşen son maliyet (ya da son üç maliyetin ortalaması) üzerinden getirmek istiyoruz. Bunu nasıl yapabiliriz.

Yukarıdaki örnek tablo üzerinden gidecek olursak ? yazılı yere 3,25 (son fiyat) ya da 3,00 (son 3 fiyatın ortalaması) nasıl getirebiliriz.

Teşekkürler

 

[uzmanamele]

Merhaba

Portakalın Ortalama fiyatı

=ETOPLA($A$2:$A$10;D2;$B$2:$B$10)/EĞERSAY($A$2:$A$10;D2)

Portakalın son fiyatı

=ARA(D2;$A$2:$A$10;$B$2:$B$10)

=KAYDIR(A1;TOPLA.ÇARPIM(MAK(--(D2=$A$2:$A$10)*SATIR($A$2:$A$10)))-1;1)

 

[yildirim52]

Sayfada örneğin 20-30 satır portakal var, ama son 3 tanesinin ortalaması gerekli.

 

[muratboz06]

Aşağıdaki dosyadaki çalışmayı inceleyiniz.

YariMamul.xlsx dosyasını indir - download

YariMamul.xlsx dosyasını indir, download. Dosya.tc .Dosya Upload. Dosya Paylaş. Dosya Yükle

s4.dosya.tc

 

[uzmanamele]

Merhaba

Son 3 portakalın ortalaması

=TOPLA.ÇARPIM(TOPLA(KAYDIR(A1;BÜYÜK(--(D2=$A$2:$A$17)*SATIR($A$2:$A$17);SATIR(1:3))-1;1))/3)

 

[Korhan Ayhan]

Alternatif;

Son 3 Portakal verisinin ortalaması;

DİZİ formüldür.

=ORTALAMA(S(DOLAYLI("B"&BÜYÜK((A2:A13="Portakal")*SATIR(A2:A13);{1;2;3}))))

 

[uzmanamele]

Merhaba

Korhan beyin ortalama fonksiyonu kullanımı hatırlatmasıyla, başka alternatif

=TOPLA.ÇARPIM(ORTALAMA(KAYDIR(A1;BÜYÜK(--(D2=$A$2:$A$17)*SATIR($A$2:$A$17);SATIR(1:3))-1;1)))

 

[yildirim52]

Evet kodlar çalıştı. İlgileriniz için çok teşekkürler.