Soru Belirlenen aralığı listboxta gösterme

[sirkülasyon]

ekli dosyamda bir tablo mevcut. D ve H aralığı birleştirilmiş.
Tabloyu B10 : J24 aralığını listboxta nasıl gösterebilirim

 

[Korhan Ayhan]

Bu şekilde gösterebilirsiniz.

Private Sub UserForm_Initialize()
    ListBox1.ColumnCount = 9
    ListBox1.ColumnWidths = "40;60;300;0;0;0;0;40;40"
    ListBox1.RowSource = "B10:J24"
End Sub

 

[veyselemre]

Private Sub UserForm_Initialize()
    Dim veri(), i&, ii%, sut%
    veri = Sheets("Sayfa1").Range("B10:J24").Value
    With ListBox1
        .ColumnCount = 5
        For i = 1 To UBound(veri)
            .AddItem veri(i, 1)
            sut = 1
            For ii = 2 To UBound(veri, 2)
                If Not (ii > 3 And ii < 8) Then
                    .List(.ListCount - 1, sut) = veri(i, ii)
                    sut = sut + 1
                End If
            Next ii
        Next i
    End With
End Sub

Private Sub UserForm_Initialize()
    Dim veri(), i&, ii%
    veri = Sheets("Sayfa1").Range("B10:J24").Value
    With ListBox1
        .ColumnCount = 5
        For i = 1 To UBound(veri)
            For ii = 4 To 5
                veri(i, ii) = veri(i, ii + 4)
            Next ii
        Next i
        ReDim Preserve veri(1 To UBound(veri), 1 To 5)
        .List = veri
    End With
End Sub

 

[sirkülasyon]

Korhan ve Veysel Abime teşekkür eder, saygılarımı sunarım.