Klasördeki dosyaların boyu, hazırlanma tarihi nasıl alınır?

[Tevfik_Kursun]

Merhaba Arkadaşlar,
Klasördeki dosyaların adını alabiliyorum. Bu dosyaların boyu, hazırlanma tarihi nasıl alınır?
Saygılarımla

 

[Haluk]

Sub ListFiles()
'   Haluk
'   15/10/2018
    Dim myFolder As String
    myFolder = "C:\TestFolder"
    
    Range("A:A").Clear
    Call GetFiles(myFolder, True)
End Sub
'
Sub GetFiles(SourceFolder As String, IncludeSubFolders As Boolean)
    Dim FSO As Object, strFolder As Object
    Dim SubFolder As Object, strFile As Object
    Dim i As Long
    
    Set FSO = CreateObject("Scripting.FileSystemObject")
    Set strFolder = FSO.GetFolder(SourceFolder)
    
    
    i = Range("A" & Rows.Count).End(xlUp).Row + 1
    Range("A" & i) = strFolder.Name
    Range("A" & i).Font.Bold = True
    Range("A" & i).Font.Color = vbRed
    i = i + 1
    
    For Each strFile In strFolder.Files
        Range("A" & i) = FSO.GetBaseName(strFile.Name)
        Range("A" & i).Hyperlinks.Add Range("A" & i), strFile, , "Dosyaya ulasmak icin tiklayin"
        Range("B" & i) = FSO.GetFile(strFile).DateCreated
        Range("C" & i) = FSO.GetFile(strFile).Size
        
        i = i + 1
    Next
    
    If IncludeSubFolders = True Then
        For Each strFolder In strFolder.SubFolders
            GetFiles strFolder.Path, True
        Next
    End If
    
    Columns(1).AutoFit
    Set strFolder = Nothing
    Set FSO = Nothing
End Sub

.

 

[Tevfik_Kursun]

Sayın Haluk Hocam,
İlginize çok teşekkür ederim. Sanırım bir yerde eksiklik yaptım.
Saygılarımla

 

[ÖmerFaruk]

Haluk beyin kodlarında şu satıra dikkat edin.
myFolder = "C:\TestFolder"

Buraya kendi klasörünüzü belirtmelisiniz.

 

[Tevfik_Kursun]

Harikasın Arkadaşım,
Çok teşekkür ederim.
Saygılarımla

 

[Tevfik_Kursun]

Çok teşekkür ederim Haluk Hocam,
Az önce hastaneden geldim. Pek çok şeye dikkat edemiyorum. Kusuruma bakmayın lütfen.
Yine de şunu sormak istiyorum. Örneğin klasörde Tnm_A0121.pdf adlı dosya var mı, varsa tarihi ve boyutunu öğrenmek istiyorum.
Saygılarımla

 

[Haluk]

Geçmiş olsun Tevfik Bey;

Sub Test()
'   Haluk - 14/06/2022
    Dim FSO As Object, strFile As String
    
    strFile = "C:\TestFolder\Tnm_A0121.pdf"
    
    Set FSO = CreateObject("Scripting.FileSystemObject")
    
    If FSO.FileExists(strFile) Then
        MsgBox FSO.GetFile(strFile).Size & " bytes"
        MsgBox FSO.GetFile(strFile).DateCreated
    Else
        MsgBox strFile & " bulunamadi!"
    End If
    
    Set FSO = Nothing
End Sub

.

 

[Tevfik_Kursun]

Sayın Haluk Hocam,
Sağlık dilekleriniz ve destekleriniz için çok teşekkür ederim. Çok makbule geçti.
Saygılarımla

 

[Haluk]

Saygı bizden Tevfik Bey,

Umarım önemli bir durum yoktur ve sadece rutin bir kontroldur...

.

 

[Tevfik_Kursun]

Sayın Haluk Hocam,
İlginize tekrar teşekkür ederim. Yaş ilerleyince rutin kontrollerde nelerin çıkacağı çok belli olmuyor, maalesef.
Saygılarımla

 

[Korhan Ayhan]

Geçmiş olsun.

 

[Tevfik_Kursun]

Sayın Korhan Hocam,
İlginize çok teşekkür ederim
Saygılarımla