belirlediğim sırada sekmeleri çıktı alsın

[modoste]

merhaba sayın hocalarım
bugün karşılaştığım bir durum için soru sorma ihtiyacı duydum

bir çalışma dosyamda 15 tane sekme var ve adları "A","B","C","D".. devam ediyo
her bir sekmenin sayfa sonu ayarlaması yapıldıktan sonra Çıktı Sırası diye bir sekme adı açıp A2 den başlayıp aşağıya doğru devam eden bir liste yapsam ve buraya almak istediğim sekme adlarını sıralasam
örnek
A2= D
A3= E
A4= A dediğimde 3 tane sekmeyi sadece yazdırmak istesem ve sırası önce D gelcek Sonra "E" gelcek sonrada "A" gelcek
bunun yapılabilmesi mümkün mü makroyla yada başka birşeyle

 

[Necdet]

Merhaba,

Sekme dediğiniz şey nedir? Excel Sayfası mıdır?

 

[modoste]

evet hocam sekme=çalışma sayfası
daha önceden siz hocalarımdan gelen makrolu çözüm ile, çalışma dosyasında bulunan sekmeleri(çalışma sayfası) altalta listelemeyi kullanmaktayım bazı çalışmalarımda
çalışma sayfa adlarını altalta listeledikten sonra ben hemen yanında sağ tarafındaki sütuna 1 den kaç sayfa varsa oraya kadar numaralar vercem ve benim verdiğim numaralara göre çıktıyı alırken belirleme yapacak.

 

[Korhan Ayhan]

Merhaba,

Aşağıdaki kodu deneyiniz.

Sub YAZDIR()
    Dim X As Integer, Sayfa As Variant, S1 As Worksheet, Say As Integer
    
    With Sheets("Çıktı Sırası")
    
        ReDim Sayfa(1 To 1)
        
        For X = 2 To .Cells(Rows.Count, 1).End(3).Row
            Set S1 = Nothing
            On Error Resume Next
            Set S1 = Sheets(.Cells(X, 1).Text)
            On Error GoTo 0
            If Not S1 Is Nothing Then
                Say = Say + 1
                ReDim Preserve Sayfa(1 To Say)
                Sayfa(Say) = S1.Name
            End If
        Next
    End With
    
    If Say > 0 Then
        Sheets(Sayfa).PrintOut
        MsgBox "Toplam yazdırılan sayfa ; " & Say
    End If
End Sub

 

[modoste]

en kısa sürede deneyip size dönecem hocam çok teşekkür ederim