Aynı hücrede bulunan metin ve sayıyı farklı hücrelere alma

[vitamin]

Arkadaşlar, herkese günaydın.

Ek'te örnek çalışma mevcut.

Aynı hücreden bulunan ve uzunlukları her iki hücredede farklı olan metin ve sayıyı farklı hücrelere nasıl alabiliriz acaba?

ilgi için şimdiden teşekkürler.

 

[hamitcan]

Linkleri inceleyin.
http://www.excel.web.tr/f50/hucredeki-sayy-ve-metni-ayyrma-t39687.html
http://www.excel.web.tr/f50/ayny-hucredeki-sayy-ve-metni-ayyrma-t41680.html

 

[Ali]

Verileriniz hep bu şekilde ise

C2 hücresine

=ARA(9,99999999999999E+307;--SAĞDAN(PARÇAAL(A2;BUL("FT.";A2)+1;TOPLA(BUL({"FT";","};A2)*{-1;1})-1);SATIR($A$1:$A$1024)))

yazıp aşağı doğru çekiniz.

D2 hücresine

=PARÇAAL(A2;MBUL(",";A2)+1;UZUNLUK(A2))

yazıp aşağı doğru çekiniz.

B2 hücresinede

=YERİNEKOY(YERİNEKOY(YERİNEKOY(PARÇAAL(A2;MBUL("FT.";A2)+3;UZUNLUK(A2));C2;"");D2;"");",";"")

yazıp aşağı doğru çekiniz.

 

[vitamin]

Ali bey,
Öncelikle ilginiz için teşekkür ederim.

C ve D hücre formülleri ok.

B hücresinde ise #DEĞER! vermekte?

 

[Ali]

Son formülde "FT ."

kısmında FT ile . arasında boşluk kalmış o kısmı düzeltip denermisiniz.

Kopyala- yapıştır yaptığımız zaman forum yazılımı zaman zaman böyle yapabiliyor.

 

[vitamin]

Ok.
Boşluğu silince formül açlışıyor fakat B2 Hücresine, E SERVİS getiriyor.

Sadece, E getirebilir mi?

 

[Ali]

Bende sorun olmadı bir kontrol edermisiniz?

 

[vitamin]

Ok. Ali bey.

İlginiz için tekrar teşekkür ederim.

iyi çalışmalar.

 

[Korhan Ayhan]

Selamlar,

Ali beyin önerdiği şık formüllerle sorunuz çözümlenmiş. Alternatif olarak aşağıdaki formülleride kullanabilirsiniz.

B2 hücresine; (CTRL+SHIFT+ENTER ile hücreye girişi tamamlayın.)

=EĞER(A2="";"";YERİNEKOY(PARÇAAL(A2;MBUL(".";A2;1)+1;MBUL(",";A2;1)-MBUL(".";A2;1)-1);PARÇAAL(PARÇAAL(A2;MBUL(".";A2;1)+1;MBUL(",";A2;1)-MBUL(".";A2;1)-1);KAÇINCI(DOĞRU;ESAYIYSA(1*PARÇAAL(PARÇAAL(A2;MBUL(".";A2;1)+1;MBUL(",";A2;1)-MBUL(".";A2;1)-1);SATIR($1:$9);1));0);BAĞ_DEĞ_SAY(1*PARÇAAL(PARÇAAL(A2;MBUL(".";A2;1)+1;MBUL(",";A2;1)-MBUL(".";A2;1)-1);SATIR($1:$9);1)));""))

C2 hücresine;

=EĞER(A2="";"";YERİNEKOY(PARÇAAL(A2;MBUL(".";A2;1)+1;MBUL(",";A2;1)-MBUL(".";A2;1)-1);B2;""))

D2 hücresine;

=EĞER(A2="";"";PARÇAAL(A2;MBUL(",";A2;1)+1;UZUNLUK(A2)-MBUL(",";A2;1)+1))

 

[vitamin]

Teşekkürler, Korhan bey.

Sizin örnekte gayet şık.

iyi çalışmalar.