Merhaba arkadaşlar. Uzun bir mesai sonrası exceli mi tamamlamak üzereyim. Fakat bir yerde takıldım. Kısaca şöyle anlatayım. Elimde 19 şehir ismi ve bunların satış rakamları var. Bir formülle bunların ortalamasını aldım ve ortalamanın altında kalan şehir isimlerini başka bir sekmeye alt alta yazdırdım. 19 şehir ismim artık 10 şehir ismine düştü fakat bu rakamlar değişken olduğu için bazen 5 şehir giriyor ortalamanın altına bazen 15 şehir. Ben başka bir hücrede bu şehir isimlerini tek bir hücrede birleştirmek istiyorum. (Örn. Ankara, İstanbul, İzmir ...... Adana ve Kayseri) gibi yazacak. Şehir sayısına bakılmaksızın her şehir sonrasına "," işareti ve son iki şehir arasına da "ve" kelimesini eklemek istiyorum. Bu mümkün müdür? Nasıl yapabilirim. Şimdiden cevap veren veya okuyup yardımcı olmaya çalışan herkese teşekkürler.
-
DİKKAT DOSYA İndirmek/Yüklemek için ÜCRETLİ ALTIN ÜYELİK Gereklidir!
Altın Üyelik Hakkında Bilgi
Formülle gelen şehir isimleri birleştirme
- Konbuyu başlatan Bybr
- Başlangıç tarihi
metinbirleştir formülü ile yababilirisniz.
dosya.co dosya.tc gibi payşalım sitelerine dosyanızı yükleyip link verebilirsiniz.
Şehir isimlerinin A sütununda değerlerin B sütununda olduğunu varsaydım.
Eğer Excel 2021 de LET ve SONRAKİMETİN fonksiyonları bulunuyorsa aşağıdaki kodu kendinize uyarlayın
Eğer Excel 2021 de LET ve SONRAKİMETİN fonksiyonları bulunuyorsa aşağıdaki kodu kendinize uyarlayın
Kod:
=LET(a;METİNBİRLEŞTİR(", ";DOĞRU;FİLTRE(A1:A7;B1:B7>=ORTALAMA(B1:B7)));b;SONRAKİMETİN(a;" ";-2);c;YERİNEKOY(b;",";" ve ");YERİNEKOY(a;b;c))
- Katılım
- 15 Mart 2005
- Mesajlar
- 43,641
- Excel Vers. ve Dili
- Microsoft 365 Tr-En 64 Bit
Bu da alternatif olsun...
Not : Kullandığınız sürüm Türkçe ise formülü çevirmeniz gerekir..
Not : Kullandığınız sürüm Türkçe ise formülü çevirmeniz gerekir..
C++:
=LET(
Filtrelenmiş;FILTER($G$1:$G$20;$F$1:$F$20>AVERAGE($F$1:$F$20));
Uzunluk;COUNTA(Filtrelenmiş);
TEXTJOIN(" ve ";1;TEXTJOIN("; ";1;TAKE(Filtrelenmiş;Uzunluk-1));TAKE(Filtrelenmiş;-1))
)"Let" fonksiyonu var fakat "sonrakimetin" fonksiyonu yok maalesef. Yinde teşekkür ederim zaman harcadınız.
=LET(
Filtrelenmiş;FİLTRE($G$1:$G$20;$F$1:$F$20>ORTALAMA($F$1:$F$20));
Uzunluk;KAÇTANE(Filtrelenmiş);
METİNBİRLEŞTİR(" ve ";1;METİNBİRLEŞTİR("; ";1;AL(Filtrelenmiş;Uzunluk-1));AL(Filtrelenmiş;-1))
)
şeklinde Türkçeye çevirdim fakat "#AD?" yazıyor. Muhtemelen biryerde yanlışlık yapıyorum.
- Katılım
- 15 Mart 2005
- Mesajlar
- 43,641
- Excel Vers. ve Dili
- Microsoft 365 Tr-En 64 Bit
KAÇTANE değil BAĞ_DEĞ_DOLU_SAY olmalı...
Korhan hocam yazmaya çekiniyorum ama yine "#AD?" diyor. Uğraştırdım sizi kusura bakmayın lütfen.
- Katılım
- 15 Mart 2005
- Mesajlar
- 43,641
- Excel Vers. ve Dili
- Microsoft 365 Tr-En 64 Bit
O zaman sizin sürümde olmayan fonksiyon var demektir.
Sırayla aşağıdaki fonksiyonları boş hücreye yazıp deneme yapabilirsiniz.
=LET(
=FİLTRE(
=ORTALAMA(
=BAĞ_DEĞ_DOLU_SAY(
=METİNBİRLEŞTİR(
=AL(
Bunları hücreye yazdığınızda excel fonksiyonların sözdizimini göstermezse sizde bu fonksiyonlar yok demektir.
Sırayla aşağıdaki fonksiyonları boş hücreye yazıp deneme yapabilirsiniz.
=LET(
=FİLTRE(
=ORTALAMA(
=BAĞ_DEĞ_DOLU_SAY(
=METİNBİRLEŞTİR(
=AL(
Bunları hücreye yazdığınızda excel fonksiyonların sözdizimini göstermezse sizde bu fonksiyonlar yok demektir.
Haklısın hocam =AL bende çıkmıyor. Diğerlerinde sorun yok.
- Katılım
- 15 Mart 2005
- Mesajlar
- 43,641
- Excel Vers. ve Dili
- Microsoft 365 Tr-En 64 Bit
Alternatif olarak bunları deneyebilirsiniz.
C++:
=LET(
Filtrelenmiş;FİLTRE($G$1:$G$20;$F$1:$F$20>ORTALAMA($F$1:$F$20));
Uzunluk;BAĞ_DEĞ_DOLU_SAY(Filtrelenmiş);
METİNBİRLEŞTİR(" ve ";1;METİNBİRLEŞTİR(", ";1;İNDİS(Filtrelenmiş;SIRALI(Uzunluk-1)));İNDİS(Filtrelenmiş, Uzunluk))
)
C++:
=LET(
Filtrelenmiş;FİLTRE($G$1:$G$20;$F$1:$F$20>ORTALAMA($F$1:$F$20));
Uzunluk;BAĞ_DEĞ_DOLU_SAY(Filtrelenmiş);
METİNBİRLEŞTİR(" ve ";1;METİNBİRLEŞTİR(", ";1;İNDİS(Filtrelenmiş;SATIR($A$1:İNDİS($A:$A;Uzunluk-1))));İNDİS(Filtrelenmiş;Uzunluk))
)Korhan hocam vermiş olduğunuz 2. alternatif işimi çözdü. Tamda istediğim gibi oldu. Elinize emeğinize sağlık.