Çözüldü Çoklu sayfalardaki yinelenen kayıtları makro ile listeleme

[Kuzeyyıldızı]

Değerli Forum ve üyelere merhabalar.
Hayırlı Ramazanlar.
Aşağıda ekli linkte çok sayfalı bir Excel kitabım var. Sayfalarda yinelenen kayıtlar var, kayıtlar bir veya birden fazla olabilir. Yinelenen kayıtlardan, herhangi bir personele ait yinelenen kayıtların, makro ile yeni sayfaya aktarmak mümkün müdür?
Yardımlarınız için şimdiden Teşekkürler.
http://s2.dosya.tc/server8/wlhlqy/i_yinelenen_kayitlari_makro_ile_listeleme.rar.html

 

[Ziynettin]

Sub kod()
Dim b()
    aranan = CStr(Sheets("list").[N1])
    For j = 1 To Worksheets.Count
        Set s1 = Sheets(j)
        If s1.Name <> "list" And s1.Name <> "Sayfa20" Then
            son = s1.Cells(Rows.Count, 1).End(3).Row
            If son > 1 Then
                a = s1.Range("A2:L" & son).Value
                For i = 1 To UBound(a)
                    If CStr(a(i, 1)) = aranan Then
                        say = say + 1
                        ReDim Preserve b(1 To UBound(a, 2) + 1, 1 To say)
                        For y = 1 To UBound(a, 2)
                            b(y, say) = a(i, y)
                        Next y
                        b(UBound(a, 2) + 1, say) = s1.Name
                    End If
                Next i
            End If
        End If
    Next j
Application.ScreenUpdating = False
Sheets("list").Range("A2:M" & Rows.Count) = Empty
    If say > 0 Then
        Sheets("list").[A2].Resize(say, UBound(a, 2) + 1) = Application.Transpose(b)
    End If
Application.ScreenUpdating = True
MsgBox "İşlem bitti.", vbInformation
End Sub

 

[Kuzeyyıldızı]

Sayın; Ziynettin
Hayırlı akşamlar.
İlginize çok teşekkür ederim, Win7-Ultimate Excel-2010 kullanıyorum. "Run-Time error '9': Subscript of range" çalışma zamanı hatası aldım. Dim b() den kaynaklanıyor olabilir mi teşekkür ederim.

 

[Ziynettin]

Bende çalışan dosyanız: İndir

 

[Kuzeyyıldızı]

Sayın; Ziynettin bey
İndirdiğim dosyada da aynı sorunla karşılaştım ancak, makronun listeleyeceği "Liste" isimli sayfa adından "e" harfini kaldırdım, sayfa adı "List" şeklinde mükemmel çalıştı, sizlerden Allah razı olsun.
Çok teşekkür ederim, şu an hazine bulmuş gibiyim, isteğim tam da bu idi. Allah işinizi rast getirsin.
Erken dönüş için, çok sağ olun, çok teşekkür ederim. Hoşça kalın.

 

[veyselemre]