Kapalı Dosyada "x" adında Sayfa Varmı

[mozdem]

Aktif dosyamda istediğim isimde sayfanın bulunup,bulunmadığını aşağıdaki kodları yazarak kontrol etmiş oluyorum.
Ancak, Aynı klasör içinde bulunan Kapalı bir dosyadaki "x" adında sayfa var mı? Yok mu?
nasıl bir kod yazarak bulabilirim.
Teşekkürler.

'***********************
Sub x_adlı_sayfa_varmı()
Dim Syf As Worksheet
Dim SayfaAd As String
'--------------------------
SayfaAd = "x"
'--------------------------
For Each Syf In Worksheets
If Syf.Name = SayfaAd Then
MsgBox "Var"
GoTo son
End If
Next
MsgBox "Sayfa Yok"
son:
End Sub

'*****************************

 

[Korhan Ayhan]

Merhaba,

Aşağıdaki kodu denermisiniz.

Sub KAPALI_DOSYADA_X_İSİMLİ_SAYFA_VARMI()
    Dim Katalog As Object, Data As Object
    Dim Tablo As Object, Sayfa_Adı As String
    
    Set Data = CreateObject("ADODB.Connection")
    Set Katalog = CreateObject("ADOX.Catalog")
    
    Dosya_Adı = ThisWorkbook.Path & "\VeriDosyam.xls"
    
    Data.Open "Driver={Microsoft Excel Driver (*.xls)};Dbq=" & Dosya_Adı & ";"
    Katalog.ActiveConnection = Data
    
    For Each Tablo In Katalog.Tables
        If InStr(1, Tablo.Type, "TABLE") > 0 Then
            If InStr(1, Tablo.Name, "kaynağından_sorgula") = 0 Then
                If InStr(1, Tablo.Name, "Yazdırma_Alanı") = 0 Then
                    Sayfa_Adı = Replace(Tablo.Name, "'", "")
                    If Right(Sayfa_Adı, 1) <> "_" Then
                        If Right(Sayfa_Adı, 1) = "$" Then
                            If Replace(Sayfa_Adı, "$", "") = "x" Then
                                MsgBox "Sayfa var..."
                                GoTo Son
                            End If
                        End If
                    End If
                End If
            End If
        End If
    Next
    
    MsgBox "Sayfa yok..."

Son:
    Sayfa_Adı = ""
    Set Data = Nothing
    Set Katalog = Nothing
End Sub

 

[mozdem]

Teşekkür

Merhaba,

Aşağıdaki kodu denermisiniz.

Sub KAPALI_DOSYADA_X_İSİMLİ_SAYFA_VARMI()
    Dim Katalog As Object, Data As Object
    Dim Tablo As Object, Sayfa_Adı As String
 ..... ..............................................
.......................................
..................................
    Sayfa_Adı = ""
 End Sub

Korhan Hocam denedim. Süper. Tam istediğim gibi. Çok teşekkür, Ellerinize sağlık.

 

[Murat OSMA]

Korhan Bey, müsadenizle ilave bir bağlantı eklemek istiyorum...

Kapalı excel dosyasında sayfa adı sorgulama

 

[Korhan Ayhan]

Merhaba,

Verdiğiniz linkte artı bilgiler bulunmaktadır. Arkadaşımız için faydalı olabilir. Hatırlatmanız için teşekkür ederim.