Excelden Word'e İLGİLİ BAŞLIK DETAYINA aktarım

[ozlemaltin]

Forumda oluşturulmuş word aktarımı ile ilgi işlemleri inceledim fakat koşullu aktarıma rastlamadım. Makroya da koşul atayamadım. Excel çalışma sayfasında TEXT23 ile yer alan tablonun Wordde text23 ile başlayan yere yapıştırılmasını istiyorum. bunu yaparken bağ yapıştır kullanmak istemiyorum. Yardımlarınız için şimdiden teşekkürler,
Özlem

 

[ozlemaltin]

böyle birşey yokmu acaba boşuna mı araştırıyorum sabahtan beri ((

 

[mancubus]

word dosyasında kopyalanacak yere "yer işareti" ekleyerek isim veriyorsunuz.
benim örnekte: "yi_text23"

VBE'de tools - references'da Microsoft Word Object Library 11.0'a referans ekliyorsunuz.

excel'den makroyu çalıştırıyorsunuz.

ben hazırını ekledim.

birden çok yere birden çok kopyalama yapılacaksa her biri için bu işlemi tekrarlama lazım.

Option Explicit

Sub WordDosyasınaKopyala()

Dim appWord As Object, objDoc As Object
Dim DosyaYolu As String, DosyaAdi As String
Dim wordekop As Range

With Application
    .ScreenUpdating = False
    .EnableEvents = False
    .DisplayAlerts = False
End With

DosyaYolu = ThisWorkbook.Path 'excel dosyası ile word dosyasının aynı klasörde olduğu kabul edilerek
DosyaAdi = "text 23.doc"

Set wordekop = Worksheets("x").Range("A4:B11") 'kopyalamak istenilen alan. ihtiyaca göre değiştirilmeli

Set appWord = CreateObject("Word.Application")
appWord.Visible = True

On Error Resume Next
Set objDoc = appWord.Documents.Open(DosyaYolu & "\" & DosyaAdi)
On Error GoTo 0

If objDoc Is Nothing Then
    MsgBox "Word dosyası bulunamadı.", vbCritical, "U Y A R I"
    appWord.Quit
    Set appWord = Nothing
    Exit Sub
End If

appWord.Selection.Goto What:=wdGoToBookmark, Name:="yi_text23"
wordekop.Copy
appWord.Selection.Paste

Application.CutCopyMode = False

With Application
    .ScreenUpdating = True
    .EnableEvents = True
    .DisplayAlerts = True
End With

Set appWord = Nothing
Set objDoc = Nothing

End Sub

 

[ozlemaltin]

Elinize sağlık, çok teşekkür ederim.
appWord.Selection.Goto What:=wdGoToBookmark, Name:="yi_text23"

satırına hata uyarısı gösteriyor. Atladığım biryer varmı acaba? Tüm dediğiniz detayları yaptım.

 

[mancubus]

eklediğim dosyalar üzerinden giderseniz daha doğru olabilir.

test ettikten sonra ekledim. sorun yoktu.

aldığınız hata mesajı nedir?

 

[ozlemaltin]

Sub WordDosyasınaKopyala() satırında ve
appWord.Selection.Goto What:=wdGoToBookmark, Name:="yi_text23"
satırında hata veriyor baştan sona aynı şekilde denedim hatta farklı bi pcde referasn ekleyip denedim olmuyor

 

[mancubus]

hata mesajının ne olduğunu ısrarla söylemiyorsunuz.
dosyalarınızı ekleyin bakalım.

 

[ozlemaltin]

dosyalar ekte, vaktiniz için teşekkürler,

Özlem

 

[mancubus]

rica ederim.

dosyalarınız olduğu gibi klasörüme aldım.
excel'den makroyu çalıştırdım.
sorunsuz word dosyasına kopyaladı.

aldığınız hata mesajını yazar veya resim olarak eklerseniz, belki ben veya diğer üyeler yardımcı olabiliriz.

 

[leumruk]

Merhaba,
Referans sorunu yaşıyorsunuz.
Sn. mancubus'un eklediği kodlardan şu satırı :

appWord.Selection.Goto What:=wdGoToBookmark, Name:="yi_text23"

Bununla değiştirin:

appWord.Selection.Goto What:=-1, Name:="yi_text23"

 

[ozlemaltin]

leumruk teşekkür ederim, mancubus sizede çok teşekkür ederim.
Selamlar,

 

[askm]

Burda farklı satıra yazdırmak istediğimizde nerde değişiklik yapmamız gerekli.Örneğin Text 3 altına yazmak istersek.

 

[askm]

Wordde yer işareti ekleyip (yer işaretine =yi_text23 verilmiş) kaydettikten sonra makro çalıştırılıyormuş. İhtiyaç duyan arkadaşlar için yazdım.