hücre içerisindeki kelime

[durhan]

Arkadaşlar A1 hücresinden A4000'e kadar hücrelerde metin yazılarım var, yapmak istediğim şey hücrelerdeki durhan kelimesini bulmak ve herhangi bir renkle işaretlemek, örneğin hücrelerdeki durhan kelimesini bulup kırmızı yapması gibi böyle birşey olabilir mi?

 

[1Al2Ver]

Merhaba,

A1:A4000 aralığını seçiniz

Koşullu Biçimlendirme'den

hücre değeri--eşit-- ="durhan" yazıp biçim butonuna tıklayıp desen'den kırmızıyı seçin

 

[Necdet]

Merhaba,

Aradığınız sözcük hücre içinde tek mi? yoksa tümcenin içinde geçen bir sözcük mü?

Eğer tek sözcük ise Sayın IAl2Ver'in çözümü geçerli, yok eğer tümce içinde geçiyorsa, farklı yöntem bulmak gerek.

Örnek dosya ile sorunuzu desteklemediğiniz için, ne demek istediğinizi anlamakta güçlük çekiyoruz.

 

[durhan]

Sayın 1AI2Ver; hücrede tek başına durhan kelimesi varsa dediğiniz gibi yapıyor, ancak durhan bir cümle içerisinde ise kırmızı yapmıyor, benim yapmak istediğim cümle içerisinde bulunan kelimeyi kırmızı yapmak
Sayın Necdet Yeşertener; "durhan" kelimesi bir cümle içerisinde geçiyor, bu "durhan" olmayıp bir telefon numarasıda olabilir. Örneğin : "bugün durhan bizim eve gelecek, istersen sende ara 0532211111 nolu telefonu kullanıyor" gibi bu cümle içesindeki "durhan" kelimesini kırmızı yapmasını istiyorum.

 

[1Al2Ver]

Sayın 1AI2Ver; hücrede tek başına durhan kelimesi varsa dediğiniz gibi yapıyor, ancak durhan bir cümle içerisinde ise kırmızı yapmıyor, benim yapmak istediğim cümle içerisinde bulunan kelimeyi kırmızı yapmak
Sayın Necdet Yeşertener; "durhan" kelimesi bir cümle içerisinde geçiyor, bu "durhan" olmayıp bir telefon numarasıda olabilir. Örneğin : "bugün durhan bizim eve gelecek, istersen sende ara 0532211111 nolu telefonu kullanıyor" gibi bu cümle içesindeki "durhan" kelimesini kırmızı yapmasını istiyorum.

Sayın durhan, örnek bir dosya eklerseniz çözüm almanız kolaylaşır, Sayın Necdet Yeşertener zaten açıklama yapmıştı,

Teşekkür ederim.

 

[Necdet]

Merhaba,

Aşağıdaki kodlar G1 hücresinde yazılan sözcüğü A sütununda arar, bulursa renklendirir.

Sub SozcukBulRenklendir()
Dim i As Long
Dim Baslangic As Integer, Uzunluk As Integer
Uzunluk = Len([G1])
With Columns("A:A")
    With .Characters
        .Font.Bold = False
        .Font.ColorIndex = 0
        .Font.Italic = False
    End With
End With
For i = 1 To [A65536].End(3).Row
    On Error Resume Next
    Baslangic = 0
    Baslangic = Application.WorksheetFunction.Search([G1], Cells(i, "A"))
    If Baslangic > 0 Then
        With Range("A" & i)
            .Characters(Baslangic, Uzunluk).Font.Bold = True
            .Characters(Baslangic, Uzunluk).Font.ColorIndex = 3
            .Characters(Baslangic, Uzunluk).Font.Italic = True
        End With
    End If
Next i
End Sub

 

[durhan]

Sayın Necdet Yeşertener; elinize sağlık çok güzel olmuş, bu benim işimde büyük kolaylık sağlayacak,
fakat küçük bir istirhamım var,
örneğin "ali" cümle içerisinde birkaç yerde tekrarlanırsa ilk "ali"'yi veriyor, diğerlerini işaretlemiyor, aranan kelimeyi yazıp renklendir butonuna bastığımda cümle içerisinde aranan kelimeden kaçtane varsa onların hepsini renklendirilmesi gibi
Mümkün değilsede önemi yok bu kadarıda benim çok işime yarayacak emeğinize sağlık teşekkürler

 

[Necdet]

Merhaba,

Aşağıdaki kodlar önceki verdiğim kodlara göre biraz daha yavaş çalışacaktır.

Option Explicit
Option Compare Text
Sub SozcukBulRenklendir()
Dim i As Long
Dim Baslangic As Integer, Uzunluk As Integer, j As Integer
Dim Bul As Range
Dim Adres As String, Dizi() As String
Uzunluk = Len([G1])
Application.ScreenUpdating = False
With Columns("A:A")
    With .Characters
        .Font.Bold = False
        .Font.ColorIndex = 0
        .Font.Italic = False
    End With
End With

i = [A65536].End(3).Row
With Range("A1:A" & i)
    Set Bul = .Find([G1], LookIn:=xlValues)
    If Not Bul Is Nothing Then
        Adres = Bul.Address
        Do
            For Baslangic = 1 To Len(Cells(Bul.Row, "A")) - Uzunluk + 1
                If Mid(Cells(Bul.Row, "A"), Baslangic, Uzunluk) = [G1] Then
                    With Range("A" & Bul.Row)
                        .Characters(Baslangic, Uzunluk).Font.Bold = True
                        .Characters(Baslangic, Uzunluk).Font.ColorIndex = 3
                        .Characters(Baslangic, Uzunluk).Font.Italic = True
                    End With
                End If
            Next Baslangic
            Set Bul = .FindNext(Bul)
        Loop While Not Bul Is Nothing And Bul.Address <> Adres
    End If
End With
Application.ScreenUpdating = True
MsgBox "Arama Tamamlandı......", vbOKOnly, "[URL="http://www.excel.web.tr/"]www.excel.web.tr[/URL] Bilgi Paylaşım Merkezi...."
End Sub

 

[durhan]

Sayın Necdet Yeşertener; Aklınıza, fikrinize, elinize, kolunuza sağlık, Allah dert keder vermesin. Saygılarımı arz ediyorum.

 

[Necdet]

Amin. Saygı bizden hemşehrim güle güle iyi günlerde kullanınız.

 

[dahey]

farklı başlık açmaktansa buraya yazmanın daha uygun olacağını düşündüm
benimde isteğim buna benzer
eğer hücrede building sözcüğü varsa, yanındaki hücreye B ya da buna benzer herhangi bir işaret koysun istiyorum
toplam 13500 satırlık bir tabloda aradığım sözcüğün bulunduğu satırların yanındaki boş satıra işaret istiyorum yani

şimdiden teşekkürler