Farklı Para Birimi Toplama Hakkında Bir soru?

[carisma]

Merhabalar Forumda daha önce paylaşılan TOPLATL,TOPLAEURO.. Fonksiyonuyla ilgili bir problem hakkında yardımlarınızı beklemekteyim.

Konu : ToplaTL Fonksiyonunu kullandığımızda grupladığımız veya gizlediğimiz satırlardaki verileri de topluyor olması. KIsaca Bu fonksiyonun Aslında AltToplaTL gibi çalışmasını nasıl sağlayabiliriz. Konu ile ilgili örnek dosya ekte mevcuttur.

Gizli hücreleri toplamdan çıkaracak olan aşağıdaki fonksiyon ile ToplaTL Birleştirilebilir mi?

"Function gizli_hucreleri_topla(hucre_topla As Object)
Application.Volatile

For Each cell In hucre_topla
If cell.Rows.Hidden = False Then
If cell.Columns.Hidden = False Then
topla = topla + cell.Value
End If
End If
Next
gizli_hucreleri_topla = topla"

Teşekkürler,

 

[Korhan Ayhan]

Merhaba,

Aşağıdaki fonksiyon ile işlemlerinizi yapabilirsiniz.

Function PARA_TOPLA(Aralık As Range, Optional Ölçüt As String = "TL", _
                    Optional Parametre As String = "T")
    Dim Hücre As Range
 
    Application.Volatile True
 
    For Each Hücre In Aralık
        If UCase(Parametre) = "T" Then
            If IsNumeric(Hücre.Value) Then
                If InStr(1, Hücre.Text, Ölçüt) > 0 Then
                    PARA_TOPLA = PARA_TOPLA + Hücre.Value
                End If
            End If
        ElseIf UCase(Parametre) = "G" Then
            If Hücre.RowHeight > 0 Then
                If IsNumeric(Hücre.Value) Then
                    If InStr(1, Hücre.Text, Ölçüt) > 0 Then
                        PARA_TOPLA = PARA_TOPLA + Hücre.Value
                    End If
                End If
            End If
        End If
    Next
End Function

Örnek kullanım şekillleri;

=PARA_TOPLA(B5:B100;"TL";"G")

=PARA_TOPLA(B5:B100;"TL";"T")

=PARA_TOPLA(B5:B100;"€";"G")

=PARA_TOPLA(B5:B100;"€";"T")

=PARA_TOPLA(B5:B100;"$";"G")

=PARA_TOPLA(B5:B100;"$";"T")

Fonksiyonda kullanılan;

"G" harfi ve "TL" kriterleri parametriktir.

"G" görünür hücreleri ifade eder. G yerine T yazarsanız ya da boş bırakırsanız opsiyonel olarak T yazdığınız varsayılır. T harfi tümünü ifade eder. Yani tüm satırları toplar.

"TL" kriteride opsiyoneldir. Boş bıraktığınızda "TL" yazdığınız varsayılır. $ yada € olarakta kullanabilirsiniz.

 

[carisma]

Teşekkür Ederim Korhan Bey, FOnksiyon Tam olarak Çalışıyor.