Buton ekleme

[sinnernekolens]

Aşağıdaki kod ile butonu sayfa1'e ekleyip bilgileri sayfa2 ye aktarmasını nasıl sağlayabilirim.

Sub dovizz()
Dim hucre As Range
[r2:t5].ClearContents
    With ActiveSheet.QueryTables.Add(Connection:="URL;http://www.tcmb.gov.tr/yeni/tablolar.php", Destination:=[r2])
        .WebFormatting = xlWebFormattingNone
        .WebTables = "4"
        .Refresh BackgroundQuery:=False
    End With
    For Each hucre In [s4:t5]
    hucre = hucre / 10000
    Next
    Range("T2").Value = Now
    Range("T1").NumberFormat = "dd.mm.yyyy hh:mm:ss"
    [s4:t5].NumberFormat = "General"
End Sub

 

[Murat OSMA]

Range belirttiğiniz kısımlardan önce Sayfa2. yazın.

Örneğin;
Sayfa2.[r2:t5].ClearContents
Sayfa2.Range("T2").Value = Now

gibi...

Ya da
Sayfa2. yerine, Sheets("Sayfa adını buraya yazabilirsiniz).

 

[sinnernekolens]

Merhaba; Dediğiniz gibi yapıyorum fakat sayfa1'e de atıyor bilgileri, siz uyarlıyabilrseniz sevinirim.

 

[Murat OSMA]

Activesheet yerine de Sayfa2 yazın.

 

[sinnernekolens]

Uğraştım ama beceremedim

With ActiveSheet.QueryTables.Add(Connection:="URL;http://www.tcmb.gov.tr/yeni/tablolar.php", Destination:=[r2])

buton sayfa1'de bilgieri sayfa2'ye atacak; activesheet yerine sayfa2 nasil yazabilirim

 

[Korhan Ayhan]

Aşağıdaki kodu deneyiniz.

Sub Doviz_Kurlari()
    Dim Hucre As Range
    
    With Sheets("Sayfa2")
        .Range("R2:T5").ClearContents
        With .QueryTables.Add(Connection:="URL;http://www.tcmb.gov.tr/yeni/tablolar.php", Destination:=.Range("R2"))
            .WebFormatting = xlWebFormattingNone
            .WebTables = "4"
            .Refresh BackgroundQuery:=False
        End With
        
        For Each Hucre In .Range("S4:T5")
            Hucre = Hucre / 10000
        Next
        
        .Range("T2").Value = Now
        .Range("T2").NumberFormat = "dd.mm.yyyy hh:mm:ss"
        .Range("S4:T5").NumberFormat = "General"
        .Range("R:T").EntireColumn.AutoFit
    End With

    MsgBox "Kur bilgileri güncellenmiştir.", vbInformation
End Sub

 

[sinnernekolens]

Çok teşekkür ederim tam istediğim gibi oldu allah razı olsun

 

[Murat OSMA]

Uğraştım ama beceremedim

With ActiveSheet.QueryTables.Add(Connection:="URL;http://www.tcmb.gov.tr/yeni/tablolar.php", Destination:=[r2])

buton sayfa1'de bilgieri sayfa2'ye atacak; activesheet yerine sayfa2 nasil yazabilirim

Korhan Bey yanıt vermiş ama sorunuzun yanıtı çok basit değil mi ? Activesheet yerine Sayfa2 yazacaktınız.
Yani; ActiveSheet'i silip Sayfa2 yazacaktınız. :dusun: