Çözüldü Excel sayfalarını alfabetik sıralama kodu nasıl olmalı?

[assenucler]

Değerli Dostlar,

Ekli dosyada Sayfa1 dışında kalan sayfaları makro kodu ile alfabetik sıralama yapmak için yardımınızı bekliyorum.
Peşinen teşekkürler.

 

[ÖmerBey]

Merhaba,
Deneyiniz...

Sub kod()
Dim a As Byte, b As Byte, x As String, S As Worksheet
ReDim syf(1 To Sheets.Count - 1)
For Each S In Sheets
    If S.Name <> "Sayfa1" Then
        a = a + 1
        syf(a) = S.Name
    End If
Next
For a = LBound(syf) To UBound(syf)
    For b = a + 1 To UBound(syf)
        If syf(a) > syf(b) Then
            x = syf(a)
            syf(a) = syf(b)
            syf(b) = x
        End If
    Next
Next
Application.ScreenUpdating = False
For a = LBound(syf) To UBound(syf)
    Sheets(syf(a)).Move After:=Sheets(Sheets.Count)
Next
Application.ScreenUpdating = True
End Sub

 

[assenucler]

Sayın ÖmerBey,

İlginiz ve yardımınız için teşekkürler. Üstadım sıralama dışında olan Sayfa1'e Sayfa2'yi de eklemek için koda nasıl ekleme gerekiyor?

 

[ÖmerBey]

sıralama dışında olan Sayfa1'e Sayfa2'yi de eklemek için koda nasıl ekleme gerekiyor?

Yukarıdaki koda kırmızı renkli değişiklikleri uygulayınız.

ReDim syf(1 To Sheets.Count - 2)
For Each S In Sheets
If S.Name <> "Sayfa1" And S.Name <> "Sayfa2" Then

 

[assenucler]

Sağ olun, var olun.

Saygılar ÖmerBey,

 

[ÖmerBey]

Bilmukabele,
İyi çalışmalar...