formülde sıfır sorunu

[bafralifatih55]

merhaba arkadaşlar
B sütunundaki verileri tekrarsız şekilde listelemek için E sütununda aşağıdaki formülü kullanıyorum. ancak formülü aşağıya doğru çoğalttığında b sütunundaki veriler formülde belirlenen bitişten önce bittiği zaman son veri olarak "sıfır" yazılıyor. bu sorunun önüne nasıl geçebilirim? nasıl bir güncelleme yapmalıyım?
=İNDİS($B$2:$B$15;KAÇINCI(0;EĞERSAY($E$1:E1;$B$2:$B$15);0);0)
teşekkürler.

 

[YUSUF44]

Formül bende 0 değil de #YOK hatası verdi EĞERHATA ile aşağıdaki şekilde hata yerine boş bırakıyor:

=EĞERHATA(İNDİS($B$2:$B$15;KAÇINCI(0;EĞERSAY($F$1:F1;$B$2:$B$15);0);0);"")

 

[bafralifatih55]

Formül bende 0 değil de #YOK hatası verdi EĞERHATA ile aşağıdaki şekilde hata yerine boş bırakıyor:

=EĞERHATA(İNDİS($B$2:$B$15;KAÇINCI(0;EĞERSAY($F$1:F1;$B$2:$B$15);0);0);"")

merhaba yusuf hocam
b sütununu yarım doldurarak deneyebilir misin? bende tam veri girişi yaptığımda hata olmuyor. ancak eksik veri girişi yaptığımda veya formülü çoğalttığımda 0 görünüyor.
deneyebilir misin?

 

[bafralifatih55]

ustatlar
ne yaptıysam olmadı. bir çözüm yok mu?

 

[çıtır]

Aşağıdaki şekilde deneyiniz.Dizi formülü.

=EĞERHATA(İNDİS($B$2:$B$15;KAÇINCI(;EĞER($B$2:$B$15<>"";EĞERSAY($F1:$F1;$B$2:$B$15));0));"")

 

[bafralifatih55]

Aşağıdaki şekilde deneyiniz.Dizi formülü.

=EĞERHATA(İNDİS($B$2:$B$15;KAÇINCI(;EĞER($B$2:$B$15<>"";EĞERSAY($F1:$F1;$B$2:$B$15));0));"")

hocam öncelikle teşekkür ederim.
f1 hücresini kendime göre e1 olarak güncelledim. ancak b sütununda ilk iki kaydı tekrar tekrar alt alta yazıyor. görebilmeniz için dosyayıda ekliyorum.
ilginiz için tekrar çok teşekkürler.

 

[çıtır]

Deneyiniz.Dizi formülü.Not :F2 Hücresine kopyalayınız.Aşağı doğru çoğaltınız.(Hata nedeni İlk F1 in sabitlenmesi unutulmuş)

=EĞERHATA(İNDİS($B$2:$B$15;KAÇINCI(;EĞER($B$2:$B$15<>"";EĞERSAY($F$1:$F1;$B$2:$B$15));0));"")

 

[bafralifatih55]

Deneyiniz.Dizi formülü.Not :F2 Hücresine kopyalayınız.Aşağı doğru çoğaltınız.(Hata nedeni İlk F1 in sabitlenmesi unutulmuş)

=EĞERHATA(İNDİS($B$2:$B$15;KAÇINCI(;EĞER($B$2:$B$15<>"";EĞERSAY($F$1:$F1;$B$2:$B$15));0));"")

merhaba
hocam çok çok teşekkür ederim. süper çalışıyor. konu ile alakalı son bir şey öğrenmek isterim.
bu formülü 100 satır çoğalttım. ben bunu ad olarak tanımlamak istiyorum. sonra veri doğrulamaya bu adı koyacağım. aşağıdaki boş hücrelerin veri doğrulamada görünmemesi için ad tanımlamasını nasıl yapmalıyım?
tekrar teşekkürler.

 

[çıtır]

Ad tanımlama formülünüzü aşağıdaki şekilde düzenleyiniz.Dönüş yaptığınız için teşekkür ederim.

=KAYDIR($F$2;;;TOPLA.ÇARPIM(($F$2:$F$200<>"")*($F$2:$F$200<>0)))

 

[Merhum İdris SERDAR]

.

0 ve hata olmaksızın aşağıdaki formüllerden birini kullanabilirsiniz.

=EĞERHATA(İNDİS($B$2:$B$15; KAÇINCI(0; İNDİS(EĞERSAY($H$1:H1; $B$2:$B$15)+($B$2:$B$15=""); ); 0)); "")

Veya

=EĞERHATA(ARA(2; 1/((EĞERSAY($G$1:G1; $B$2:$B$20)=0)*($B$2:$B$20<>"")); $B$2:$B$20);"")

.

 

[bafralifatih55]

Ad tanımlama formülünüzü aşağıdaki şekilde düzenleyiniz.Dönüş yaptığınız için teşekkür ederim.

=KAYDIR($F$2;;;TOPLA.ÇARPIM(($F$2:$F$200<>"")*($F$2:$F$200<>0)))

hocam merhaba
formül güzel çalıştı. ama kendi dosyamdaki veri ile ilişkilendiremedim. şöyle:
F sütunundaki veriler A sütunundaki verilerin seçimine göre veri doğrulamada görünsün istiyorum. yani A sütununa bağımlı olacak. bu konuda da bana yardımcı olabilirseniz sevinirim.
teşekkürler.

 

[bafralifatih55]

arkadaşlar hayırlı sabahlar.
bu formülleri a sütunundailere göre nasıl bağımlı hale getirebilirim. bu konuda bana yardımcı olabilir misiniz?
teşekkür ederim.