jpeg olarak kaydetme hakk.

[GursoyC]

Merhaba,
forumda bulduğum ve tam benim işimi görecek olan ekli şu jpg kaydetme makrosunda düğmeye bastığımda aynen düğme üzerinde yazdığı gibi işlem yapıyor. Ancak resmi açtığımda bembeyaz sayfa. yani belirlenen aralıktaki hücre içeriklerinden eser yok.
sorun benim excel'imle mi ilgili yardım eder misiniz?

 

[Korhan Ayhan]

Deneyiniz.

C klasörüne kayıt için izin gerekebilir.

Bu sebeple ben aktif dosyanın bulunduğu klasöre kayıt yaptırdım.

Sub Resim_Kaydet()
    Dim Alan As Range, S1 As Worksheet, S2 As Worksheet
    Dim XL_Chart As Chart, XL_Picture As Picture
    Dim Yol As String, Dosya_Adı As String
    
    Application.ScreenUpdating = False
    
    Set S1 = Sheets("Sayfa1")
    Set Alan = S1.Range(S1.Range("A1").Value)
    Yol = ThisWorkbook.Path & "\"
    Dosya_Adı = Yol & S1.Range("A3").Value & ".jpg"
    
    Set S2 = Worksheets.Add
    Charts.Add
    ActiveChart.Location Where:=xlLocationAsObject, Name:=S2.Name
    Set XL_Chart = ActiveChart
    Alan.CopyPicture Appearance:=xlScreen, Format:=xlPicture
    XL_Chart.Paste
    Set XL_Picture = Selection
    
    With XL_Chart.Parent
        .Border.LineStyle = 0
        .Width = Alan.Width
        .Height = Alan.Height
    End With
    
    XL_Chart.Export Filename:=Dosya_Adı, FilterName:="jpg"
    
    Application.DisplayAlerts = False
    S2.Delete
    Application.DisplayAlerts = True
    
    'Kill ThisWorkbook.Path & "\Resim.jpg"
    Application.ScreenUpdating = True
    
    MsgBox "İşleminiz tamamlanmıştır."
End Sub

 

[GursoyC]

Korhan bey cevabınız için teşekkür ederim, gayet güzel çalışıyor.
Yalnız resmi küçük çekiyor. Yani excel'in kopyala\resim olarak kopyala komutundaki gibi değil.
çektiği fotoyu biraz büyütmek için yapılabilecek bir şey var mıdır?

 

[GursoyC]

Korhan bey, gerek kalmadı. Hücreleri ve font değerlerini büyüterek çözdüm.
Tekrar teşekkür ederim.