excelden worde biçimli aktarmada sorun

[cosarx]

macro kod ile bir excel dosyasındaki bir sheet'in içeriğini worde nasıl kaydedebilirim? yada excel dosyasını word olarak kod ile nasıl saveas yapabilirim?

 

[ENDMUH1]

...

Kullandığım şöyle bir örnek vardı elimde...

İyi çalışmalar...

Sub SeciliAlaniWordeYapistir(ust, alt, sol, sag As Integer, yon, kapat As Boolean, kytAd)
'(ust: Üst Kenar Boşluğu, alt: Kenar Boşluğu, sol: Kenar Boşluğu, sag: Üst Kenar Boşluğu
'yon: Dikey ise True, Yatay ise False
'kapat: Kapatılacak ise True, Kapatılmayacak ise False
'kytAd: Dosyanın kaydedileceği ad
Application.ScreenUpdating = True
Dim objword As Object
Set objword = CreateObject("Word.Application")
Set Mydoc = objword.Documents.Add(DocumentType:=wdNewBlankDocument)
objword.Visible = True

With Mydoc.PageSetup
.TopMargin = ust '42.55
.BottomMargin = alt '42.55
.LeftMargin = sol '25#
.RightMargin = sag '25#
If yon = True Then
.PageWidth = 595.35 'CentimetersToPoints(21) 'dikey
.PageHeight = 841.95 'CentimetersToPoints(29,7) 'dikey
Else
.PageWidth = 841.95 'CentimetersToPoints(29.7) 'yataysayfa
.PageHeight = 595.35 'CentimetersToPoints(21) 'yataysayfa
End If
End With
objword.Selection.PasteSpecial Link:=False, DataType:=10
Application.CutCopyMode = False

If kytAd <> "" Then
With objword
.ActiveDocument.SaveAs kytAd
If kapat = True Then
.ActiveDocument.Close
.Quit
End If
End With
End If
Set objword = Nothing: Set Mydoc = Nothing
Application.ScreenUpdating = False
End Sub


Private Sub CommandButton1_Click()
ThisWorkbook.Worksheets("RAPOR").Activate
ThisWorkbook.Worksheets("RAPOR").Range("A1:N43").Copy
strAd = ThisWorkbook.Path & "\" & ActiveSheet.Name & "-" & Format(Now, "dd-mm-yy h-mm-ss") & ".doc"
Call SeciliAlaniWordeYapistir(42.55, 42.55, 25, 25, False, False, strAd)

Unload Me
End Sub

 

[janveljan]

Wordde bir makro hazırlayın ve aşağıdaki kodları ekleyin
FileName kısmına ekleyeceğiniz excel dosyasının adını (aynı dizinde değillerse yoluyla beraber)
Range kısmına da excel dosyasında eklemek istediniz alanı yazın.
Bu yöntemle worde excel dosyası eklendiğinde formüllü hücreler düzgün gözükmüyor, eklemeden önce sayfayı değer olarak yapıştırmak lazım.

Sub Makro1()
Application.DisplayAlerts = wdAlertsNone
Selection.InsertFile FileName:="ekkk.xls", Range:="Sayfa1!A1:B4", ConfirmConversions:= _
        False, Link:=False, Attachment:=False
Application.DisplayAlerts = wdAlertsAll
End Sub

 

[cosarx]

cok teşekkürler ENDMUH belirttiğiniz kodu uyguladım tam istediğim gibi olmuş elinize sağlık... janveljan ilginiz ve cevabınız için cok teşekkürler...