aynı bilgileri birkere yazmak

[gedavet]

iyi günler
ekdeki örnekdede açıklamaya çalıştım ben alış, satış, gelir, gider şeklinde sayfalar var bazı bilgiler aynı şeyi defalarca giriyorum bunun daha pratik bir yöntemi varmı
satış sayfasından örnek verecek olursak mesela 10 adet ürün satışı yapacaksam 10 adet ürünü 10 satıra yazıyorum baştarafına kasa/yıl/bölge/il/isim gibi bilgileri (kırmızı rekli olnan) her satırda aynı bilgileri bir kere yazarak nasıl yapa biliriz
bu konuda değişik işlemler veya yöntemlerle nasıl yapılabilir
yardımlarınıza ihtiyacım var

 

[Necdet]

Merhaba,

Tekrarlanan verileri bir kere yazmanız yeterli, sonra istediğiniz zaman aşağıdaki kodları çalıştırabilirsiniz.

Sub Doldur()
    Dim i As Long
    i = Cells(Rows.Count, "I").End(3).Row
    Range("B5:N" & i).SpecialCells(xlCellTypeBlanks).FormulaR1C1 = "=R[-1]C"
End Sub

 

[gedavet]

necdet bey ilginiz için teşekkür ederim ancak diyelimki bir satış fişi düşünelim
kırmızı renki olan bilgileri üstte yazıp diğerlerinde alta istediğimiz kadar ürün yazacak şekilde yazsak alttada toplam satırı olsa ve bu 1 numaralı fişin bilgilerini bu şekilde girsek ve toplamında görmüş oluruz bu bilgiyi kaydet desek ve bir yere bilgiyi aktarsa ve fişi boşaltsabu şekilde devam etsek nasıl olur
toplam satırı ile üürnler arasında yazdıkca satırı kendi eklese veye bilgiyi sildikce boş satırı kendi silse ve aktarırkende toplam satırı aktarmasa
bu mümkünmüdür vey daha güzel nasıl olabilir

 

[gedavet]

Ekde yeni bir fiş örneği yaparak yapmak istediğikleri açıklamaya çalıştım
bu konuda bana yardımcı olabilirmiisniz
daha önceki yazdığım gibi bu benim fikrim sizleirn fikirleri olursa oda olur

 

[hımmmmmmmm]

slm

musti...senin istediğin şey, ha! deyince olabilecek bir durum değil.. sen veri tabanı sitemine dayalı komplike bir programlama istiyosun.. olaki istediğin yapıldı istatistksel ve listelemelere dayalı şeylerde isteyeceksin.. uzun soluklu bir durum... buda oturup adamakıllı bir şey yapmayı gerektirecek...
isimlere ait satış bilgilerin mevcut... kişiyi seçtiğinde o isme ait bilgiler gelmesi gerek.. düzeltmeler eklemeler silmeler yapabileceğin sonrada veri olarak yeniden saklanabilecek esnek programlara ve bir veri tabanına ihtiyaç var.. komplike bir durum... kısa kotlarla halledilecek bir konu değil... istediğin şey uzun soluklu...
yanlışmı düşündüm bilmiyorum...

 

[gedavet]

ilginiz için teşekkür ederim ancak sizingibi hocalarımızın emeklerine sağlık çok güzel yaparlar diye inanıyorum

şöyle olabilir sadece fişe yazıp veri sayfasına kaydede oradanda özet tablo alınır istenen rapor çıkar
hatta alış, satış, gelir, gider fişleride veri sayfasına aktarılabilirse bir özet tablo ile istenilen bilgiye ulaşılır

 

[hımmmmmmmm]

elbette düşündüğün, programlamaların olmazsa olmazları... yapılabilir..
ama dediğim gibi düşündüğün her işlem için kotlama gerek...

 

[Necdet]

necdet bey ilginiz için teşekkür ederim ancak diyelimki bir satış fişi düşünelim
kırmızı renki olan bilgileri üstte yazıp diğerlerinde alta istediğimiz kadar ürün yazacak şekilde yazsak alttada toplam satırı olsa ve bu 1 numaralı fişin bilgilerini bu şekilde girsek ve toplamında görmüş oluruz bu bilgiyi kaydet desek ve bir yere bilgiyi aktarsa ve fişi boşaltsabu şekilde devam etsek nasıl olur
toplam satırı ile üürnler arasında yazdıkca satırı kendi eklese veye bilgiyi sildikce boş satırı kendi silse ve aktarırkende toplam satırı aktarmasa
bu mümkünmüdür vey daha güzel nasıl olabilir

e şimdi bu sorunun ilk sorudaki konu ile ne ilgisi var?
İkisi bambaşka konular. Önce ısınma sorusu soruyorsunuz sonra sol gösterip sağ vuruyorsunuz.

Doğrudan ikinci soru ile konu açsanız şimdiye kadar bir arkadaşımız mutlaka yanıt verirdi.

Ben artık böyle sol gösterip sağ vurulan soruları yanıtlamayacağım. Boş durma boşa çalış gibi birşey oluyor.

 

[gedavet]

necdet hocam yanlış anlaşıldım ise özür dilerim ilk önce nasıl yapmak gerektiği hakkında bir fikrim olmadı nasıl yapılacağı huhusunda
ondan sonra bu şekilde olabilmi diye fiş adlı dosyayı ekledim
bu kodu yazı verirseniz çok iyi olacak fiş sayfasındaki bilgileri veri sayfasına aktarıverse

 

[Necdet]

Merhaba,

Ekli dosyayı inceleyiniz. Modül, Sayfada kodları ve Form kullandım.
Formda sadece Combobox var.

Aşağıdaki kodlar "SATIŞ FİŞİ" sayfasının kod bölümünde olmalı.

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
    If Intersect(Target, [D:E]) Is Nothing Then Exit Sub
    Dim i As Integer
    i = Target.Row + 1
    Rows(i & ":" & i).Insert Shift:=xlDown
    Cells(i, "F") = "=D" & i & "*E" & i
End Sub

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
    If Intersect(Target, [B:C]) Is Nothing Then Exit Sub
    If Target.Row < 8 Or Target.Row = 10 Or Target.Row = 11 Then Exit Sub
    If Selection.Count > 1 Then Exit Sub
    
    Dim SonSat As Integer
    SonSat = Cells(Rows.Count, "B").End(3).Row - 1
    If Target.Row > SonSat Then Exit Sub
    
    If Target.Address = "$C$8" Then
        Kolon = 5
    ElseIf Target.Address = "$C$9" Then
        Kolon = 4
    Else
        Kolon = Target.Column
    End If
    UserForm1.Show
End Sub

Userformun Initialize kodları

Private Sub UserForm_Initialize()
    Dim sp  As Worksheet
    Dim i   As Integer
    Dim Son As Integer
    
    Set sp = Sheets("Parametre")
    If Kolon = 2 Then
        Label1.Caption = "GRUBU SEÇİNİZ"
    ElseIf Kolon = 3 Then
        Label1.Caption = "ÜRÜNÜ SEÇİNİZ"
    ElseIf Kolon = 4 Then
        Label1.Caption = "İLİ SEÇİNİZ"
    Else
        Label1.Caption = "BÖLGEYİ SEÇİNİZ"
    End If
        
    Son = sp.Cells(Rows.Count, Kolon).End(3).Row
    
    For i = 2 To Son
        ComboBox1.AddItem sp.Cells(i, Kolon)
    Next i
End Sub

ve Modülde Aktarma Kodu:

Public Kolon As Integer
Sub Aktar()
    Dim i   As Long, _
        j   As Integer, _
        sv  As Worksheet
    
    Set sv = Sheets("VERİ")
    
    i = sv.Cells(Rows.Count, "A").End(3).Row + 1
    j = 12
    Sheets("SATIŞ FİŞİ").Select
    Application.ScreenUpdating = False
    
    Do While Cells(j, "B") > "" And Not Cells(j, "B") = "TOPLAM"
        sv.Cells(i, "A") = Cells(6, "C")
        sv.Cells(i, "B") = Cells(6, "F")
        sv.Cells(i, "C") = Cells(8, "C")
        sv.Cells(i, "D") = Cells(9, "C")
        sv.Cells(i, "E") = Cells(8, "F")
        sv.Cells(i, "F") = Cells(9, "F")
        sv.Cells(i, "G") = Cells(4, "C")
        sv.Cells(i, "H") = Cells(j, "B")
        sv.Cells(i, "I") = Cells(j, "C")
        sv.Cells(i, "J") = Cells(j, "D")
        sv.Cells(i, "K") = Cells(j, "E")
        sv.Cells(i, "L") = Cells(j, "F")
        sv.Cells(i, "M") = Cells(4, "F")
        i = i + 1
        j = j + 1
    Loop
   
    j = j - 1
    Range("C6,C8,C9,F4,F6,F8,F9,B12:E" & j).ClearContents
    Range("C4") = Range("C4") + 1
    
    MsgBox "BİLGİLER AKTARILMIŞTIR....", vbInformation, "N. YEŞERTENER--> [URL="http://www.web.tr/"]www.web.tr[/URL]"
    
End Sub

 

[Orion1]

musti...senin istediğin şey, ha! deyince olabilecek bir durum değil.. sen veri tabanı sitemine dayalı komplike bir programlama istiyosun.. olaki istediğin yapıldı istatistksel ve listelemelere dayalı şeylerde isteyeceksin.. uzun soluklu bir durum... buda oturup adamakıllı bir şey yapmayı gerektirecek...
isimlere ait satış bilgilerin mevcut... kişiyi seçtiğinde o isme ait bilgiler gelmesi gerek.. düzeltmeler eklemeler silmeler yapabileceğin sonrada veri olarak yeniden saklanabilecek esnek programlara ve bir veri tabanına ihtiyaç var.. komplike bir durum... kısa kotlarla halledilecek bir konu değil... istediğin şey uzun soluklu...
yanlışmı düşündüm bilmiyorum...

Aynen katılıyorum. k::

 

[gedavet]

Necdet bey ilginiz için teşekkür ederim inceliyorum