kapalı csv dosyasını farklı kaydet ile Excel Çalışma kitabına çevirmek

[burhancavus61]

kapalı csv dosyasını farklı kaydet ile Excel Çalışma kitabına çevirmek mümkünmü. biraz deneme yaptım ama sağlıklı çevirme yapamadım. sistem csv kabul etmediği için orjinal dosyayı sııştırarak ekledim

Sub Dosya_Degis()
    Dim sFileName As String
    sFileName = Application.GetOpenFilename
    Label1 = sFileName
    Application.DisplayAlerts = False
    Workbooks.Open Filename:=sFileName
    ActiveWorkbook.SaveAs Filename:="C:\Users\burhancavus\Downloads\aaa.xlsx", _
        FileFormat:=xlOpenXMLWorkbook, CreateBackup:=False
End Sub

 

[Haluk]

Sub Test()
    'Haluk - 21/04/2022
    'sa4truss@gmail.com
  
    Dim myFile As Variant, newWB As Workbook
  
    Application.ScreenUpdating = False
  
    myFile = Application.GetOpenFilename("CSV Files, *.csv", , "Dosya seçin...")
    If myFile = False Then Exit Sub
  
    Set newWB = Workbooks.Add
  
    With newWB.Sheets(1).QueryTables.Add(Connection:="TEXT;" & myFile, Destination:=newWB.Sheets(1).Range("$A$1"))
        .Name = "myTable"
        .TextFilePlatform = 65001
        .TextFileStartRow = 1
        .TextFileParseType = xlDelimited
        .TextFileSemicolonDelimiter = True
        .TextFileDecimalSeparator = ","
        .TextFileThousandsSeparator = "."
        .Refresh BackgroundQuery:=False
    End With
  
    newWB.Connections(1).Delete
    newWB.Sheets(1).QueryTables(1).Delete
  
    fileXL = ThisWorkbook.Path & "\Test.xlsx"
  
    If Dir(fileXL) <> "" Then Kill fileXL
  
    newWB.SaveAs Filename:=fileXL, FileFormat:=xlOpenXMLWorkbook, CreateBackup:=False
    newWB.Close
    Application.ScreenUpdating = True
End Sub

Not: Kod revize edildi....

.

 

[burhancavus61]

Haluk Hocam çok teşekkür ederim çok iyi çalışıyor.

 

[burhancavus61]

Haluk hocam bu makroya ekleme yapabilirmiyiz. Csv xlsx çevirdikten sonra csv yi olduğu konumdan sildirebilirmiyiz.

 

[Haluk]

Aşağıdaki kırmızı ilaveyi yapın ("Kill myFile" satırı);

'   .......

'   ....

    If Dir(fileXL) <> "" Then Kill fileXL

    Kill myFile

.

 

[burhancavus61]

Sağolun hocam