Biçimleri değiştirmeden birleştirme

[japoncaci]

merhaba
5 yan yana hücreyi birleştirmek istiyorum
formülden birleştirince yazı büyüklükleri ve fontlar da aynı oluyor. farklı olmasını istiyorum.

a1 deki 12 boyuntunda "SimSun" fontu
c1 deki 10 boyuntunda "MS Mincho" fontu
e1 deki 8 boyutunda "Times New Roman" fontu

2 dosya ekledim birincisini yapmak istiyorum ama japonca karekterler bilgisayarınızda çıkmıyorsa 2. dosyadan göstermeniz mümkünse sevinirim.

teşekkürler...

 

[Korhan Ayhan]

Selamlar,

Sayfanızın kod bölümüne aşağıdaki kodu uygulayın. "F" sütununda herhangi bir hücreyi tıkladığınızda yada seçtiğinizde işlem otomatik olarak yapılacaktır.

Option Explicit
 
Private Sub Worksheet_SelectionChange(ByVal Target As Range)
    Dim UZUNLUK1 As Byte, UZUNLUK2 As Byte, UZUNLUK3 As Byte
    
    If Intersect(Target, Range("F:F")) Is Nothing Then Exit Sub
    Application.ScreenUpdating = False
    
    UZUNLUK1 = Len(Cells(Target.Row, "A"))
    UZUNLUK2 = Len(Cells(Target.Row, "C"))
    UZUNLUK3 = Len(Cells(Target.Row, "E"))
    Target = Cells(Target.Row, "A") & Cells(Target.Row, "B") & Cells(Target.Row, "C") & Cells(Target.Row, "D") & Cells(Target.Row, "E")
    
    With Target.Characters(Start:=1, Length:=UZUNLUK1).Font
        .Name = "SimSun"
        .FontStyle = "Normal"
        .Size = 12
    End With
    
    With Target.Characters(Start:=UZUNLUK1 + 3, Length:=UZUNLUK2).Font
        .Name = "MS Mincho"
        .FontStyle = "Normal"
        .Size = 11
    End With
    With Target.Characters(Start:=UZUNLUK1 + UZUNLUK2 + 7, Length:=UZUNLUK3).Font
        .Name = "Times New Roman"
        .FontStyle = "Normal"
        .Size = 8
    End With
    
    Application.ScreenUpdating = True
End Sub

 

[japoncaci]

selam korhan. dediğini yapmaya çalıştım.
geliştirici kartından "makro" ya tıkladım. makro adı verip "oluştur" dedim.
yazdığın kodu açılan penceredeki "Sub d() End Sub" arasına kopyaladım. "copile error invalid inside procedure" diye mesaj çıktı.
sonra ilk çıkan sayfadaki "Sub d() End Sub" silip verdiğin kodu kopyaladım. makroyu uygula dediğimde hiçbirşey çıkmadı.
doğru yapıp yapmadığımıda bilmediğim için ayrıntılı yazmaya çalıştım.

 

[Korhan Ayhan]

Selamlar,

Yanlış uygulamışsınız. Önerdiğim kod sayfaya ait koddur. Modül kodu değildir.

Aşağıdaki işlemleri yapınız.

Sayfa adı üzerinde sağ klik yapın.
Açılan menüden "KOD GÖRÜNTÜLE" seçeneğini seçin.
Karşınıza beyaz renkli boş bir sayfa açılacaktır.
Vermiş olduğum kodu bu beyaz bölüme uygulayın.

Son olarak bu pencereyi kapatın. Dosyanızı kaydedip kapatın ve tekrar açın. Sayfada "F" sütunundan hücrelerden seçim yaptığınızda kod çalışacaktır.

 

[japoncaci]

teşekkürler. çalıştı fakat bir iki yer aklıma pek yatmadı.
kodu boş beyaz sayfaya yapıştırdım. sonra "save" butonuna bastım.
"makro içermeyen çalışma kitabı olarak kaydetmeye devam etmek için Evetet i tıklatın" diye mesaj çıktı.

evet dedim.

burdan sonra sayfayı kapatıp açınca kod işlevsiz oluyor. kapatmadan f den biryere basınca çalışıyor. fakat teker teker hepsine basmak gerekiyor. yani 1000 lerce tıklama yapmak gerekiyor.

belki hepsi aynı anda değişir diye f stununun başlığına tıkladığımda blg. kilitlendi.

son bikez daha açıklaman münkünse çok sevinirim.

 

[hsayar]

EXEL 2007 VE 2010 ile çalışıyorsanız dosya türünü Makra içerebilen çalışma kitabı (xlsm) ya da 2003 dosya türü olna xls olarak kaydediniz.

 

[japoncaci]

EXEL 2007 VE 2010 ile çalışıyorsanız dosya türünü Makra içerebilen çalışma kitabı (xlsm) ya da 2003 dosya türü olna xls olarak kaydediniz.

dediğin gibi kaydettim (xlsm) şuan çalışıyor ama sanırım bu kod tüm satırları aynı anda birleştirmiyor. her satır için tıklamam gerekiyor.

 

[japoncaci]

EXEL 2007 VE 2010 ile çalışıyorsanız dosya türünü Makra içerebilen çalışma kitabı (xlsm) ya da 2003 dosya türü olna xls olarak kaydediniz.

teşekkürler
dediğin gibi kaydettim (xlsm) şuan çalışıyor ama sanırım bu kod tüm satırları aynı anda birleştirmiyor. her satır için tıklamam gerekiyor.

 

[Korhan Ayhan]

Selamlar,

İlk mesajınızda eksik açıklama yaptığınız için konu uzadı gitti. Sorularınızı sorarken formülle çözüm arıyorsanız hücre aralıklarını belirtmelisiniz. Eğer makro ile çözüm gerekiyorsa hücreye veri girişi anındamı yoksa bir butona basıncamı işlem yapılacak bunları belirtmelisiniz. Çünkü bizler her üyemize her sorusunda çözüm butonlamı yada hücreye veri girişindemi olacak diye soramayız. Bu tarz detayları soruyu soran üyelerimiz vermek durumundadır. Aksi halde verilen yanıtlar sizleri tatmin etmemektedir.

Aşağıdaki kodu BOŞ BİR MODÜLE ekleyip çalıştırın. Dilerseniz sayfada oluşturacağınız bir butona kodu atayıp kullanabilirsiniz. Butona kod atamayı bilmiyorsanız lütfen linki inceleyin.

Option Explicit
 
Sub VERİLERİ_BİRLEŞTİR()
    Dim X As Long, UZUNLUK1 As Byte, UZUNLUK2 As Byte, UZUNLUK3 As Byte
    
    Application.ScreenUpdating = False
    
    Range("F:F").ClearContents
    
    For X = 1 To Range("A65536").End(3).Row
        UZUNLUK1 = Len(Cells(X, "A"))
        UZUNLUK2 = Len(Cells(X, "C"))
        UZUNLUK3 = Len(Cells(X, "E"))
        Cells(X, "F") = Cells(X, "A") & Cells(X, "B") & Cells(X, "C") & Cells(X, "D") & Cells(X, "E")
        
        With Cells(X, "F").Characters(Start:=1, Length:=UZUNLUK1).Font
            .Name = "SimSun"
            .FontStyle = "Normal"
            .Size = 12
        End With
        
        With Cells(X, "F").Characters(Start:=UZUNLUK1 + 3, Length:=UZUNLUK2).Font
            .Name = "MS Mincho"
            .FontStyle = "Normal"
            .Size = 11
        End With
        With Cells(X, "F").Characters(Start:=UZUNLUK1 + UZUNLUK2 + 7, Length:=UZUNLUK3).Font
            .Name = "Times New Roman"
            .FontStyle = "Normal"
            .Size = 8
        End With
    Next
    
    Range("F:F").EntireColumn.AutoFit
    
    Application.ScreenUpdating = True
    
    MsgBox "İşleminiz tamamlanmıştır.", vbInformation
End Sub

 

[japoncaci]

yıllardır execell kullanıyorum fakat bu siteye girinceye kadar yalnızca a' dan z' ye sıralamayı biliyordum.

Teşekkürler az önce verdiğiniz kodu çalıştırmayı başardım.

 

[ahatbek]

Merhebe bu konuda bir soruda benden gelsin,
şimdi yanyana hücreleri birleştirdik ama alt alta olan hücreyi nasıl birleştirelim?