Hücreden 2 Comboboxa Veri Nasıl Çekebilirim ?

[gamisaga]

Öncelikler herkese selam, Takıldığım bir noktada yardımlarınıza ihtiyacım var.

Yapmak istediğim şey UserForma eklediğim iki Açılırkutuya Hücrelerden veri eklemek. UserForm aktif olduğunda Açılır Kutu1 in içine A kolonundaki boşluk hariç yazılı olan değerleri Atması,

Açılır Kutu bir, Ahmet, Mehmet, Hakkı ve Deneme değerlerini attıktan sonra içinden seçtiğim bir ismin yanında yazan değerleri yani B C D E.... XX kolonları gibi 2.ci açılır kutuma yazdırmak. Derdimi tam olarak anlatamamış olabilrim. Birde ekran görüntüsünde yapmak istediğim şeyi gönderiyorum.

 

[Orion1]

Örnek dosya ekleyiniz.

 

[gamisaga]

Örnek Dosya eklediğimi düşünüyordum sadece resmi eklemişim özür dilerim.

Örnek Dosyada Ekran görüntüsünün olduğu excel ve Userform Üzerinde iki tane Açılır kutu mevcut

 

[Orion1]

Dosyanız ektedir.

Private Sub UserForm_Initialize()
Dim sh As Worksheet, sat As Long, z, hcr As Range
Set sh = Sheets("Sayfa2")
Set z = CreateObject("Scripting.Dictionary")
sat = sh.Cells(sh.Rows.Count, "A").End(xlUp).Row
For Each hcr In sh.Range("A1:A" & sat).SpecialCells(xlCellTypeConstants)
If hcr.Value <> "" And Not z.exists(hcr.Value) Then z.Add (hcr.Value), Nothing
Next
ComboBox1.List = (z.keys)
End Sub


Private Sub ComboBox1_Change()
Dim k As Range, sat As Long, sh As Worksheet
ComboBox2.Clear
Set sh = Sheets("Sayfa2")
sat = sh.Cells(sh.Rows.Count, "A").End(xlUp).Row
Set k = sh.Range("A1:A" & sat).Find(ComboBox1.Value, , xlValues, xlWhole)
If Not k Is Nothing Then
    sut = sh.Cells(k.Row, 256).End(xlToLeft).Column
    If sut > 1 Then
        For i = 2 To sut
            ComboBox2.AddItem sh.Cells(k.Row, i)
        Next
    End If
    
End If
    
End Sub

 

[gamisaga]

Orion1 Çok teşekkür ederim. Gerçekten sağolasın Yardımın için allah razı olsun.