Carıi Hesap için Sayfalar arası veri akışını sağlamak

[rota59]

Merhaba,

Konu başlığını soruma uygun yaza bilmişimdir umarım.

Bir cari hesap tablosu hazırlamaktayım.
Ekte ki dosyada yapmak istediğimi açıkladım.
Formül ile beceremediğim den makro için ya da formül için yardımınızı rica ederim.

 

[rota59]

Eki unutmuşum pardon. Ek aşağı da mevcuttur

 

[Orion1]

Dosyanız ektedir.

Sub aktar59()
Dim sh As Worksheet, z As Object, sonsat As Long, k As Byte
Dim i As Long
Sheets("ANASAYFA").Select
Set z = CreateObject("Scripting.dictionary")
Range("K2:K13").ClearContents
For k = 1 To 12
    z.Add CStr(k), 0
Next k
For Each sh In Worksheets
    If sh.Name <> "ANASAYFA" Then
        sonsat = sh.Cells(Rows.Count, "B").End(xlUp).Row
        For i = 6 To sonsat
            z.Item(CStr(Month(sh.Cells(i, "B").Value))) = _
                z.Item(CStr(Month(sh.Cells(i, "B").Value))) + sh.Cells(i, "K").Value
        Next i
    End If
Next
Range("K2").Resize(z.Count, 1) = Application.Transpose(z.items)
MsgBox "İşlem tamamdır." & vbLf & "evrengizlen@hotmail.com"
End Sub

 

[Ziynettin]

Çeşitlilik olsun.

Option Explicit
Sub ay_topla()
Dim a(), b(), c(), d As Object, Krt As Variant
Dim Say As Long, i As Long, j As Byte, x As Long
Dim S1 As Worksheet, S2 As Worksheet
Set S2 = Worksheets("ANASAYFA")
Application.ScreenUpdating = False
Set d = CreateObject("Scripting.Dictionary")
b = Range("J2:J" & Cells(Rows.Count, "J").End(3).Row)
ReDim c(1 To UBound(b), 1 To 1)
For j = 1 To Worksheets.Count
    Set S1 = Sheets(j)
    If S1.Name <> "ANASAYFA" Then
    a = S1.Range("B6:K" & S1.Cells(Rows.Count, 2).End(3).Row)
        For i = 1 To UBound(a)
            Krt = UCase(Replace(Replace((Format(a(i, 1), "mmmm")), "i", "İ"), "ı", "I"))
            d(Krt) = d(Krt) + a(i, 10)
        Next i
End If
Next j
For x = 1 To UBound(b)
    c(x, 1) = d(b(x, 1))
Next x
S2.Range("K2").Resize(UBound(b)) = c
Application.ScreenUpdating = True
MsgBox "İşleminiz Bitti...", vbInformation
End Sub

 

[rota59]

Desteğiniz için teşekkür ederim ikisi de çok güzel.