Farklı sayfalardaki hücrelere ulaşma

[goQsheen]

Arkadaşlar benim 20 sayfalık bir excel dosyam var. Bu sayfaların herbirinde isimler ve puanlar var. Ben bir arama ile bu sayfalar içerisinde aradığım isim hangi hücrede ise onun yanına veya hizasındaki herhangi bir sütuna istediğim değeri yazdırabilirmiyim ?

Yardımlarınız için şimdiden teşekkürler...

 

[Korhan Ayhan]

Selamlar,

Normalde CTFL+F (BUL) komutu ile kitap içinde istediğiniz veriyi arama işlemi yapabilirsiniz. Bu menüyü açtıktan sonra karşınıza gelen kutucuğa aramak istediğiniz veriyi yazın. Alt kısımdaki SEÇENEKLER butonuna tıklayın. Açılan menüdeki "İÇİNDE" seçeneğini "ÇALIŞMA KİTABI" olarak ayarlayın. Tümünü bul butonuna tıkladığınızda tüm kitap içinde belirttiğiniz veri bulunur ve listelenir. Siz listeden seçim yaparak ilgili sayfaya ulaşarak verinin bulunduğu satırdaki istediğiniz sütuna istediğiniz bilgi girişini yapabilirsiniz.

Ya da aşağıdaki makro ile bu işlemi yapabilirsiniz. Kod içindeki kırmızı renki 2 değeri verinin nereye yazılacağını belirtir.

Örnek; bulunan veri A sütununda ise 2 yan sütuna (yani C sütununa) bilgi yazdırılır.

Option Explicit
 
Sub SAYFALARDA_BUL_BİLGİ_EKLE()
    Dim İSİM As Variant, BİLGİ As Variant, SAYFA As Worksheet, BUL As Range, ADRES As String
 
    İSİM = Application.InputBox("Lütfen aramak istediğiniz ismi giriniz !", "İSİM GİRİŞİ")
    If İSİM = False Or İSİM = "" Then
        MsgBox "Lütfen isim giriniz !", vbCritical
        Exit Sub
    End If
 
    BİLGİ = Application.InputBox("Lütfen eklemek istediğiniz bilgiyi giriniz !", "BİLGİ GİRİŞİ")
    If BİLGİ = False Or BİLGİ = "" Then
        MsgBox "Lütfen bilgi giriniz !", vbCritical
        Exit Sub
    End If
 
    For Each SAYFA In ThisWorkbook.Worksheets
        Set BUL = SAYFA.Cells.Find(İSİM, , , xlWhole)
        If Not BUL Is Nothing Then
            ADRES = BUL.Address
            Do
                BUL.Offset(0, 2) = BİLGİ
            Set BUL = SAYFA.Cells.FindNext(BUL)
            Loop While Not BUL Is Nothing And BUL.Address <> ADRES
        End If
    Next
 
    Set BUL = Nothing
 
    MsgBox "İşleminiz tamamlanmıştır.", vbInformation
End Sub

 

[goQsheen]

Hocam teşeşkkürler yardımınız için. ancak bu kod sadece bir kere arama yapıyor. Aynı içriğe sahip birden fazla hücre olabiliyor. Bu durumda diğer hücrelerdekini bulmuyor.

 

[Korhan Ayhan]

Selamlar,

Üstteki mesajımdaki kodu güncelledim. İncelermisiniz.

 

[goQsheen]

İnceledim. Tam istediğim gibi teşekkürler...