Formül Kısaltma [ Döviz Kuru ]

[tamer42]

Merhabalar,
Ekli dosyada 4 ürün için bir maliyet simülasyonu yapmaya çalışıyorum.,
Piyasa Verileri sayfasında her bir ürünün alışı farklı kurlarda, USD, EUR, TL
Piyasa PB sayfasında ise tek bir döviz kuruna getirmeye çalışıyorum, Dashboard sayfasında B2 hücresinde yazan kur değerine göre;

bunun için Piyasa PB sayfasına aşağıdaki gibi uzun bir formül yazmak zorunda kaldım

bu formülü kısaltmanın bir yöntemi var mıdır?
başka bir sayfada yardımcı olacak çarpanlar hazırlayarak buradaki formülü daha kısa olarak yazmak mümkün müdür?

bu konuda sizlerin yönlendirme ve çözüm öenerilerinize ihtiyacım bulunmakta;

=EĞERHATA(
  EĞER(Dashboard!$D$2="USD";
      EĞER($B7="USD";
          İNDİS('Piyasa Verileri'!$C:$AAA; KAÇINCI($A7; 'Piyasa Verileri'!$A:$A; 0); KAÇINCI(C$1; 'Piyasa Verileri'!$C$1:$AAA$1; 0));
          EĞER($B7="TL";
              İNDİS('Piyasa Verileri'!$C:$AAA; KAÇINCI($A7; 'Piyasa Verileri'!$A:$A; 0); KAÇINCI(C$1; 'Piyasa Verileri'!$C$1:$AAA$1; 0))/C$4;
              İNDİS('Piyasa Verileri'!$C:$AAA; KAÇINCI($A7; 'Piyasa Verileri'!$A:$A; 0); KAÇINCI(C$1; 'Piyasa Verileri'!$C$1:$AAA$1; 0))*C$5/C$4
          )
      );
      EĞER(Dashboard!$D$2="EUR";
          EĞER($B7="EUR";
              İNDİS('Piyasa Verileri'!$C:$AAA; KAÇINCI($A7; 'Piyasa Verileri'!$A:$A; 0); KAÇINCI(C$1; 'Piyasa Verileri'!$C$1:$AAA$1; 0));
              EĞER($B7="TL";
                  İNDİS('Piyasa Verileri'!$C:$AAA; KAÇINCI($A7; 'Piyasa Verileri'!$A:$A; 0); KAÇINCI(C$1; 'Piyasa Verileri'!$C$1:$AAA$1; 0))/C$5;
                  İNDİS('Piyasa Verileri'!$C:$AAA; KAÇINCI($A7; 'Piyasa Verileri'!$A:$A; 0); KAÇINCI(C$1; 'Piyasa Verileri'!$C$1:$AAA$1; 0))*C$4/C$5
              )
          );
          EĞER($B7="TL";
              İNDİS('Piyasa Verileri'!$C:$AAA; KAÇINCI($A7; 'Piyasa Verileri'!$A:$A; 0); KAÇINCI(C$1; 'Piyasa Verileri'!$C$1:$AAA$1; 0));
              EĞER($B7="USD";
                  İNDİS('Piyasa Verileri'!$C:$AAA; KAÇINCI($A7; 'Piyasa Verileri'!$A:$A; 0); KAÇINCI(C$1; 'Piyasa Verileri'!$C$1:$AAA$1; 0))*C$4;
                  İNDİS('Piyasa Verileri'!$C:$AAA; KAÇINCI($A7; 'Piyasa Verileri'!$A:$A; 0); KAÇINCI(C$1; 'Piyasa Verileri'!$C$1:$AAA$1; 0))*C$5
              )
          )
      )
  );
  ""
)

yardımlarınız için şimdiden teşekkürler,
iyi Çalışamalar

 

[Muzaffer Ali]

Merhaba.

=EĞERHATA(
  İNDİS('Piyasa Verileri'!$C:$AAA; KAÇINCI($A7; 'Piyasa Verileri'!$A:$A; 0); KAÇINCI(C$1; 'Piyasa Verileri'!$C$1:$AAA$1; 0)) *
  EĞER(Dashboard!$D$2=$B7; 1;
    EĞER(Dashboard!$D$2="USD";
      EĞER($B7="TL"; 1/C$4; C$5/C$4);
      EĞER(Dashboard!$D$2="EUR";
        EĞER($B7="TL"; 1/C$5; C$4/C$5);
        EĞER($B7="USD"; C$4; C$5)
      )

 

[tamer42]

Merhaba.

=EĞERHATA(
  İNDİS('Piyasa Verileri'!$C:$AAA; KAÇINCI($A7; 'Piyasa Verileri'!$A:$A; 0); KAÇINCI(C$1; 'Piyasa Verileri'!$C$1:$AAA$1; 0)) *
  EĞER(Dashboard!$D$2=$B7; 1;
    EĞER(Dashboard!$D$2="USD";
      EĞER($B7="TL"; 1/C$4; C$5/C$4);
      EĞER(Dashboard!$D$2="EUR";
        EĞER($B7="TL"; 1/C$5; C$4/C$5);
        EĞER($B7="USD"; C$4; C$5)
      )

Çok teşekkürler Hocam;
Dashboard!$D$2 hücresini Kur olarak "ad" tanımlayınca; aşağıdaki şekle geldi, daha fazla kısaltmaz zannedersem;

=İNDİS('Piyasa Verileri'!$C:$AAA;KAÇINCI($A7;'Piyasa Verileri'!$A:$A;0);KAÇINCI(C$1;'Piyasa Verileri'!$C$1:$AAA$1;0))*
EĞER(Kur=$B7;1;
EĞER(Kur="USD";
EĞER($B7="TL";1/C$4;C$5/C$4);
EĞER(Kur="EUR";
EĞER($B7="TL";1/C$5;C$4/C$5);
EĞER($B7="USD";C$4;C$5))))

 

[Muzaffer Ali]

Ad tanımlama ile sadece formül metnini kısaltırsınız, hesaplama adımları değişmez.
En kısa hali bu sanırım.

 

[tamer42]

Ad tanımlama ile sadece formül metnini kısaltırsınız, hesaplama adımları değişmez.
En kısa hali bu sanırım.

teşekkürler Muzaffer Hocam

 

[Korhan Ayhan]

Alternatif...

=EĞERHATA(DÜŞEYARA($A7;'Piyasa Verileri'!$A:$AAA;KAÇINCI(C$1;'Piyasa Verileri'!$1:$1;0);0)*ELEMAN(KAÇINCI(SOLDAN(Dashboard!$D$2;1)&SOLDAN($B7;1);{"TT";"UU";"EE";"UT";"ET";"TU";"TE";"UE";"EU"};0);1;1;1;1/C$4;1/C$5;1/C$4;1/C$5;C$5/C$4;C$4/C$5);"")