Dört farklı kritere göre toplam almak

[byysmn]

Arkadaşlar kolay gelsin
ekteki dosyamda sayfa 2 deki verilerin sayfa 1 de raporunu almak istiyorum özet taplo ile bazı sıkıntılar olduğundan formül ile toplam almak istiyorum.
Yapmak istediğim şubenin altında grup, grubun altıda ürün ,ürünün altında koda göre 4 farklı katagoriye göre toplam almak istiyorum İLGİNİZE TEŞEKKÜR EDERİM

 

[Korhan Ayhan]

Merhaba,

C4 hücresine aşağıdaki formülü uygulayın. Sağa ve alt hücrelere sürükleyin.

=TOPLA.ÇARPIM((Sayfa2!$A$3:$A$1000=$A$2)*(Sayfa2!$B$3:$B$1000=$B$2)*(Sayfa2!$C$3:$C$1000=$A$3)*(Sayfa2!$D$3:$D$1000=$B4)*(Sayfa2!$E$2:$K$2=C$3)*(Sayfa2!$E$3:$K$1000))

 

[byysmn]

hocam eline sağlık tam istediğim gibi olmuş teşekkürler

 

[byysmn]

Korhan hocam kolay gelsin
aynı formülün kod'ları sayanını nasıl yaparız
birde şube alanı boş olduğunda tümünü gösterebilirmiyiz
ilginize teşekkürler

 

[byysmn]

Korhan hocam kolay gelsin
formülün aynısının kodları sayanını nasıl yaparız
birde şube alanı boş oldudunda tamamını gösterebilirmiyiz

 

[Korhan Ayhan]

Merhaba,

Şube kodu boş olduğunda aşağıdaki şekilde kullanabilirsiniz.

Sayma işlemi yapar;

=EĞER($A$2="";TOPLA.ÇARPIM((Sayfa2!$B$3:$B$1000=$B$2)*(Sayfa2!$C$3:$C$1000=$A$3)*(Sayfa2!$D$3:$D$1000=$B4)*(Sayfa2!$E$2:$K$2=C$3));TOPLA.ÇARPIM((Sayfa2!$A$3:$A$1000=$A$2)*(Sayfa2!$B$3:$B$1000=$B$2)*(Sayfa2!$C$3:$C$1000=$A$3)*(Sayfa2!$D$3:$D$1000=$B4)*(Sayfa2!$E$2:$K$2=C$3)))

Toplama işlemi yapar;

=EĞER($A$2="";TOPLA.ÇARPIM((Sayfa2!$B$3:$B$1000=$B$2)*(Sayfa2!$C$3:$C$1000=$A$3)*(Sayfa2!$D$3:$D$1000=$B4)*(Sayfa2!$E$2:$K$2=C$3)*(Sayfa2!$E$3:$K$1000));TOPLA.ÇARPIM((Sayfa2!$A$3:$A$1000=$A$2)*(Sayfa2!$B$3:$B$1000=$B$2)*(Sayfa2!$C$3:$C$1000=$A$3)*(Sayfa2!$D$3:$D$1000=$B4)*(Sayfa2!$E$2:$K$2=C$3)*(Sayfa2!$E$3:$K$1000)))

 

[byysmn]

hocam saydırma bir sorun var bu kodların sayısını veriyor
ekteki dosyamda sayfa 2 deki verilerin sayfa 1 de raporunu almak istiyorum özet taplo ile bazı sıkıntılar olduğundan formül ile toplam almak istiyorum.
Yapmak istediğim şubenin altında grup, grubun altıda ürün ,ürünün altında koda göre 1,2,3,4,5,6,7 den dolu olanları saysın istiyorum
yardımcı olursanız çok sevinirim

 

[Korhan Ayhan]

Merhaba,

Görmek istediğiniz sonucuda dosyanıza elle yazıp foruma eklermisiniz.

 

[byysmn]

Hocam dosya ekte

Hocam SİZİDE UĞRAŞTIRDIM KUSURA BAKMAYIN OLURMU. DİĞER İSTEDİKLERİM SÜPER OLDU
İLGİNİZE ÇOK TEŞEKKÜR EDERİM

 

[Korhan Ayhan]

Merhaba,

Aşağıdaki formülü deneyin.

=EĞER($A$2="";TOPLA.ÇARPIM((Sayfa2!$B$3:$B$1000=$B$2)*(Sayfa2!$C$3:$C$1000=$A$3)*(Sayfa2!$D$3:$D$1000=$B4)*(Sayfa2!$E$2:$K$2=C$3)*(Sayfa2!$E$3:$K$1000<>""));TOPLA.ÇARPIM((Sayfa2!$A$3:$A$1000=$A$2)*(Sayfa2!$B$3:$B$1000=$B$2)*(Sayfa2!$C$3:$C$1000=$A$3)*(Sayfa2!$D$3:$D$1000=$B4)*(Sayfa2!$E$2:$K$2=C$3)*(Sayfa2!$E$3:$K$1000<>"")))

 

[byysmn]

Korhan hocam ilginize çok teşekkür ederim
süper oldu emeğinize sağlık

 

[assenucler]

Bir istek

Sayın byysmn;

Merhaba ve iyi pazarlar.

Sayın Korhan Ayhan üstadımızın formüllerine göre, dosyanızın en son şeklini sitemize eklemeniz mümkün mü?

Emek ve katkılarınız için teşekkürler.