e-mail atarken buton görünmesin

[sinnernekolens]

iyi günler arkadaşlar, aşağıdaki kod ile butono basınca sayfayı outlook'a ekliyor.
mail olarak gönderdiğim sayfada butonun çıkmasını istemiyorum. belli aralıkları kopyalamasını istiyorum örnek;a1:e50 benim içi önemli olan butonun sayfada görünmemesi o yüzden bu ilşlemi istiyorum farklı çözüm varsa oda olabilir.yardımlarınızı rica ediyorum

Sub ETA()
'Working in Excel 2000-2013
'For Tips see: http://www.rondebruin.nl/win/winmail/Outlook/tips.htm
    Dim FileExtStr As String
    Dim FileFormatNum As Long
    Dim Sourcewb As Workbook
    Dim Destwb As Workbook
    Dim TempFilePath As String
    Dim TempFileName As String
    Dim OutApp As Object
    Dim OutMail As Object

    With Application
        .ScreenUpdating = False
        .EnableEvents = False
    End With

    Set Sourcewb = ActiveWorkbook

    'Copy the ActiveSheet to a new workbook
    Sheets("ETA FORM").Copy
    Set Destwb = ActiveWorkbook

    'Determine the Excel version and file extension/format
    With Destwb
        If Val(Application.Version) < 12 Then
            'You use Excel 97-2003
            FileExtStr = ".xls": FileFormatNum = -4143
        Else
            'You use Excel 2007-2013
            Select Case Sourcewb.FileFormat
            Case 51: FileExtStr = ".xlsx": FileFormatNum = 51
            Case 52:
                If .HasVBProject Then
                    FileExtStr = ".xlsm": FileFormatNum = 52
                Else
                    FileExtStr = ".xlsx": FileFormatNum = 51
                End If
            Case 56: FileExtStr = ".xls": FileFormatNum = 56
            Case Else: FileExtStr = ".xlsb": FileFormatNum = 50
            End Select
        End If
    End With

    '    'Change all cells in the worksheet to values if you want
    '    With Destwb.Sheets(1).UsedRange
    '        .Cells.Copy
    '        .Cells.PasteSpecial xlPasteValues
    '        .Cells(1).Select
    '    End With
    '    Application.CutCopyMode = False

    'Save the new workbook/Mail it/Delete it
    TempFilePath = Environ$("temp") & "\"
    TempFileName = Format(Range("B11").Value, "yyyy-mm-dd-hh-mm") & " - " & Format(Now, "dd-mm-yy") & " - ETA FORM"

    Set OutApp = CreateObject("Outlook.Application")
    Set OutMail = OutApp.CreateItem(0)

    With Destwb
        .SaveAs TempFilePath & TempFileName & FileExtStr, FileFormat:=FileFormatNum
        On Error Resume Next
        With OutMail
            .To = ""
            .CC = ""
            .BCC = ""
            .Subject = Format(Range("B11").Value, "yyyy-mm-dd-hh-mm") & " - " & Format(Now, "dd-mm-yy") & " - ETA FORM"
            .Body = "İyi günler," & Chr(10) & Chr(10) & "İlgi gemiye ait ETA FORM ektedir." & Chr(10) & Chr(10) & "Bilgilerinize."
            .Attachments.Add Destwb.FullName
            .Display
        End With
        On Error GoTo 0
        .Close savechanges:=False
    End With

    'Delete the file you have send
    Kill TempFilePath & TempFileName & FileExtStr

    Set OutMail = Nothing
    Set OutApp = Nothing

    With Application
        .ScreenUpdating = True
        .EnableEvents = True
    End With
End Sub

 

[Emir Hüseyin Çoban]

. . .

Şu satırı ilave ederek deneyin.
ActiveSheet.Shapes.Range(Array("Button 1")).Delete

[COLOR="SeaGreen"]'Save the new workbook/Mail it/Delete it[/COLOR]
[B][COLOR="Purple"]ActiveSheet.Shapes.Range(Array("Button 1")).Delete[/COLOR][/B]
TempFilePath = Environ$("temp") & "\"
TempFileName = Format(Range("B11").Value, "yyyy-mm-dd-hh-mm") & " - " & Format(Now, "dd-mm-yy") & " - ETA FORM"

. . .

 

[sinnernekolens]

çok teşekkürler elinize sağlık