illere göre ilçelerini yazsın

[me68met]

Arkadaşlar iyi çalışmalar, yapmaya çalıştığım programda userform üzerinde bulunan combobox1 e excel sayfamdan il adlarını çekiyorum ama combobox2 ye, combobox1 e çektiğim ile ait ilçeleri nasıl çektirebilirim. excel sayfamda illere göre ilçe adlarıda mevcut yardımcı okursnız sevinirim. Teşekkürler

 

[Necdet]

Merhaba,

örnek dosya ekler misiniz?

 

[me68met]

örnek dosya ekledim. Teşekkürler

 

[Necdet]

Merhaba,

Private Sub UserForm_Initialize()
Dim i   As Integer, _
    s1  As Worksheet
    Set s1 = Sheets("Sayfa1")
    
    For i = 1 To s1.Cells(Rows.Count, "A").End(3).Row
        ComboBox1.AddItem s1.Cells(i, "A")
    Next i
End Sub

Private Sub ComboBox1_Change()
    Dim c   As Range, _
        s1  As Worksheet, _
        Adr As String
    ComboBox2.Clear
    
    Set s1 = Sheets("Sayfa1")
    
    With s1.Range("C:C")
        Set c = .Find(ComboBox1.Value, LookIn:=xlValues)
        If Not c Is Nothing Then
            Adr = c.Address
            Do
                ComboBox2.AddItem s1.Cells(c.Row, "D")
                Set c = .FindNext(c)
            Loop While Not c Is Nothing And c.Address <> Adr
        End If
    End With
End Sub

 

[me68met]

sayın Necdet Bey çok çok teşekkür ederim. Tam istediğim gibi