Soru Klasör adını almak

[k0081]

Merhaba arkadaşlar;

Excel tablomda ; D3 : D150 arasında bu şekilde path yazıları var.

K:\aaa\bbbb\cccc\3000 MERDIVEN
K:\aaa\bbbb\cccc\BALKON01
K:\aaa\bbbb\cccc\KASA
K:\aaa\bbbb\cccc\VARIL4
K:\aaa\bbbb\cccc\PORTATIF MANGAL
...


A3 : A150 arasına bu şekilde , Path de yazan son kalsör adını Command buton ile D3 : D150 aralığındaki referansdan alarak yazdırabilir miyiz?

3000 MERDIVEN
BALKON01
KASA
VARIL4
PORTATIF MANGAL
...



yardımcı arkadaşa şimdiden Teşekkürler.

Herkese Mutlu Yıllar Dilerim...

 

[işsiz123]

Merhabalar aşağıdaki kodu deneyebilirsiniz.

Sub bol()

Dim a As Long
For a = 1 To Cells(1, 4).End(xlDown).Row
Sheets("Sayfa1").Range("A" & a).Value = Split(Sheets("Sayfa1").Range("D" & a).Value, "\")(4)
Next

End Sub

 

[Haluk]

"Google Sheets" ile alternatif;



.

 

[Zeki Gürsoy]

p = "K:\aaa\bbbb\cccc\3000 MERDIVEN"
MsgBox CreateObject("Scripting.FileSystemObject").GetBaseName(p)

 

[Murat OSMA]

Alternatif;

Sub Osma()
    For i% = 3 To 150
        adres$ = Cells(i, 1).Value
        Cells(i, 4) = Mid(adres, InStrRev(adres, "\") + 1, Len(adres))
    Next i
End Sub

 

[Haluk]

3 No'lu mesajdaki "Google Sheets" alternatifinin VBA karşılığı;

Sub Test()
    Dim regExp As Object, i As Integer
    Set regExp = CreateObject("VBScript.RegExp")

    regExp.Pattern = "(.+)\\"
  
    For i = 3 To 150
        Range("D" & i) = regExp.Replace(Range("A" & i).Text, "")
    Next
End Sub

.

 

[Korhan Ayhan]

Bu da alternatif olsun;

Option Explicit

Sub Klasor_Adi_Al()
    Dim Son As Long
    
    Son = Cells(Rows.Count, "D").End(3).Row
    
    Range("A3:A" & Rows.Count).ClearContents
    
    With Range("A3:A" & Son)
        .Formula = "=MID(D3,FIND(""|"",SUBSTITUTE(D3,""\"",""|"",LEN(D3)-LEN(SUBSTITUTE(D3,""\"",""""))))+1,255)"
        .Value = .Value
    End With
End Sub

 

[k0081]

işsiz123

bu hatayı veriyor..,

 

[k0081]

Zeki Gürsoy

sadece 1 path için tamamdır... bu tabloda işime yaramayacak ama başka uygulamalarda kullanabilirim. Arşive ekliyorum

Teşekkürler.

 

[k0081]

Murat OSMA

Haluk

-----

iki kodda aynı şekilde çalışıyor. fakat istediğim tam olarak bu değil.. yada ben düzenleyemedim... ( yol aynı zamanda köprü biçiminde...)

Teşekkürler.

 

[k0081]

Korhan Ayhan


Hocam çok Teşekkür ediyorum, Tamamdır...