excel tabloda veri arama

[lost_war]

merhaba. excel'e yeni başladım.daha doğrusu makro yazma işlemine.ufak tefek şeyleri yapabiliyorum ama karmaşık şeyler çıkınca birde alt yapıda az olunca malesef tıkanıp kalıyorum.sadece alıştırma yapma amaçlı bir tablo yaptım.bu tabloda atıyorum 5 satır 5 sütun var. ve bütün hüreler dolu.benim istediğim en üsteki satırda arama yapıp onun altındaki değerleri başka bir sayfaya kopyalamak.bunu da bir textbox'a değer girerek yapmak. yardımlarınız için şimdiden teşekkürler

 

[Necdet]

Merhaba,

Sorunuzu basit örnek dosya ile destekleyiniz.

 

[lost_war]

örnek dosyayı yükledim.sayfa c2 hücresinden başlayan ayın günleri altlarına doğru olan ise kişilerin o günlerde çalıştıkları saatler. ben bunu yaptığım makro ile textbox'a 15 yazdığım zaman ayın 15 inde kişilerin çalışma saatlerini sayfa 2 de hazırladığım tabloya fazla çalışandan az çalışana doğru sıralaması.Gün hücresine de hangi gün olduğunun yazılması.

 

[lost_war]

sanırım zor yerden çıktı

 

[Korhan Ayhan]

Aşağıdaki kodu deneyiniz.

Private Sub CommandButton1_Click()
    Dim S1 As Worksheet, S2 As Worksheet
    Dim Bul As Range, Adres As String, Son As Long
    
    If TextBox1 = "" Then
        MsgBox "Gün bilgisini giriniz!", vbCritical
        TextBox1.SetFocus
        Exit Sub
    End If
    
    Set S1 = Sheets("Sayfa1")
    Set S2 = Sheets("Sayfa2")
    
    Son = S2.Cells(Rows.Count, 1).End(3).Row
    If Son > 2 Then S2.Range("A3:C" & Son).Clear
    
    Set Bul = S1.Rows(2).Find(TextBox1, , , xlWhole)
    If Not Bul Is Nothing Then
        Son = S1.Cells(Rows.Count, 1).End(3).Row
        Adres = Cells(3, Bul.Column).Address(0, 0) & ":" & Cells(Son, Bul.Column).Address(0, 0)
        S1.Range("A3:B" & Son).Copy S2.Range("A3")
        S1.Range(Adres).Copy S2.Range("C3")
        MsgBox "İşleminiz tamamlanmıştır.", vbInformation
    Else
        MsgBox "Gün bulunamadı!", vbCritical
    End If

    Set Bul = Nothing
    Set S1 = Nothing
    Set S2 = Nothing
End Sub

 

[lost_war]

Teşekkürler Süper olmuş