İki Sayfa Arasındaki Değerleri Karşılaştırma

[arestos]

Merhaba Arkadaşlar;

Forumda daha önce açılmış konulara göz attım ancak şöyle bir şey söz konusu. Çalıştığım şirkette iki farklı fabrika olduğu için iki farklı hesap var. Muhasebe programı olarakta netsis kullanıyoruz. x fabrikamız için olan netsis hesabındaki firmalara açılan cari kodların y fabrikamızda olan netsis hesabındaki cari kodlarla eşit olmasını sağlamak için firmaları ve cari kodları exel sayfasına döktüm ancak tek tek cari kodları ve firma isimlerini gözle takip etmek çok zor.2000'in üzerinde kod var. Benim istegim exel tablosunda a2'de cari kodlar b2'de firma isimleri. x fab.'sı sayfa 1'de y fab. sayfa 2'de. Sayfa 3'e x fab.'sının 15. sırasındaki cari kod atıyorum 102-001-002 firma ise a firması y fab. 102-001-002 cari kodunda b firması yer alıyor. Sayfa 3'te Cari Kodu DOĞRU Firma ismi YANLIŞ şeklinde göstermesini sağlamak.

Şimdiden Yardımlarınız için çok teşekkür ederim.

 

[Ömer]

Merhaba,

Sorunuzu destekleyen küçük bir örnek dosya eklermisiniz..

.

 

[arestos]

Üstad Ekte ufak bir şekilde gösterdim..

 

[Ömer]

Birebir karşılaştırma mı istiyorsunuz. Eklediğiniz tabloyu tekrar düzenleyerek Sayfa3'ü olmasını istediğiniz gibi manuel hazırlayarak ekleyiniz..

.

 

[arestos]

Buyur üstad. inşallah anlaşılır olmuştur..

 

[Ömer]

H1 hücresini adet sayısını bulalım. Sayımı bu hücreden almamızdaki neden diğer hücrelerdeki formülleri daha hızlı çalışması içindir.

H1: ( Dizi formülüdür )

=TOPLA(EĞER(Sayfa1!$A$2:$A$50<>Sayfa2!$A$2:$A$50;1))

------------------------------------------------------------------------------------------------

A2: ( Dizi formülüdür )

=EĞER(SATIRSAY($A$2:A2)>$H$1;"";İNDİS(Sayfa1!$A$2:$A$50;KÜÇÜK(EĞER(
  Sayfa1!$A$2:$A$50<>Sayfa2!$A$2:$A$50;SATIR(Sayfa1!$A$2:$A$50)
   -SATIR(Sayfa1!$A$2)+1);SATIRSAY($A$2:A2))))

B2: ( Dizi formülüdür )

=EĞER(SATIRSAY($B$2:B2)>$H$1;"";İNDİS(Sayfa2!$A$2:$A$50;KÜÇÜK(EĞER(
  Sayfa1!$A$2:$A$50<>Sayfa2!$A$2:$A$50;SATIR(Sayfa1!$A$2:$A$50)
   -SATIR(Sayfa1!$A$2)+1);SATIRSAY($B$2:B2))))

C2: ( Dizi formülüdür )

=EĞER(SATIRSAY($C$2:C2)>$H$1;"";İNDİS(Sayfa1!$B$2:$B$50;KÜÇÜK(EĞER(
  Sayfa1!$A$2:$A$50<>Sayfa2!$A$2:$A$50;SATIR(Sayfa1!$A$2:$A$50)
   -SATIR(Sayfa1!$A$2)+1);SATIRSAY($C$2:C2))))

D2: ( Dizi formülüdür )

=EĞER(SATIRSAY($D$2:D2)>$H$1;"";İNDİS(Sayfa2!$B$2:$B$50;KÜÇÜK(EĞER(
  Sayfa1!$A$2:$A$50<>Sayfa2!$A$2:$A$50;SATIR(Sayfa1!$A$2:$A$50)
   -SATIR(Sayfa1!$A$2)+1);SATIRSAY($D$2:D2))))

E2:

=A2=B2

F2:

=C2=D2

(Dizi Formülü): Bu not yazdığım hücrelere formülleri girerken önce formülü hücreye kopyalayın entera basmadan ctrl + shift + enter tuş kombinasyonu ile formülün girişini tamamlayını. Bu işlemden sonra formülün başına ve sonuna { } ayıraçları otomatik eklenecektir.

Kopyalama işleminden sonra;

A2:F2 arasını fare ile seçin ve alt satırlara kopyalayınız..

.

 

[arestos]

Günaydın üstad.

Sizin yazdığınız formülü denedim.Ancak aşağı satırlara uyguladığımda böyle birşey söz konusu..Peki şöyle bir şey yapmamız mümkünmüdür.? Sayfa 1'deki Cari Kodu Atıyorum 120-000-001 ve Cari İsmi A Firması. Sayfa 2'deki 120-000-001 Cari koduna hangi cari ismi geliyorsa sayfa 1'de cari isminin yanına çektirip ondan sonra karşılaştırmak.. Böyle birşey mümkünmü.?

 

[Ömer]

E2:

=eğer(a2="";"";a2=b2)


f2:

=eğer(a2="";"";c2=d2)

.

 

[arestos]

üstad tam anlamıyla istediğim bu değil.ekte görsel olarak anlatmaya calıştım..

 

[arestos]

Konu hala güncel...!

 

[Ömer]

Dosyayı tamamen değiştirmişsiniz.

Düşeyara fonksiyonu işinizi görür sanırım.

Excel Dersanesi bölümünde düşeyara ile ilgili konuyu bulup incelemenizi tavsiye ederim.

.