Kaçıncı, Formüle İlave

[1Al2Ver]

Merhaba,

Aşağıdaki dizi formül ile "MEVCUTLAR" sayfası A2:A997 arasındaki tarih verilerini (gg aa yyyy) farklı bir sayfada (AYRINTI isimli sayfa) V2:V13 aralığındaki ay'lara ( Ocak, Şubat...) göre W2 hücresine alabiliyorum,

İsteğim bu verileri ; "MEVCUTLAR" sayfası A2:A997 arasındaki tarih verilerini (gg aa yyyy) farklı bir sayfada (AYRINTI isimli sayfa) V2:V13 aralığındaki ay'lara ve S1'deki yıl'a göre W2 hücresine almak,

Mevcut Dizi Formül ;

=EĞERHATA(TOPLA(EĞER(MEVCUTLAR!$A$2:$A$997<>"";EĞER(AY(MEVCUTLAR!$A$2:$A$997)=KAÇINCI(V3;{"Ocak";"Şubat";"Mart";"Nisan";"Mayıs";"Haziran";"Temmuz";"Ağustos";"Eylül";"Ekim";"Kasım";"Aralık"};0);1)));"")

Denediğim Dizi Formül ;

=EĞERHATA(TOPLA(EĞER(MEVCUTLAR!$A$2:$A$997<>"";EĞER(YIL(MEVCUTLAR!$A$2:$A$997)=KAÇINCI($S$1;{"2017";"2018";"2019"};0);EĞER(AY(MEVCUTLAR!$A$2:$A$997)=KAÇINCI(V2;{"Ocak";"Şubat";"Mart";"Nisan";"Mayıs";"Haziran";"Temmuz";"Ağustos";"Eylül";"Ekim";"Kasım";"Aralık"};0);1))));"")

Teşekkür ederim.

 

[çıtır]

W2 Kopyalayınız.Aşağı doğru çoğaltınız.

=TOPLA.ÇARPIM((MEVCUTLAR!$A$2:$A$2000<>"")*(METNEÇEVİR(MEVCUTLAR!$A$2:$A$2000;"aaaa")=$V2)*(YIL(MEVCUTLAR!$A$2:$A$2000)=$S$1))

 

[1Al2Ver]

Sayın çıtır merhaba,

Öncelikle duyarlığınız ve çözüm için teşekkür ederim, topla.çarpım ile sonuç almak dışında,

Ben ayrıca ; mesajımdaki formüle ilave yaparak yada düzenleyerek bir çözüm elde etmek ve nerede eksiğim yada hatam var öğrenmek isterim.

Tekrar teşekkür ederim.

Saygılarımla.

 

[çıtır]

Aşağıdaki şekilde deneyiniz.Dizi formülü.

=EĞERHATA(TOPLA(EĞER(MEVCUTLAR!$A$2:$A$997<>"";EĞER(AY(MEVCUTLAR!$A$2:$A$997)*(YIL(MEVCUTLAR!$A$2:$A$997)=$S$1)=KAÇINCI(V2;{"Ocak";"Şubat";"Mart";"Nisan";"Mayıs";"Haziran";"Temmuz";"Ağustos";"Eylül";"Ekim";"Kasım";"Aralık"};0);1)));"")

 

[1Al2Ver]

Sayın çıtır tekrar merhaba,

Teşekkür ederim,

Saygılarımla.

 

[Ömer BARAN]

Merhaba.
Hem alternatif (ikinci formül) , hem de mevcut dizi formülüne ilişkin değişiklik öneresi (birinci formül).

=TOPLA(EĞER(YIL(MEVCUTLAR!$A$2:$A$997)=$S$1;EĞER(AY(MEVCUTLAR!$A$2:$A$997)=SATIR()-1;1)))
=TOPLA.ÇARPIM((YIL(MEVCUTLAR!$A$2:$A$997)=$S$1)*(AY(MEVCUTLAR!$A$2:$A$997)=SATIR()-1))

 

[çıtır]

Sayın çıtır tekrar merhaba,

Teşekkür ederim,

Saygılarımla.

Sayın 1Al2Ver merhaba;
Rica ederim.Dönüş yaptığınız için teşekkür ederim.Bilmukabele.

 

[1Al2Ver]

Sayın Ömer BARAN, merhaba,

Duyarlığınız ve alternatif çözümleriniz için teşekkür ederim, böylece Sayın Çıtır ve sizin yardımlarınızla, 4 farklı çözüme ulaşmış oldum.

Saygılarımla.

 

[Ömer BARAN]

Estağfurullah, alternatif iyidir.
Benim verdiğim dizi formülünde dikkat ederseniz ay adını, ay adları listesinde aramak yerine,
SATIR numarasıyla ay sayısı arasındaki ilişkiden hareket ettim.
Zira sadece belli aylara ait sonuç değil, sırayla 12 aya ait sonucun alınması şeklinde bir düzen vardı.
.