Birleştirme

[gezgin-49]

Sayın üstadlarım ekteki dosyada
YAN YANA BİRLEŞTİR butonuna bastığımda soldaki verilerin K hücresi ile R hücrelerine yılı ve dosya numaralarını arada "/" olarak birleştirmesini istiyorum.

Örneğin : K2 hücresine 2006/5, L2 hücresine 2006/6, M2 hücresine 2006/10 gibi,

ALT ALTA BİRLEŞTİR butonuna bastığımda soldaki verilerin U2 hücresinden aşağıya doğru yılı ve dosya numaralarını arada "/" olarak birleştirmesini istiyorum.

Örneğin : U2 hücresine 2006/5, U3 hücresine 2006/6, U4 hücresine 2006/10 gibi bu konuda yardımlarınızı bekliyorum.

SAYGILARIMLA

 

[Ömer]

Merhaba,

Bu şekilde deneyin.

'yan yana birleştir
Sub YanaBirlestir()
    Dim i As Long, j As Byte
    
    Application.ScreenUpdating = False
    Range("K:R").ClearContents
    
    For i = 2 To Cells(Rows.Count, "A").End(xlUp).Row
        If IsNumeric(Cells(i, "A")) = True Then
            For j = 1 To 8
                If Cells(i, j + 1) <> "" Then
                    Cells(i, 10 + j) = Cells(i, "A") & "/" & Cells(i, j + 1)
                End If
            Next j
        End If
    Next i
    
End Sub
'alt alta birleştir
Sub AltaBirlestir()
    Dim i As Long, j As Byte
    
    Application.ScreenUpdating = False
    Range("U:U").ClearContents
    
    For i = 2 To Cells(Rows.Count, "A").End(xlUp).Row
        If IsNumeric(Cells(i, "A")) = True Then
            For j = 1 To 8
                If Cells(i, j + 1) <> "" Then
                    son = Cells(Rows.Count, "U").End(xlUp).Row + 1
                    Cells(son, "U") = Cells(i, "A") & "/" & Cells(i, j + 1)
                End If
            Next j
        End If
    Next i
    
End Sub

.

 

[gezgin-49]

Sayın üstadım tam istediğim gibi olmuş, çok teşekkür ediyorum, Allah sizden razı olsun. (Amin)