Belirli sıradaki karakteri değiştirme

[tamer42]

Merhaba,
Ekli dosyada "A" sütunda yer alan değerlerin;
8. sıradaki karakterini "a" olarak değiştirmenin paratik bir yolu var mıdır?

Aşağıdaki kod istenilen değeri değiştiriyor, benim istediğim her bir satırda 8. sırada hangi karakter varsa o karakteri "a" olarak değiştirecek

  Range("A:A").Replace What:="0", Replacement:="a"

desteğiniz için şimdiden teşekkürler,
iyi akşamlar.

 

[Korhan Ayhan]

Merhaba,

Linkteki fonksiyonu deneyebilirsiniz.

DEĞİşTİr işlevi - Microsoft Desteği

support.microsoft.com

 

[tamer42]

Merhaba,

Linkteki fonksiyonu deneyebilirsiniz.

DEĞİşTİr işlevi - Microsoft Desteği

support.microsoft.com

Korhan Hocam teşekkürler,
Aşağıdaki gibi uygulayabiliyoruz,
bu durumu for ... next döngüsüne girmeden tüm sütuna bir seferde uygulamak mümkün müdür?

w = Application.WorksheetFunction.Replace("abcdefghijk", 6, 1, "@")
MsgBox w

iyi akşamlar.

 

[dost]

Merhaba,

With CreateObject("ADODB.CONNECTION")
        .Open "Provider=Microsoft.Ace.Oledb.12.0;Extended Properties='Excel 12.0;HDR=YES;IMEX=0';Data Source=" & _
               ThisWorkbook.FullName
         .Execute " UPDATE [Sheet1$]  " & _
                  " SET [Baslik1] = LEFT([Baslik1], 7) & 'a' & RIGHT([Baslik1], LEN([Baslik1]) - 8) " & _
                  " WHERE LEN([Baslik1]) > 7"
        .Close
End With

 

[Korhan Ayhan]

Aşağıdaki gibi de olabilir..

Option Explicit

Sub Replace_Specific_Character()
    Dim WS As Worksheet
    Dim Last_Row As Long
    Dim Rng As Range
    Dim Character_Index As Integer
    Dim New_Character As Variant
    
    Set WS = ThisWorkbook.Sheets("Sayfa1")
    
    Last_Row = WS.Cells(WS.Rows.Count, 1).End(3).Row
    
    Set Rng = WS.Range("A1:A" & Last_Row)
    
    Character_Index = 8
    New_Character = "a"
    
    Rng.Value = Evaluate("IF(ROW(" & Rng.Address & "),LEFT(" & Rng.Address & "," & _
                         Character_Index - 1 & ")&""" & New_Character & """&MID(" & Rng.Address & _
                         "," & Character_Index + 1 & ",LEN(" & Rng.Address & ")-" & Character_Index & "))")

    Set Rng = Nothing
    Set WS = Nothing
    
    MsgBox "İşleminiz tamamlanmıştır.", vbInformation
End Sub

 

[tamer42]

Aşağıdaki gibi de olabilir..

Option Explicit

Sub Replace_Specific_Character()
    Dim WS As Worksheet
    Dim Last_Row As Long
    Dim Rng As Range
    Dim Character_Index As Integer
    Dim New_Character As Variant
   
    Set WS = ThisWorkbook.Sheets("Sayfa1")
   
    Last_Row = WS.Cells(WS.Rows.Count, 1).End(3).Row
   
    Set Rng = WS.Range("A1:A" & Last_Row)
   
    Character_Index = 8
    New_Character = "a"
   
    Rng.Value = Evaluate("IF(ROW(" & Rng.Address & "),LEFT(" & Rng.Address & "," & _
                         Character_Index - 1 & ")&""" & New_Character & """&MID(" & Rng.Address & _
                         "," & Character_Index + 1 & ",LEN(" & Rng.Address & ")-" & Character_Index & "))")

    Set Rng = Nothing
    Set WS = Nothing
   
    MsgBox "İşleminiz tamamlanmıştır.", vbInformation
End Sub

çok teşekkürler Korhan Hocam
iyi ki varsınız..

 

[dost]

@tamer42,

İkinci kez aynı şeyi yapıyorsunuz.

Sorduğunuz sorulara verdiğimiz cevaplarla paylaştığımız bilgimizi ve zamanımızı yok sayıyorsunuz

Bundan sonra soracağınız sorularınızın cevabını bilsem bile asla cevap vermeyeceğim (diğer forumdaki arkadaşlar kusura bakmasınlar).

 

[Necdet]

@tamer42,

İkinci kez aynı şeyi yapıyorsunuz.

Sorduğunuz sorulara verdiğimiz cevaplarla paylaştığımız bilgimizi ve zamanımızı yok sayıyorsunuz

Bundan sonra soracağınız sorularınızın cevabını bilsem bile asla cevap vermeyeceğim (diğer forumdaki arkadaşlar kusura bakmasınlar).

Haklısınız, geri dönüş olması gerek.

 

[tamer42]

@tamer42,

İkinci kez aynı şeyi yapıyorsunuz.

Sorduğunuz sorulara verdiğimiz cevaplarla paylaştığımız bilgimizi ve zamanımızı yok sayıyorsunuz

Bundan sonra soracağınız sorularınızın cevabını bilsem bile asla cevap vermeyeceğim (diğer forumdaki arkadaşlar kusura bakmasınlar).

Kusura bakmayın Hocam
Korhan Hocam' ın cevaplarına odaklandığım için sizi atlamışım, lütfen özrümü kabul edin.
bir kaç gündür yoğunluktan dolayı telefondaki mesajlara bile bakamadım.
ilgi ve alakanız için tekrar tekrar teşekkür ediyorum.