Bir hücreye tıklayınca zoom yapması ve bir hücreyi DEL tuşu kullanarak silince formüllerin korunması

[sefa044]

Bir hücreye tıklayınca zoom yapan makro ile
bir hücreyi DEL tuşu kullanarak silince sabitleri silen ancak hücredeki formülleri koruyan makro arıyorum. tşk.

 

[turist]

Zoom yapmak için sayfa koduna ekleyip deneyin.

Private Sub worksheet_selectionchange(ByVal Target As Range)
    Dim xRg As Range
    Dim xCell As Range
    Dim xShape As Variant
    Set xRg = Target.Areas(1)
    For Each xShape In ActiveSheet.Pictures
        If xShape.Name = "zoom_cells" Then
            xShape.Delete
        End If
    Next
    If Application.WorksheetFunction.CountBlank(xRg) = xRg.Count Then Exit Sub
    Application.ScreenUpdating = False
    xRg.CopyPicture appearance:=xlScreen, Format:=xlPicture
    Application.ActiveSheet.Pictures.Paste.Select
    With Selection
        .Name = "zoom_cells"
        With .ShapeRange
            .ScaleWidth 1.6, msoFalse, msoScaleFromTopLeft
            .ScaleHeight 1.6, msoFalse, msoScaleFromTopLeft
            With .Fill
                .ForeColor.SchemeColor = 1
                .Visible = msoTrue
                .Solid
                .Transparency = 0
            End With
        End With
    End With
    xRg.Select
    Application.ScreenUpdating = True
    Set xRg = Nothing
End Sub

bir hücreyi DEL tuşu kullanarak silince sabitleri silen ancak hücredeki formülleri koruyan

ile TAM olarak neyi istediğiniz çok net değil. Detaylı açıklama yaparsanız, bunu yapmakla esas amacınızı belirtirseniz; daha kolay ve doğru cevap bulabilirsiniz.
İyi çalışmalar...