çoklu kelime arama

[teyadih]

Arkadaşlar şöyle bir formüle ihtiyacım var
eğer O10'daki kelimelerin içinde
Başkan varsa 1000
Üye varsa 1000
Aday varsa 2000
(S) varsa 4000
(4/B) varsa 4000
bunların dışındaki kelimelere ise 3000 yazsın G10'a

Örnek
Başkan 1000
Hakim Adayı 2000
Mübaşir (4/B) 4000
Mübaşir 3000 gibi

şimdiden teşekkür ederim

 

[mehmetuca]

verilerinin A1 hücresinde olduğunu varsayıp B1 hücresine formülü yapıştırın

=EĞERSAY(A1;"*"&"başkan"&"*")*1000+EĞERSAY(A1;"*"&"üye"&"*")*1000+EĞERSAY(A1;"*"&"aday"&"*")*2000+EĞERSAY(A1;"*"&"(S)"&"*")*4000+EĞERSAY(A1;"*"&"(4/B)"&"*")*4000

 

[mehmetuca]

=EĞERSAY(A1;"*"&"başkan"&"*")*1000+EĞERSAY(A1;"*"&"üye"&"*")*1000+EĞERSAY(A1;"*"&"aday"&"*")*2000+EĞERSAY(A1;"*"&"(S)"&"*")*4000+EĞERSAY(A1;"*"&"(4/B)"&"*")*4000

 

[teyadih]

#AD? hatası veriyor sayın meranyar. her 2 formülde de. Deneme yapmış mıydınız
Eksik bilgi vermiş olabilirim. O10'da bulunan kelimelerin içinde
Başkan varsa 1000
Üye varsa 1000
Aday varsa 2000
(S) varsa 4000
(4/B) varsa 4000
bunların dışındaki kelimelere ise 3000 yazsın
aşağıdakileri A1 hücresine yazıp deneye bilir misiniz.
Mahkeme Başkanı 1000
Hakim Adayı 2000
Mübaşir (4/B) 4000
Mübaşir 3000
Z.Katibi (4/B) 4000
Z.Katibi 3000

 

[Korhan Ayhan]

Foruma formül ya da kod eklerken mesaj yazdığınız penceredeki # (diyez) simgesine tıklanıp eklerseniz yazım hatalarını engellemiş olursunuz.

Size önerilen formülde EĞ ERSAY şeklinde arada bir boşluk oluşmuş.

 

[teyadih]

evet korhan bey ondanmış ancak belirtiğim kelimelere belirttiğim rakamları veriyor ama bunların dışındaki kelimelere ise 3000 vermiyor
aşağıdakileri A1 hücresine yazıp deneye bilir misiniz.
Mahkeme Başkanı 1000
Hakim Adayı 2000
Mübaşir (4/B) 4000
Mübaşir 3000
Z.Katibi (4/B) 4000
Z.Katibi 3000

 

[mehmetuca]

Biraz uzun olacak ama:

=EĞER(EĞERSAY(A1;"*"&"başkan"&"*")*1000+EĞERSAY(A1;"*"&"üye"&"*")*1000+EĞERSAY(A1;"*"&"aday"&"*")*2000+EĞERSAY(A1;"*"&"(S)"&"*")*4000+EĞERSAY(A1;"*"&"(4/B)"&"*")*4000=0;3000;EĞERSAY(A1;"*"&"başkan"&"*")*1000+EĞERSAY(A1;"*"&"üye"&"*")*1000+EĞERSAY(A1;"*"&"aday"&"*")*2000+EĞERSAY(A1;"*"&"(S)"&"*")*4000+EĞERSAY(A1;"*"&"(4/B)"&"*")*4000)

 

[Korhan Ayhan]

Deneyiniz.

=TOPLA.ÇARPIM(ESAYIYSA((MBUL({"BAŞKAN";"ÜYE";"ADAY";"(S)";"(4/B)"};A1)))*({1000;1000;2000;4000;4000}))

 

[teyadih]

teşekkür ederim sayın meranyar olmuş

teşekkür ederim korhan bey daha kısa formül ama belirtiğim kelimeleri dışındaki kelimelere 3000 vermiyor

 

[Korhan Ayhan]

Deneyiniz.

=EĞER(A1="";0;EĞER(TOPLA.ÇARPIM(ESAYIYSA((MBUL({"BAŞKAN";"ÜYE";"ADAY";"(S)";"(4/B)"};A1)))*({1000;1000;2000;4000;4000}))=0;3000;TOPLA.ÇARPIM(ESAYIYSA((MBUL({"BAŞKAN";"ÜYE";"ADAY";"(S)";"(4/B)"};A1)))*({1000;1000;2000;4000;4000}))))

 

[teyadih]

tam isabet sayın korhan.