Belirtilen sayfaya aktarma

[mbattal]

Arkadaşlar merhaba,
Ocak, Şubat,Mart..... Aralık diye 12 adet sayfam var.
Userform üzerideki textbox lardaki verileri textbox1 de yazılan sayfaya aktarmak istiyorum.
Örneğin TextBox1 de OCAK yazıyorsa diğer bütün textbox lardaki bilgilerin OCAK sayfasının belirlediğim hücrelerine aktarmasını istiyorum.
Nasıl bir kod yazılabilir ?
Yardımcı olursanız sevinirim.

 

[Ömer]

Merhaba,

Sorunuzu küçük bir örnek dosya ile desteklermisiniz.

 

[mbattal]

belirtilen sayfaya aktarma

Sayın Ömer,
İlginize teşekkür ederim.
Dosyayı ekledim açıklamayı Userform üzerine yazdım
Teşekkürler

 

[Ömer]

Sayın Ömer,
İlginize teşekkür ederim.
Dosyayı ekledim açıklamayı Userform üzerine yazdım
Teşekkürler

Bu mantıkla geri kalanını siz doldurursunuz. Eğer textbox numaraları ekteki gibi sıralı gidiyorsa 35 satır yazmak yerine daha kısa bir kod yazılabilir. Bundan emin olamadığım için uzun yolu verdim.

Private Sub CommandButton1_Click()
 
    Dim syf As Worksheet
 
    If ComboBox1.Value = "" Then Exit Sub
 
    Set syf = Sheets("" & ComboBox1.Value & "")
 
    With syf
        .Range("C3") = TextBox1.Text
        .Range("C4") = TextBox2.Text
        '
        '
        '
    End With
 
End Sub

 

[mbattal]

Sayın Ömer Bey,
Çok teşekkür ederim...
Esasında textboxlarım sıralı olarak gidiyor ve 35 ten çok fazla.. Daha kısa bir yol varsa rica edebilirmiyim..

 

[Ömer]

Sayın Ömer Bey,
Çok teşekkür ederim...
Esasında textboxlarım sıralı olarak gidiyor ve 35 ten çok fazla.. Daha kısa bir yol varsa rica edebilirmiyim..

Bu şekilde deneyin.

Veri aktarımından sonra Textbox daki verileri temizlemek istemezseniz mavi işaretli kod satırını silersiniz.

Mod 7 deki 7 sayısı tablo 7 satırlı olduğı için kullanılmıştır.
sat + 2 deki 2 sayısı veriler 3.satırdan başladığı için kullanılmıştır.
sut = 2 deki 2 sayısı veriler 3.sütundan başladığı için kullanılmıştır.

Buna göre kendi dosyanıza uyarlarsınız.

Private Sub CommandButton1_Click()
 
    Dim syf As Worksheet, i As Byte, sat As Long, sut As Integer
 
    If ComboBox1.Value = "" Then Exit Sub
 
    Set syf = Sheets("" & ComboBox1.Value & "")
 
    sut = 2
    For i = 1 To 35
        sat = ((i - 1) Mod 7) + 1
        If (i - 1) Mod 7 = 0 Then
            sut = sut + 1
        End If
        syf.Cells(sat + 2, sut) = Controls("TextBox" & i).Text
        [COLOR=blue]Controls("TextBox" & i).Text = ""[/COLOR]
    Next i
 
End Sub

Ayrıca ay isimlerini Combobox'a alırken sayfadaki yardımcı hücre kullanmadan eski kodların yerine aşağıdaki kodları kullanabilirsiniz.

Private Sub UserForm_Initialize()
 
    Dim i As Byte
 
    For i = 1 To 12
        ComboBox1.AddItem Format(CDate("1." & i), "mmmm")
    Next i
 
End Sub

.

 

[mbattal]

Sayın Ömer Bey,
Elinize, Kolunuza,Aklınıza ve Gözünüze Sağlık...
Çok teşekkür ederim...