excelde until mantığı

[idle.]

Merhabalar,

Ben excel 2010 da çalışıyorum ve sayfaya ait hücreler üzerinde işlem yaparken belirli kısıtlamalar kulanmak istiyorum.

her hücreye ayrı bilginin girildiği bir sayfada B sütununu referans olarak belirlemek istiyorum.

Örneğin, Sayfa1deki B sütununa ait hücrenin dolu olduğu satırları Sayfa2'ye yazdırsın, aynı satırda B sütununa ait hücre boşsa onu Sayfa2'ye yazdırmasın.

Tıpkı programlama mantığındaki "until" gibi,

"B sütunundaki hücrenin boş olduğu satıra gelene kadar, satırları Sayfa2'ye yazdır. "

Excelde bunu yapıyı nasıl sağlarım?

Teşekkürler, iyi çalışmalar

 

[Necdet]

Merhaba,

Verinin 2. satırdan ve A:E sütunlarından oluştuğu varsayılarak aşağıdaki kodları deneyiniz.

Sub Aktar()

    Dim s1  As Worksheet, _
        s2  As Worksheet, _
        i   As Long, _
        j   As Long
    
    Set s1 = Sheets("Sayfa1")
    Set s2 = Sheets("Sayfa2")
    
    s2.Range("A2:E" & Rows.Count).ClearContents
    j = 1
    
    For i = 2 To s1.Cells(Rows.Count, "B").End(3).Row
        If Not s1.Cells(i, "B") = "" Then
            j = j + 1
            s1.Range("A" & i & ":E" & i).Copy s2.Cells(j, "A")
        End If
    Next i
    
End Sub

 

[YUSUF44]

Sub aktar()
son = sheets("Sayfa1").cells(Rows.count,"B").end(3).row
for i = 1 to son
if sheets("Sayfa1").cells(i,"B")<>"" then
yeni = sheets("Sayfa2").cells(Rows.count,"B").end(3).row +1
Sheets("Sayfa1").rows(i).copy sheets("Sayfa2").cells(yeni,"A")
End if
Next
End Sub

 

[idle.]

cevaplar için çok teşekkür ederim,

sayın YUSUF44 acaba bu makroyu çalışma sayfaları değil de çalışma kitapları arasında bir buton sayesinde gerçekleştirmek istesem(a.xlsm'nin ilk sayfasından b.xlsm'nin ilk sayfasına), makroyu butona atayabilmek için nasıl düzenlemem gerekir?

Teşekkürler, iyi çalışmalar.