Farklı excel dosyalarında ki satır bilgisini satır olarak alma

[Kutlusubut]

İyi akşamlar,
4 gün önce başladığım yeni işimde müdürümün istediği bir excel tablosunu yapamadım ve sizlerden yardım rica ediyorum.
Excel dosyasında, bir ana sayfamız var, bir arkadaşımız sigorta şirketleri ile yapılan işlemleri fatura bazında işliyor. Bir satıra: ilk sutuna sigorta şirketi adı, 2. sütun tarih, 3. sutun fatura no, 4. sutun fatura toplamı, 5. sutun araç markası vb olarak 11 sutun işliyor. günde 60 fatura işleniyor. Sigorta şirket sayısı 11.
benden istediği, bu sayfaya dokunmadan başka bir sayfada kendisinin görebileceği şekilde, mesela yalnızca Ak Sigorta işlemlkerini görebilmek. başka bir sayfada Nippon sigorta işlemlerini görebilmek.
Böylece tabloya veri giren arkadaşı meşgul etmeden istediği verileri güncel olarak ayrı bir excelde görebilmek. Nette baktım düşeyara kullanılabilir diyor ama hiç kullanmadığım için çözemedim bu formülü. Bu problemim için yardım ederseniz çok sevinirim.
Saygılarımla.

 

[Orion1]

İyi akşamlar,
4 gün önce başladığım yeni işimde müdürümün istediği bir excel tablosunu yapamadım ve sizlerden yardım rica ediyorum.
Excel dosyasında, bir ana sayfamız var, bir arkadaşımız sigorta şirketleri ile yapılan işlemleri fatura bazında işliyor. Bir satıra: ilk sutuna sigorta şirketi adı, 2. sütun tarih, 3. sutun fatura no, 4. sutun fatura toplamı, 5. sutun araç markası vb olarak 11 sutun işliyor. günde 60 fatura işleniyor. Sigorta şirket sayısı 11.
benden istediği, bu sayfaya dokunmadan başka bir sayfada kendisinin görebileceği şekilde, mesela yalnızca Ak Sigorta işlemlkerini görebilmek. başka bir sayfada Nippon sigorta işlemlerini görebilmek.
Böylece tabloya veri giren arkadaşı meşgul etmeden istediği verileri güncel olarak ayrı bir excelde görebilmek. Nette baktım düşeyara kullanılabilir diyor ama hiç kullanmadığım için çözemedim bu formülü. Bu problemim için yardım ederseniz çok sevinirim.
Saygılarımla.

Örnek dosyalarınızı buraya link veriniz.

 

[Kutlusubut]

Örnek dosyalarınızı buraya link veriniz.

Forumda yeniyim kusura bakmayın, link vermeyi bilmiyorum.
evrengizlen@hotmail.com adresine mail attım.
İlginize teşekkür ederim.

 

[Orion1]

Dosyanız ektedir.
Ana Sayfa Adlı sayfanızın adını Ana_Sayfa olarak değiştirdim.
Kaynak dosyanızın çalışırken kapalı olması lazım.

Sub firmalar()
Dim conn As Object, rs As Object
Set conn = CreateObject("Adodb.Connection")
Set rs = CreateObject("Adodb.Recordset")
conn.Open "Provider=Microsoft.ace.oledb.12.0;data source=" & ThisWorkbook.Path _
        & "\Sigorta- Maliyet-DENEME2.xlsx;extended properties=""excel 12.0;hdr=Yes;imex=1"""
Set rs = conn.Execute("select distinct ([SİGORTA]) from [Ana_Sayfa$A3:A1000000] GROUP BY ([SİGORTA])")
Sayfa1.ComboBox21.Clear
Sayfa1.ComboBox21.Column = rs.getrows
Sayfa1.ComboBox21.ListIndex = 0
conn.Close
Set rs = Nothing
Set conn = Nothing
End Sub
Sub liste()
Dim conn As Object, rs As Object
Range("A4:K" & Rows.Count).ClearContents
If Sayfa1.ComboBox21.Value = "" Then
    MsgBox "Lütfen Bir firma ismi seçiniz!" & vbLf & "İşlem İptal Oldu" & vbLf & _
            "evrengizlen@hotmail.com", vbOKOnly + vbInformation, Application.UserName
            Exit Sub
End If
Application.ScreenUpdating = False
Set conn = CreateObject("Adodb.Connection")
Set rs = CreateObject("Adodb.Recordset")
conn.Open "Provider=Microsoft.ace.oledb.12.0;data source=" & ThisWorkbook.Path _
        & "\Sigorta- Maliyet-DENEME2.xlsx;extended properties=""excel 12.0;hdr=Yes;imex=1"""
rs.Open "select * from [Ana_Sayfa$A3:K1000000] where ([SİGORTA])='" & Sayfa1.ComboBox21.Value & "';", conn, 1, 1
Range("A4").CopyFromRecordset rs
Application.ScreenUpdating = True
rs.Close: conn.Close
Set rs = Nothing: Set conn = Nothing
MsgBox "İşlem Gerçekleşti." & vbLf & "evrengizlen@hotmail.com", vbOKOnly + vbInformation, Application.UserName
End Sub
Sub auto_open()
Call firmalar
End Sub

DOSYANIZI BU LİNKTEN TIKLAYARAK İNDİREBİLİRSİNİZ.

 

[mustor]

kardeşim pivot tablo oluştur ne kasıyorsun ki hepsini tek bir tabloda görür sigorta firmasınıda filtre olarak koy seçsin seçsin görsün