IE Web Girisini Chrome ye Cevirmede Yardim

[barmen2169]

Selamun aleyküm arkadaşlar. Aşağıda hazırlamış olduğum kodlar sorunsuz bir şekilde çalışmaktadır. Yapmak istediğim bu kodları internet explorer'dan değil de Google Chrome 'dan yaptırmak. Bir kaç kod buldum Chrome web sayfası açmak için fakat, veri girişi kodlarında düzenleme yapamıyorum. Yardım ederseniz çok sevinirim. Şimdiden teşekkürler...

Function FnWait(intTime)
    newHour = Hour(Now())
    newMinute = Minute(Now())
    newSecond = Second(Now()) + intTime
    waitTime = TimeSerial(newHour, newMinute, newSecond)
    Application.Wait waitTime
End Function

Sub YTBS_Giris()
Dim URL As String
Dim HTML_Body As Object
Dim IE As Object
Dim Satir As Integer

URL = "http://ytbs.teias.gov.tr/ytbs/frm_login.jsf"
Set IE = CreateObject("InternetExplorer.Application")
Satir = Range("E7").Value

With IE
.Navigate URL
.Visible = True
End With

Do Until IE.ReadyState = 4: DoEvents: Loop
Do While IE.Busy: DoEvents: Loop
IE.Document.all("loginForm:username").Value = "username"
IE.Document.all("loginForm:password").Value = "password"
IE.Document.all("loginForm:btnLogin").Click

Do Until IE.ReadyState = 4: DoEvents: Loop
Do While IE.Busy: DoEvents: Loop
Call FnWait(4)
IE.Document.getElementByID("form:verigiris").Click

Do Until IE.ReadyState = 4: DoEvents: Loop
Do While IE.Busy: DoEvents: Loop
Call FnWait(4)

      Range("B" & Range("E7").Value).Select
      ' Do döngüsünü boş hücreye ulaşıldığında duracak şekilde ayarla.
      Do Until IsEmpty(ActiveCell)
        IE.Document.getElementByID("veriGirisForm:kopyaAlani").Value = FormatNumber(Range("b" & Satir).Value, 2) + " " + FormatNumber(Range("C" & Satir).Value, 2) + " " + FormatNumber(Range("D" & Satir).Value, 2)
        IE.Document.getElementByID("veriGirisForm:j_idt184").Click
        Do Until IE.ReadyState = 4: DoEvents: Loop
        Do While IE.Busy: DoEvents: Loop
        IE.Document.getElementByID("veriGirisForm:dtVeriGiris:j_idt208").Click
         ' Geçerli konumdan 1 satır aşağı git.
        ActiveCell.Offset(1, 0).Select
        Satir = Satir + 1
        Call FnWait(5)
      Loop
    
Do Until IE.ReadyState = 4: DoEvents: Loop
Do While IE.Busy: DoEvents: Loop

Set IE = Nothing
Set HTML_Body = Nothing

MsgBox ("Veri Girişi Tamamlandı..")

End Sub

 

[Asri]

Selenimum vba eklentisi ile farklı bir browser kullanabilir siniz.
Linkteki örnek kodlarda "firefox" yerine "chrome" yazdığımda kodlar çalıştı.

Firefox da sürüm sorunu olabilir.

http://www.makeuseof.com/tag/how-to-automate-firefox-or-chrome-with-vba-and-selenium/

 

[Asri]

Aşağıdaki kodlar Chrome için kullanıcı adı ve şifresine bilgileri yazdıktan sonra giriş butonunu tıklayıp , ekranın resmi çekip excel e yapıştırır.

Deneme amaçlıdır.

    Public Sub chrome_giris()
       Dim selenium As New SeleniumWrapper.WebDriver
       selenium.Start "chrome", "http://ytbs.teias.gov.tr/ytbs/frm_login.jsf"""
       selenium.Open "/"
       selenium.Type "name=loginForm:username", "adisoyadi"
       selenium.Type "name=loginForm:password", "sifre"
       selenium.Click "name=loginForm:btnLogin"
       selenium.Wait 1000
       selenium.getScreenshot().Copy
       selenium.stop
       Sheets(1).Range("A10").PasteSpecial       'Paste the screenshoot at range A10
    End Sub