Excel üzerinden otomatik mail gönderme

[avare1907]

Merhaba arkadaşlar çok araştırdım çeşitli denemeler de yaptım fakat henüz bi sonuca ulaşamadım eğer yarcımcı olabilirseniz çok memnun olurum...Benim rutin olarak hergün firmanın kullandığı programdan aldığım güncel veriyi excel üzerine yapıştırıp bu bilgiyi sonra kopyalayıp e-mail'e yapıştırıp çoklu mail adresine gönderiyorum...bunu otomatik hale getirme şansım varmıdır...örnek dosya ekledim.kopyalanacak alan sekmesindeki çerçeveli alan kullanmak istediğim verilerin tam denk geldiği alan o alanı kopyalayıp sayfa 1'deki renkli alana yapıştırsın sonra o renkli alanı otomatik mail gönderebileyim tabii kişiler otomatik ekli hatta ve hatta mümkün ise konu başlığıda standart hazır gelsin...şimdiden teşekkürler olursa

 

[Asri]

Merhaba arkadaşlar çok araştırdım çeşitli denemeler de yaptım fakat henüz bi sonuca ulaşamadım eğer yarcımcı olabilirseniz çok memnun olurum...Benim rutin olarak hergün firmanın kullandığı programdan aldığım güncel veriyi excel üzerine yapıştırıp bu bilgiyi sonra kopyalayıp e-mail'e yapıştırıp çoklu mail adresine gönderiyorum...bunu otomatik hale getirme şansım varmıdır...örnek dosya ekledim.kopyalanacak alan sekmesindeki çerçeveli alan kullanmak istediğim verilerin tam denk geldiği alan o alanı kopyalayıp sayfa 1'deki renkli alana yapıştırsın sonra o renkli alanı otomatik mail gönderebileyim tabii kişiler otomatik ekli hatta ve hatta mümkün ise konu başlığıda standart hazır gelsin...şimdiden teşekkürler olursa

Aşağıdaki şekilde deneyiniz.
"SAYFA 01" I1 de mail adresleri ; ile ayrılmış yazılmalıdır.
"SAYFA 01" I2 de mail konusu yazılmalıdır.

Maili otomatik göndermek için .send deki tırnak işaretini kaldırın.
'.send

Mail_Gonder ile gönderim sağlanır.

Sub Mail_Gonder()
    Sheets("SAYFA 01").Select
    Columns("A:F").Select
    Application.CutCopyMode = False
    Selection.ClearContents
    Sheets("KOPYALANACAK ALAN").Select
    Range("A1").Select
    Range("D1:I11").Select
    Selection.Copy
    Sheets("SAYFA 01").Select
    Range("A1").Select
    Selection.PasteSpecial Paste:=xlPasteValues, Operation:=xlNone, SkipBlanks:=False, Transpose:=False
    Range("A1").Select
    Call mail_secili_alan
End Sub

Sub mail_secili_alan()
      Sheets("SAYFA 01").Select
      Dim wrdEdit
      Dim alan As Range
      
      Set alan = Range("A1:F11")
            
      Set OutApp = CreateObject("Outlook.Application")
      Set OutMail = OutApp.CreateItem(0)
      With OutMail
       .To = Cells(1, "I").Value
       .CC = ""
       .BCC = ""
       .Subject = Cells(2, "I").Value
       .Display
       
       'Maili otomatik göndermek için .send deki tırnak işaretini kaldırın.
       '.send
       .HTMLBody = RangetoHTML(alan) & .HTMLBody
       End With
      
      Set wrdEdit = Nothing
      Set OutMail = Nothing
      Set OutApp = Nothing
End Sub

Function RangetoHTML(rng As Range)
' Changed by Ron de Bruin 28-Oct-2006
' Working in Office 2000-2013
    Dim fso As Object
    Dim ts As Object
    Dim TempFile As String
    Dim TempWB As Workbook

    TempFile = Environ$("temp") & "\" & Format(Now, "dd-mm-yy h-mm-ss") & ".htm"

    'Copy the range and create a new workbook to past the data in
    rng.Copy
    Set TempWB = Workbooks.Add(1)
    With TempWB.Sheets(1)
        .Cells(1).PasteSpecial Paste:=8
        .Cells(1).PasteSpecial xlPasteValues, , False, False
        .Cells(1).PasteSpecial xlPasteFormats, , False, False
        .Cells(1).Select
        Application.CutCopyMode = False
        On Error Resume Next
        .DrawingObjects.Visible = True
        .DrawingObjects.Delete
        On Error GoTo 0
    End With

    'Publish the sheet to a htm file
    With TempWB.PublishObjects.Add( _
         SourceType:=xlSourceRange, _
         Filename:=TempFile, _
         Sheet:=TempWB.Sheets(1).Name, _
         Source:=TempWB.Sheets(1).UsedRange.Address, _
         HtmlType:=xlHtmlStatic)
        .Publish (True)
    End With

    'Read all data from the htm file into RangetoHTML
    Set fso = CreateObject("Scripting.FileSystemObject")
    Set ts = fso.GetFile(TempFile).OpenAsTextStream(1, -2)
    RangetoHTML = ts.readall
    ts.Close
    RangetoHTML = Replace(RangetoHTML, "align=center x:publishsource=", _
                          "align=left x:publishsource=")

    'Close TempWB
    TempWB.Close savechanges:=False

    'Delete the htm file we used in this function
    Kill TempFile

    Set ts = Nothing
    Set fso = Nothing
    Set TempWB = Nothing
End Function

 

[avare1907]

hocam desteğiniz için çok teşekkür ederim fakat anlatırken 1 konuyu atladığımı farkettim mailin bilgi kısmına (cc) e posta adresleri eklenebilirmi mümkünse...

 

[Korhan Ayhan]

Kod içinde geçen aşağıdaki satırı bulun ve dilediğiniz gibi değiştirin.

.CC = ""

Örnek;

B1 ve C1 hücrelerindeki adresleri ekler.

.CC = Cells(1, "B").Value & "," & Cells(1, "C").Value