Filtre Hatası

[tolga78]

Ekli exe dosyasında tüm işlemler butonuna bastığımızda firma ünvanı yazan yere otamatik filtre koyuyor. ilaveten firmanın yazılı olduğu sütüna 2.filtre koyuyor. Yapılacak işlem Tüm işlemler butonuna basılınca firma ünvanın yazılan sütüna filtre konulmaması olacak bu konuda yardımlarınız bekliyorum

 

[Korhan Ayhan]

Deneyiniz.

Sub XL_Filter_And_Sort()
    With Worksheets("FATURA")
        On Error Resume Next
        If ActiveSheet.AutoFilterMode Then
           ActiveSheet.AutoFilterMode = False
        End If
        .ListObjects("Tablo1").ShowAllData
        If Not .ListObjects("Tablo1").ShowAutoFilter Then
            .ListObjects("Tablo1").ShowAutoFilter = True
        End If
        On Error GoTo 0
        With .ListObjects("Tablo1").Sort
            .SortFields.Clear
            .SortFields.Add Key:=Range("Tablo1[FİRMA ÜNVANI]"), SortOn:=xlSortOnValues, Order:=xlDescending
            .SortFields.Add Key:=Range("Tablo1[İŞLEM TÜRÜ]"), SortOn:=xlSortOnValues, Order:=xlDescending
            .Header = xlYes
            .Apply
        End With
    End With
End Sub

 

[tolga78]

Korhan bey mesajda yazdığınız kodları excel uygulamasında fatura kısmına yapıştırdım ama maalesef gene aynı filtre hatasoı alıyorum

 

[Korhan Ayhan]

Önerdiğim kodu dosyanıza ekledim. Ekli dosya bende sorunsuz çalışıyor.

 

[veyselemre]

    With Worksheets("FATURA").ListObjects("Tablo1")
        If .Range.AutoFilter Then .Range.AutoFilter
        With .Sort
            .SortFields.Clear
            .SortFields.Add Key:=Range("Tablo1[FİRMA ÜNVANI]"), SortOn:=xlSortOnValues, Order:=xlDescending
            .SortFields.Add Key:=Range("Tablo1[İŞLEM TÜRÜ]"), SortOn:=xlSortOnValues, Order:=xlDescending
            .Header = xlYes
            .Apply
        End With
    End With

 

[tolga78]

korhan bey size dosyayı gönderiyorum tüm işlemlere bastığımda yukarıda firma unvanı yazan yere otomatik filtre koyuyor bazen de ara sıra aşağıda yaza adres veya vergi no yere de filtre koyuyor sizin yaptığınız kodlamayı da ekledim ama gene de aynısını yapıyor. Dosyada ok işareti ile gösterdim.

 

[Korhan Ayhan]

Önerdiğim kodu dosyanızda göremedim...

 

[tolga78]

kopya olan dosyayı göndermişim kusura bakmayın orjinali gönderiyorum

 

[tolga78]

Tüm işlemler butonuna tıklayınca 2 kere işlem yapıyor. Yalnız bu butona birkez basınca yapılan tüm işlemler gelecek. ayrıca yukarıda yazan firma ünvanı kısmına filtre koymayacak

 

[Greenblacksea53]

Sorunu doğru mu anladım bilmiyorum ama, ben size şöyle birşey yaptım, C2 de ne seçerseniz filtreleme yapacak.

 

[Korhan Ayhan]

Önerdiğim kodu dosyanıza eklemişsiniz fakat butona bu kodu tanımlamamışsınız. Butona tıklayınca halâ sizin eski kodunuz devreye giriyor.

 

[tolga78]

Korhan bey tum işlemler butonuna tıklayınca tum yapılan işlemlerin gelmesi gerekiyor.Sizin kodu ekledim hatta butona sizin kodları olan makroyuda atadım.Ama tıklayınca komple yapılan işlemler gelmiyor.Tum işlemlere tıklayınca yapılan komple işlemlerin geliyor fakat yukarıda firmayı seçince firma ünvanı yazılan yere filtre koyuyor.

 

[Korhan Ayhan]

Bu kodu deneyiniz.

Sub XL_Filter_And_Sort()
    Application.ScreenUpdating = False
    With Worksheets("FATURA")
        On Error Resume Next
        If ActiveSheet.AutoFilterMode Then
           ActiveSheet.AutoFilterMode = False
        End If
        With .ListObjects("Tablo1")
            If Not .AutoFilter Is Nothing Then .AutoFilter.ShowAllData
        End With
        On Error GoTo 0
        With .ListObjects("Tablo1").Sort
            .SortFields.Clear
            .SortFields.Add Key:=Range("Tablo1[FİRMA ÜNVANI]"), SortOn:=xlSortOnValues, Order:=xlDescending
            .SortFields.Add Key:=Range("Tablo1[İŞLEM TÜRÜ]"), SortOn:=xlSortOnValues, Order:=xlDescending
            .Header = xlYes
            .Apply
        End With
    End With
    Application.ScreenUpdating = True
End Sub

 

[tolga78]

Teşekkür ederim. şimdi oldu. herşey düzeldi. Elinize emeğinize sağlık . sıkıntı nereden kaynaklanıyormuş.

 

[Korhan Ayhan]

Filtreyi temizleyen kod satırını hatalı kurgulamışım. Ondan kaynaklı sorun olmuş.

 

[tolga78]

Korhan bey benim yaptığım excelde tum işlemler makrosunda hata nerede onu demiştim.

 

[Korhan Ayhan]

Aşağıdaki satırdan önce hücre seçimi belirtmemişsiniz.

Selection.AutoFilter ....

Doğal olarak sayfada hangi hücre seçili ise o hücreye göre kod çalışacaktır. Eğer sayfada hatalı bir hücre seçili ise kod istediğiniz gibi çalışmayacaktır.

Ayrıca kodun devamındaki sıralama işleminde Range("B8:J65536").Select alanını seçerek işlem yapmışsınız. Fakat tablonuz "O" sütununa kadar devam ediyor.