• DİKKAT

    DOSYA İndirmek/Yüklemek için ÜCRETLİ ALTIN ÜYELİK Gereklidir!
    Altın Üyelik Hakkında Bilgi

Hücre içindeki sayıları toplama

Yandex disk dosyasi ile paylasilan dosya ayni degil yanlis degilsem yandex dosyasindaki icin formul istiyorsunuz.
 
Deneyiniz.

J5;

Kod: 
=EĞER(ESAYIYSA(MBUL(" KG";I5));TOPLA.ÇARPIM(--(0&KIRP(YERİNEKOY(PARÇAAL(YERİNEKOY(I5;"KG,";YİNELE(" ";UZUNLUK(I5)));1+((SATIR(DOLAYLI("$1:"&(1+UZUNLUK(I5)-UZUNLUK(YERİNEKOY(I5;"KG,";"")))))-1)*UZUNLUK(I5));UZUNLUK(I5));"KG";""))));TOPLA.ÇARPIM(--KIRP(PARÇAAL(YERİNEKOY(I5;",";YİNELE(" ";UZUNLUK(I5)));1+((SATIR(DOLAYLI("$1:"&(1+UZUNLUK(I5)-UZUNLUK(YERİNEKOY(I5;",";"")))))-1)*UZUNLUK(I5));UZUNLUK(I5)))))
 
Formülü kurgulayan arkadaşlarımızın eline ve zihnine sağlık. Ben sadece küçük dokunuşlar yaptım.
 
Merhaba,

Haluk Bey'in eklediği formül mantığıyla, uzunluğu artırarak ve formülü biraz kısaltarak:

Dizi formülüdür. Girişini ctrl+shift+enter ile yapınız.

Kod: 
=TOPLA(EĞERHATA(--KIRP(PARÇAAL(YERİNEKOY(I5;" ";YİNELE(" ";100))
 ;SATIR(DOLAYLI("1:"&UZUNLUK(I5)))*100-99;100));0))

.
 
Vayyy Vayyy herkesin eline sağlık bilgisine sağlık.

Analar ne excel canavarları doğurmuş, helal olsun :)
 
Aynen Necdet Hocam. Size, Ömer Bey'e, Korhan Bey'e koca bir Maşallah ve ellerinize sağlık yıllardır forumun yükünü çektiniz. Yalnız Haluk Hocam fonksiyon işine el atmasa iyiydi. Yaz makronu ne işin fonksiyonla.
 
Ali' Alıntı:
Aynen Necdet Hocam. Size, Ömer Bey'e, Korhan Bey'e koca bir Maşallah ve ellerinize sağlık yıllardır forumun yükünü çektiniz.
Genişletmek için tıkla ...

Ben de aynen katılıyorum..... İlaveten; Sayın Moderatör Ömer Bey, İdris Bey, Evren Gizlen, Veysel Emre, Asri Akdeniz, Mustafa Altun ve şu anda aklıma gelmeyen ama aktif durumdaki daha bir çok arkadaşa da buradan sevgi ve saygılar

Ali' Alıntı:
Yalnız Haluk Hocam fonksiyon işine el atmasa iyiydi. Yaz makronu ne işin fonksiyonla.
Genişletmek için tıkla ...

İlahi Ali Bey ......Sizler öyle güzel fonksiyonlar yazınca, bizim de canımız çekiyor .... bir şeyler karalıyoruz işte ... :biggrin:


.
 
Son düzenleme:
Herkesin ellerinize, zihnine sağlık. :)
Ali abi'nin de belirttiği gibi; yıllardır forumun neredeyse tüm yükünü siz çektiniz, bu platformun bu seviyeye gelmesinde büyük emeğiniz var. :bravo:
Hepiniz bu alandaki bilgi birikiminizle ve gösterdiğiniz özveri ile saygıyı sonuna dek hak ediyorsunuz..


Konuya dönecek olursak, bir örnek de ben paylaşmak isterim..

A1 hücresindeki verinin formatı bu şekilde olursa; 36,36 kg,25 kg,65,45 kg,45 kg, aşağıdaki formül de alternatif olarak kullanılabilir.

Saygılar

Kod: 
[SIZE="2"]=TOPLA.ÇARPIM(--PARÇAAL(YERİNEKOY(A1;"kg,";YİNELE(" ";UZUNLUK(A1)));(SATIR(DOLAYLI("1:"&(UZUNLUK(A1)-UZUNLUK(YERİNEKOY(A1;" kg,";"")))/4))-1)*UZUNLUK(A1)+1;UZUNLUK(A1)))[/SIZE]
​
 
dosya içindeki vb kodu ile yapılan çözüm işime yaradı. ayrıca, ayıraç için kendiniz belirleme yapmanız çok güzel bir çözüm olmuş. elinize sağlık teşekkürler.
 
Ali' Alıntı:
A1 hücrenize 125-89 gibi bir ifade olsun

Bunun sonucu 125+89=214 olarak B1 hücresinde toplanmış olarak görmek için B1 hücrenize

Kod: 
=SOLDAN(A1;BUL("-";A1;1)-1)+PARÇAAL(A1;BUL("-";A1;1)+1;UZUNLUK(A1))

yazın.
Genişletmek için tıkla ...
Ali' Alıntı:
A1 hücrenize 125-89 gibi bir ifade olsun

Bunun sonucu 125+89=214 olarak B1 hücresinde toplanmış olarak görmek için B1 hücrenize

Kod: 
=SOLDAN(A1;BUL("-";A1;1)-1)+PARÇAAL(A1;BUL("-";A1;1)+1;UZUNLUK(A1))

yazın.
Genişletmek için tıkla ...

ALİ BEY MERHABALAR;
YAZMIŞ OLDUĞUNUZ FORMULÜ UYGULADIM İŞE YARADI FAKAT AYNI HÜCRE İÇERİSİNDEN İKİDEN FAZLA SAYI OLUNCA HATA VERİYOR.
10-56-89-50-63-80 GİBİ YANYANA ÇOKLU DEĞERLERİ NASIL TOPLAYABİLİRİM.BU FORMULE NASIL UYARLAYABİLİRİZ?
YARDIMCI OLABİLİRMİSİNİZ.
TEŞEKKÜRLER KOLAY GELSİN.
 
Hücredeki sayılar bu şekilde ise

Kod: 
=TOPLA.ÇARPIM(--KIRP(PARÇAAL(YERİNEKOY(A1;"-";YİNELE(" ";UZUNLUK(A1)));1+((SATIR(DOLAYLI("$1:"&(1+UZUNLUK(A1)-UZUNLUK(YERİNEKOY(A1;"-";"")))))-1)*UZUNLUK(A1));UZUNLUK(A1))))

formülü denermisiniz.
 
Ali' Alıntı:
Hücredeki sayılar bu şekilde ise

Kod: 
=TOPLA.ÇARPIM(--KIRP(PARÇAAL(YERİNEKOY(A1;"-";YİNELE(" ";UZUNLUK(A1)));1+((SATIR(DOLAYLI("$1:"&(1+UZUNLUK(A1)-UZUNLUK(YERİNEKOY(A1;"-";"")))))-1)*UZUNLUK(A1));UZUNLUK(A1))))

formülü denermisiniz.
Genişletmek için tıkla ...
önerdiğiniz formül çalışmadı ali bey.değerleri örnek olarak vermiştim. gün içerisinde aynı hücre içerisine depodan alınan malzeme kg leri yazılacak.(425+910+300+275+400 gibi. enaz 15değer yazılcaktır. değerler örnektir)aynı hücre içerisinde yazılı olan bu değerlerin hepsinin toplanıp başka bir hücrede toplamını görmek istiyorum.yardımcı olabilirmisiniz.
teşekkürler.
 
Örneğimizi görmedim tahmini yazınca bu kadar oluyor.
 
İlk örneğinizde sayıların arasında (-) kullanmışsınız. Sonraki mesajınızda ise (+) kullanarak örneklemişsiniz.

Ali beyin önerisindeki (-) sembolünü (+) olarak değiştirirseniz formül sonuç verecektir.

A1 hücresindeki veriye göre çalışır.

Kod: 
=TOPLA.ÇARPIM(--KIRP(PARÇAAL(YERİNEKOY(A1;"+";YİNELE(" ";UZUNLUK(A1)));1+((SATIR(DOLAYLI("$1:"&(1+UZUNLUK(A1)-UZUNLUK(YERİNEKOY(A1;"+";"")))))-1)*UZUNLUK(A1));UZUNLUK(A1))))
 
Ali' Alıntı:
Örneğimizi görmedim tahmini yazınca bu kadar oluyor.
Genişletmek için tıkla ...
Korhan Ayhan' Alıntı:
İlk örneğinizde sayıların arasında (-) kullanmışsınız. Sonraki mesajınızda ise (+) kullanarak örneklemişsiniz.

Ali beyin önerisindeki (-) sembolünü (+) olarak değiştirirseniz formül sonuç verecektir.

A1 hücresindeki veriye göre çalışır.

Kod: 
=TOPLA.ÇARPIM(--KIRP(PARÇAAL(YERİNEKOY(A1;"+";YİNELE(" ";UZUNLUK(A1)));1+((SATIR(DOLAYLI("$1:"&(1+UZUNLUK(A1)-UZUNLUK(YERİNEKOY(A1;"+";"")))))-1)*UZUNLUK(A1));UZUNLUK(A1))))
Genişletmek için tıkla ...

YARDIMLARINIZ İÇİN ÇOK TEŞEKKÜRLER KORHAN BEY İŞE YARADI FORMÜL ÇALIŞIYOR.
ÇOK MAKBULE GEÇTİ TEKRAR TEŞEKKÜRLER.
 
Korhan Ayhan' Alıntı:
İlk örneğinizde sayıların arasında (-) kullanmışsınız. Sonraki mesajınızda ise (+) kullanarak örneklemişsiniz.

Ali beyin önerisindeki (-) sembolünü (+) olarak değiştirirseniz formül sonuç verecektir.

A1 hücresindeki veriye göre çalışır.

Kod: 
=TOPLA.ÇARPIM(--KIRP(PARÇAAL(YERİNEKOY(A1;"+";YİNELE(" ";UZUNLUK(A1)));1+((SATIR(DOLAYLI("$1:"&(1+UZUNLUK(A1)-UZUNLUK(YERİNEKOY(A1;"+";"")))))-1)*UZUNLUK(A1));UZUNLUK(A1))))
Genişletmek için tıkla ...

İyi günler. Formüle + yada - yerine Alt+Enter'ı nasıl yerleştirebiliriz?
Yani tek hücrede bulunan alt alta olan sayıları nasıl toplayabiliriz?

1
5
17
65
183 gibi

Şimdiden teşekkürler.
 
Cevap yazmak için giriş yap yada kayıt ol.
Geri
Üst