fatura kesildiği anda stok düşürmek

[GursoyC]

merhaba,
bir fatura formatım var. bu fatura üzerindeki "stok düşür" düğmesine bastığımda fatura içeriğindeki kalemlerin adetlerinin stok listesi tablosundaki fatura tarihi sütununa eklenmesini (eklenerek gitmesini) istiyorum.
örnek dosyaları ekledim.

yardımcı olur musunuz?

teşekkürler.

 

[tahsinanarat]

Bence stok tutma şeklin yanlış, aynı renkten aynı günden birden fazla fatura kestiğinde nereye yazacak?
Bir stok listesi sayfan olur, GİRİŞ, ÇIKIŞ diye ayrı sayfalarda, yada giriş çıkış adlı tek bir sayfada giriş ve çıkışlarını takip edersin
Buna bağlı Stok adlı sayfada da güncel datalarını görürsün.

 

[GursoyC]

Bence stok tutma şeklin yanlış, aynı renkten aynı günden birden fazla fatura kestiğinde nereye yazacak?
Bir stok listesi sayfan olur, GİRİŞ, ÇIKIŞ diye ayrı sayfalarda, yada giriş çıkış adlı tek bir sayfada giriş ve çıkışlarını takip edersin
Buna bağlı Stok adlı sayfada da güncel datalarını görürsün.

parantez içerisinde "eklenerek gidecek" cümlesini bu yüzden girmiştim. yani örneğin bugün ilk faturada kırmızı 5 adet kestim. ayın 20'sine 5 yazdı. ikinci faturada yine kırmızıdan 3 tane kesersem, 5'e 3 ekleyerek 8 yazması gerek.

benim amacım zaten stok çıkışlarını otomatize etmek.

stok girişleri haftada bir yapıldığı için onu manuel yaparım sorun değil. ama çıkışları faturaya bağlamak işimi çok kolaylaştıracak.

 

[GursoyC]

günceldir.

 

[Korhan Ayhan]

İki dosyayı birleştirirseniz daha kolay aktarım işlemi yapılabilir.

 

[GursoyC]

Korhan hocam merhaba,
öncelikle biraz geç cevap verdiğim için özür dilerim.
İki dosyanın birleşimi elbette mümkündür. Neden son çare olarak düşündüğümü belirteyim.
Her gün "farklı kaydet" yaparak günlük fatura arşivi yapıyorum. haliyle o günün tarihiyle bir excel dosyası oluşuyor. stok.xls diye ayrı bir sayfa tutma isteğim bundan. ancak elbette bu durumda bile işim şu andaki halinden daha kolay olacaktır.

İki dosyayı birleştirerek aynı excel dosyasına aldığım durum için nasıl yapacağım konusunda yardımcı olur musunuz? Dosyayı ekledim.

Teşekkür ederim.

 

[Korhan Ayhan]

Merhaba,

Aşağıdaki kodu deneyiniz.

Kodu her çalıştırdığınızda stoktan düşürme işlemi yapacağı için dikkatli kullanmanızda fayda var.

Sub STOK_DÜŞÜR()
    Dim S1 As Worksheet, S2 As Worksheet, Alan As Range, Veri As Range, Stok As Range, Tarih As Range
    
    Set S1 = Sheets("1")
    Set S2 = Sheets("stok")
    Set Alan = S1.Range("I31:I50")
    
    For Each Veri In Alan
        If Veri.Value <> "" Then
            Set Stok = S2.Range("A:A").Find(Veri.Value, , , xlWhole)
            If Not Stok Is Nothing Then
                Set Tarih = S2.Rows(2).Find(S1.Range("AI21").Value, , , xlWhole)
                If Not Tarih Is Nothing Then
                    S2.Cells(Stok.Row, Tarih.Column) = S2.Cells(Stok.Row, Tarih.Column) + S1.Cells(Veri.Row, "Y")
                End If
            End If
        End If
    Next
    
    Set Alan = Nothing
    Set Stok = Nothing
    Set Tarih = Nothing
    Set S1 = Nothing
    Set S2 = Nothing

    MsgBox "Stok düşürme işlemi tamamlanmıştır.", vbInformation
End Sub

 

[GursoyC]

çok teşekkür ederim hemen deneyeyim Korhan bey.
Saygılarımla,

 

[GursoyC]

Korhan bey, gayet güzel çalışıyor.
Ellerinize sağlık.

Teşekkürler, iyi çalışmalar.

 

[GursoyC]

Korhan bey tekrar merhaba,
verdiğiniz kodda Set S1 = Sheets("1") satırındaki sayfa ismini kaldırmak mümkün müdür?
Yani mesela sayfanın ismi 5 de olsa, herhangi başka bir değer de olsa kodun aynı şekilde çalışması için ne yapmam gerekir?
Saygılarımla.

 

[GursoyC]

Set S1 = ActiveSheet yazdım, oldu.
Tekrar teşekkürler.