Formül içinde adres formülü oluşturma hatası

[KMLZDMR]

Sayın site arkadaşları, aşağıdaki formül (a) da; YIL($K$9:$AA$9) alanı $K$9:$AA$9 yerine ADRES($B$16;11;1)&":"&ADRES($B$16;27;1) formülünü (b) yerleştirdiğimde (Bu formül sonucu: $K$9:$AA$9 olmaktadır.) formülü (c) #DEĞER! HATASI VERMEKTEDİR. LÜTFEN, NASIL DÜZENLEMEK GEREKTİĞİ HAKKINDA YARDIMCI OLUR MUSUNUZ?

formül DİZİ FORMÜLÜ' dür.
(a) {=EĞER(TOPLA(EĞER(YIL($K$9:$AA$9)<=A20;1))-EĞERSAY($K$2:$AA$2;"H")<0;0;TOPLA(EĞER(YIL($K$9:$AA$9)<=A20;1))-EĞERSAY($K$2:$AA$2;"H"))}


(b) ADRES($B$16;11;1)&":"&ADRES($B$16;27;1)

çalışmayan dizi formülü
(c) {=EĞER(TOPLA(EĞER(YIL(ADRES($B$16;11;1)&":"&ADRES($B$16;27;1))<=A20;1))-EĞERSAY($K$2:$AA$2;"H")<0;0;TOPLA(EĞER(YIL(ADRES($B$16;11;1)&":"&ADRES($B$16;27;1))<=A20;1))-EĞERSAY($K$2:$AA$2;"H"))}

 

[Ömer BARAN]

Merhaba Sayın ÖZDEMİR.

Sorunuzda kırmızı renklendirdiğiniz kısımlar;
sadece B16 hücresine 9 yazdığınızda $K$9:$AA$9 sonucunu verir.

Bunda sorun yoksa; başka çözüm seçenekleri de olabilir elbette
ancak mevcut formül tarzı üzerinden giderek şu şekilde açıklayayım.
YIL işlevi parantezinin içine aldığınız bu alan adını DOLAYLI işlevi parantezine alarak deneyiniz.

Ayrıca boş hücre kontrolü de yapmak gerekebilir. Zira boş hücreye atfen YIL işlevi içeren formül oluşturursanız yıl değeri 1900 olarak bulunur.

Formülünüzün TOPLA kısmını aşağıdaki mavi renklendirdiğim şekilde kullanabilirsiniz. Diğer kısımlarını da bunü göre düzeltin.

Formüldeki ADRES($B$16;11;1)&":"&ADRES($B$16;27;1) kısmını,
başına = işareti ekleyerek örneğin B1 hücresine uygulamışsanız;
aşağıdaki formülde bunların yerine (DOLAYLI parantezinin içine) B1 yazabilirsiniz.

A20 hücresinde örneğin 2012 değeri var ve K9:AA9 hücre aralığında bazı hücreler boş ve bazı hücrelerde de 2012 veya daha eski tarih içeren değerler varsa aşağıdaki formül parçası, dolu ve yıl değeri 2012 ve daha küçük olanların adetini verir.
.

[COLOR="Red"]TOPLA(EĞER(YIL(ADRES($B$16;11;1)&":"&ADRES($B$16;27;1))<=A20;1))[/COLOR]
[COLOR="Blue"]TOPLA(EĞER(DOLAYLI(ADRES($B$16;11;1)&":"&ADRES($B$16;27;1))<>"";EĞER(YIL(DOLAYLI(ADRES($B$16;11;1)&":"&ADRES($B$16;27;1)))<=A20;1)))[/COLOR]

 

[KMLZDMR]

Günaydın, Sayın Ömer BARAN üstadım,
Öncelikle ilgi ve yardımınız için teşekkür ederim.
Mavi renkli formülü uyguladım,çalıştı. 1 pencerede (c) formülü içinde bulunan eksi işaretli: -EĞERSAY($K$2:$AA$2;"H") formül k2:aa2 hücre aralığına EVET/HAYIR kısaltması olarak E/H seçenekleri var. Bunun amacı düzenlediğiniz mavi renkli yukarıdaki formül kriterlere göre saymaktadır. Amacım ise kriterler doğru ve saydı ama $K$2:$AA$2 aralığında "H" olan $K$9:$AA$9 (9 lar malumunuz üzere değişken) sütununda uyan olsa dahi "H" olanları saymamasını sağlamaktı. Mavi renkli formülünüze bu durumu nasıl ekleriz. BU şekilde tekar formül düzenlemeniz mümkün mü? Saygılarımla.

 

[Ömer BARAN]

Merhaba şu an İstanbul'a gitmek üzere havaalanındayım.
Başka cevaplayan olmazsa, ancak birkaç saat sonra bakabilirim.
İyi çalışmalar.

 

[KMLZDMR]

Üstad kolay gelsin. Sizin cevabınızı bekliyorum. Teşekkür ederim.

 

[Ömer BARAN]

Tekrar merhaba.

Amaç, B16 hücresinde yazılı satırda (örneğimizde 9) olmak üzere K:AA sütununda,
A20 hücresinde yazılı yıl ve daha eski yıllara ait tarihleri içeren VE
-- K2:AA2 (bu alan sabit) hücre aralığında H yazmayan (boş veya E) hücre adetini bulmak ise mavi kısmı,
-- K2:AA2 (bu alan sabit) hücre aralığında E yazan ise kırmızı kısmı,
kullanın.
.

=TOPLA(EĞER($K$2:$AA$2[B][COLOR="Blue"]<>"H"[/COLOR][COLOR="Red"]="E"[/COLOR][/B];EĞER(DOLAYLI(ADRES($B$16;11;1)&":"&ADRES($B$16;27;1))<>"";EĞER(YIL(DOLAYLI(ADRES($B$16;11;1)&":"&ADRES($B$16;27;1)))<=A20;1))))
[COLOR="Blue"]Formül diizi formülü olduğundan [B]CTRL+SHIFT+ENTER[/B] ile girilmelidir.[/COLOR]

 

[KMLZDMR]

Sayın Ömer BARAN üstadım, teşekkür ederim. Çalıştı. <>"H"="E" renklerden H / E yi formülde yalnız birisini seçmek gerektiği anlaşılıyor. Doğru mu?

Ayrıca aşağıdaki şekilde YADA fonksiyonunu eklediğimde de aynı sonucu alınabilmektedir. Sizce de uygun mudur?

=TOPLA(EĞER(YADA($K$2:$AA$2<>"H";$K$2:$AA$2="E");EĞER(DOLAYLI(ADRES($B$16;11;1)&":"&ADRES($B$16;27;1))<>"";EĞER(YIL(DOLAYLI(ADRES($B$16;11;1)&":"&ADRES($B$16;27;1)))<=A24;1))))

 

[Ömer BARAN]

Evet Sayın ÖZDEMİR.
-- Amacınız; sadece E olan sütunlarda, yıl kriterine göre sayma ise ="E" kısmını kullanlamalısınız.
-- Amacınız; sadece boş veya E olan sütunlarda yıl kriterine göre sayma ise <>"H" kısmını kullanlamalısınız.

Belirttiğiniz YADA işlevi boş ve E olanlarda sayım yapar.
Yani sadece <>"H" kısmı yeterli demektir.

Kararınızı, üstte belirttiğim amaca göre vermelisiniz.

NOT: Şahsi e-posta adresinizi kontrol ediniz.
.