Çözüldü Fazla Veri İçeren Excel Çalışması

[gicimi]

Merhaba;

200.000 satır üzeri veri işlenmiş bir excel sayfasında aynı çalışma kitabı Sayfaları içerisinde "Belirli bir data içerisinde bilgilere ulaşmak istediğim değerin satırlarını hızlı bir şekilde sonuca ulaşmak için nasıl bir kod kullanılmalıdır.

Örnek Olarak: Sayfa1 B Sutundaki datayı Sayfa2 A Sutundaki data ile karşılatırıp B sutundaki veriyi Sayfa1 C sutuna yazması. Excel ektedir.

Konu hakkında yardımlarınız lütfen.

 

[Zeki Gürsoy]

Bunun birden fazla yolu var. Bana göre en hızlı yolu Sql/Join yani kesişim yöntemidir.

 

[gicimi]

Bunun birden fazla yolu var. Bana göre en hızlı yolu Sql/Join yani kesişim yöntemidir.

Zeki Bey ekteki çalışma için Sql/Join gösterebilir misiniz. Teşekkürler.

 

[Zeki Gürsoy]

Dosyanızı şimdi inceleme fırsatı bulabildim. Dosyaya bakıldığında tekrar eden malzeme tanımları var. Örneğin, "B01" için "A mı gelecek? "J" mi gelecek? Bu haliyle uygun değil. Tekil olması gerekir. "Malzeme no" bunun için uygun görünüyor ama karşılaştırma yapılacak sütun yok.

 

[gicimi]

Dosyanızı şimdi inceleme fırsatı bulabildim. Dosyaya bakıldığında tekrar eden malzeme tanımları var. Örneğin, "B01" için "A mı gelecek? "J" mi gelecek? Bu haliyle uygun değil. Tekil olması gerekir. "Malzeme no" bunun için uygun görünüyor ama karşılaştırma yapılacak sütun yok.

Zeki Bey haklısınız fark edemedim. Sayfa2 deki bilgiler tekrar eden değil tekildir. Amacım Malzeme No ait Malzeme tanımının Malzeme eklentisi bilgisini Sayfa2 aratıp bulması durumunda Sayfa bire aktarması.

 

[Zeki Gürsoy]

Deneyin...

Sub Test()
    Dim cn As Object, rs As Object, t1 As Single, t2 As Single
    
    Set cn = CreateObject("ADODB.Connection")
    
    cn.Open "Provider=Microsoft.ACE.OLEDB.12.0;" & _
            "Data Source=" & ThisWorkbook.FullName & _
            ";Extended Properties=""Excel 12.0;HDR=YES"";"
            
    t1 = Timer
    
    Set rs = cn.Execute( _
    "select a.[Malzeme No], a.[Malzeme Tanımı], b.[Tesis Eklentisi] " & _
    "from [Sayfa1$] as a left join [Sayfa2$] as b " & _
    "on a.[Malzeme Tanımı] = b.[Malzeme Tanımı]")
            
    Sheets("Sayfa1").[a2].CopyFromRecordset rs
            
    t2 = Timer
    
    rs.Close
    
    cn.Close
    
    Set rs = Nothing
    Set cn = Nothing
    
    MsgBox "İşlem süresi : " & Round(t2 - t1, 2) & " saniye", vbInformation
End Sub

 

[gicimi]

Deneyin...

Sub Test()
    Dim cn As Object, rs As Object, t1 As Single, t2 As Single
   
    Set cn = CreateObject("ADODB.Connection")
   
    cn.Open "Provider=Microsoft.ACE.OLEDB.12.0;" & _
            "Data Source=" & ThisWorkbook.FullName & _
            ";Extended Properties=""Excel 12.0;HDR=YES"";"
           
    t1 = Timer
   
    Set rs = cn.Execute( _
    "select a.[Malzeme No], a.[Malzeme Tanımı], b.[Tesis Eklentisi] " & _
    "from [Sayfa1$] as a left join [Sayfa2$] as b " & _
    "on a.[Malzeme Tanımı] = b.[Malzeme Tanımı]")
           
    Sheets("Sayfa1").[a2].CopyFromRecordset rs
           
    t2 = Timer
   
    rs.Close
   
    cn.Close
   
    Set rs = Nothing
    Set cn = Nothing
   
    MsgBox "İşlem süresi : " & Round(t2 - t1, 2) & " saniye", vbInformation
End Sub

Zeki Bey Teşekkür ederim Elinize sağlık.