Belli bir aralıkta sıralama

[tamer42]

Merhaba,
ekli tabloda olduğu gibi "A" sütununda veriler mevcut; bu verilerde 2-3 arasında kalan değerleri kendi içinde sıra numarasını almak istiyorum,

"A" sütununda eğer değer 2-3 arasında ise (2 ve 3 dahil) B sütununa kendi içinde (2-3 aralığındaki tüm değerlerde) bir sıralama yapacak ve bu sıra numarasını en küçükten başlayarak, (en küçük:1) B sütununda karşına yazacak bir formül aramaktayım.
desteğinizi için şimdeden teşekkürler,

iyi Çalışmalar.

 

[Korhan Ayhan]

Mesela A sürunundaki 2,09 değerinin karşınıza ne yazmalı?

 

[tamer42]

Mesela A sürunundaki 2,09 değerinin karşınıza ne yazmalı?

en küçükse : 1, bir yükseği 2, bir sonraki yüksek değeri :3 , 4, 5 diye gidecek.
özetle küçükten büyüğe doğru kaçıncı sırada olduğu ( 1,2,3.....................9,10..........................)

 

[Korhan Ayhan]

Deneyiniz.

DİZİ formüldür. (Ctrl+Shift+Enter)

=EĞERHATA(KAÇINCI(A2;KÜÇÜK(EĞER($A$2:$A$115>=2;EĞER($A$2:$A$115<=3;$A$2:$A$115;9,999E+307);9,999E+307);SATIR($A$2:$A$115)-1);0)+ÇOKEĞERSAY($A$2:A2;">=2";$A$2:A2;"<=3";$A$2:A2;A2)-1;"")

 

[Korhan Ayhan]

Bu da biraz öğrenmek adına E-Tablo uygulaması..

=IFERROR(MATCH(A2;SORT(QUERY($A$2:$A$115;"Select A Where A>=2 And A<=3"));0)+COUNTIFS($A$2:A2;">=2";$A$2:A2;"<=3";$A$2:A2;A2)-1;"")

 

[Haluk]

Korhan Bey, iyi başlangıç ....

.

 

[tamer42]

Bu da biraz öğrenmek adına E-Tablo uygulaması..

=IFERROR(MATCH(A2;SORT(QUERY($A$2:$A$115;"Select A Where A>=2 And A<=3"));0)+COUNTIFS($A$2:A2;">=2";$A$2:A2;"<=3";$A$2:A2;A2)-1;"")

Ekli dosyayı görüntüle 223688

Korhan hocam çok teşekkür ederim, gerçekten harika bir iş yapmışsınız. emeğine sağlık!

 

[Haluk]

Ekli alternatif formül ise; şartları sağlayan verileri ve kaçıncı olduklarını ayrı ayrı listeler.

E2 hücresine yazılacak formül, bütün tabloyu oluşturacaktır;

=SORT({QUERY(A2:A;"Select A where A>=2 and A<=3")\ARRAYFORMULA(RANK(QUERY(A2:A;"Select A where A>=2 and A<=3");QUERY(A2:A;"Select A where A>=2 and A<=3");TRUE))};2;TRUE)

.

 

[Haluk]

Tekrar eden değerlerden kaçınmak için de, aşağıdaki gibi olabilir;

2-3 arası değerleri listelemek için J2 hücresine;

=SORT(UNIQUE(FILTER(A2:A115;A2:A115>=2;A2:A115<=3));1;TRUE)

Bu değerlerin kaçıncı olduklarını listelemek için de, K2 hücresine;

=ARRAYFORMULA(RANK(J2:J26;J2:J26;TRUE))

.

 

[c_235]

Bu da biraz öğrenmek adına E-Tablo uygulaması..

=IFERROR(MATCH(A2;SORT(QUERY($A$2:$A$115;"Select A Where A>=2 And A<=3"));0)+COUNTIFS($A$2:A2;">=2";$A$2:A2;"<=3";$A$2:A2;A2)-1;"")

Ekli dosyayı görüntüle 223688

Koray bey merhaba;

bende formül çalışmadı #AD? hatası veriyor.

 

[Korhan Ayhan]

Nerede uyguladınız.

 

[c_235]

Nerede uyguladınız.

verilen dosyada uyguladım ama hata aldım, kodlar ingilizce olsada çalışmıyor mu ?

 

[Haluk]

@c_235 ;

Excel değil, Google Sheets formülü .....

.

 

[c_235]

@c_235 ;

Excel değil, Google Sheets formülü .....

.

Gözümden kaçmış nerede uygulandığı teşekkürler.